001:       SUBROUTINE ZTRSYL( TRANA, TRANB, ISGN, M, N, A, LDA, B, LDB, C,
002:      $                   LDC, SCALE, INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          TRANA, TRANB
010:       INTEGER            INFO, ISGN, LDA, LDB, LDC, M, N
011:       DOUBLE PRECISION   SCALE
012: *     ..
013: *     .. Array Arguments ..
014:       COMPLEX*16         A( LDA, * ), B( LDB, * ), C( LDC, * )
015: *     ..
016: *
017: *  Purpose
018: *  =======
019: *
020: *  ZTRSYL solves the complex Sylvester matrix equation:
021: *
022: *     op(A)*X + X*op(B) = scale*C or
023: *     op(A)*X - X*op(B) = scale*C,
024: *
025: *  where op(A) = A or A**H, and A and B are both upper triangular. A is
026: *  M-by-M and B is N-by-N; the right hand side C and the solution X are
027: *  M-by-N; and scale is an output scale factor, set <= 1 to avoid
028: *  overflow in X.
029: *
030: *  Arguments
031: *  =========
032: *
033: *  TRANA   (input) CHARACTER*1
034: *          Specifies the option op(A):
035: *          = 'N': op(A) = A    (No transpose)
036: *          = 'C': op(A) = A**H (Conjugate transpose)
037: *
038: *  TRANB   (input) CHARACTER*1
039: *          Specifies the option op(B):
040: *          = 'N': op(B) = B    (No transpose)
041: *          = 'C': op(B) = B**H (Conjugate transpose)
042: *
043: *  ISGN    (input) INTEGER
044: *          Specifies the sign in the equation:
045: *          = +1: solve op(A)*X + X*op(B) = scale*C
046: *          = -1: solve op(A)*X - X*op(B) = scale*C
047: *
048: *  M       (input) INTEGER
049: *          The order of the matrix A, and the number of rows in the
050: *          matrices X and C. M >= 0.
051: *
052: *  N       (input) INTEGER
053: *          The order of the matrix B, and the number of columns in the
054: *          matrices X and C. N >= 0.
055: *
056: *  A       (input) COMPLEX*16 array, dimension (LDA,M)
057: *          The upper triangular matrix A.
058: *
059: *  LDA     (input) INTEGER
060: *          The leading dimension of the array A. LDA >= max(1,M).
061: *
062: *  B       (input) COMPLEX*16 array, dimension (LDB,N)
063: *          The upper triangular matrix B.
064: *
065: *  LDB     (input) INTEGER
066: *          The leading dimension of the array B. LDB >= max(1,N).
067: *
068: *  C       (input/output) COMPLEX*16 array, dimension (LDC,N)
069: *          On entry, the M-by-N right hand side matrix C.
070: *          On exit, C is overwritten by the solution matrix X.
071: *
072: *  LDC     (input) INTEGER
073: *          The leading dimension of the array C. LDC >= max(1,M)
074: *
075: *  SCALE   (output) DOUBLE PRECISION
076: *          The scale factor, scale, set <= 1 to avoid overflow in X.
077: *
078: *  INFO    (output) INTEGER
079: *          = 0: successful exit
080: *          < 0: if INFO = -i, the i-th argument had an illegal value
081: *          = 1: A and B have common or very close eigenvalues; perturbed
082: *               values were used to solve the equation (but the matrices
083: *               A and B are unchanged).
084: *
085: *  =====================================================================
086: *
087: *     .. Parameters ..
088:       DOUBLE PRECISION   ONE
089:       PARAMETER          ( ONE = 1.0D+0 )
090: *     ..
091: *     .. Local Scalars ..
092:       LOGICAL            NOTRNA, NOTRNB
093:       INTEGER            J, K, L
094:       DOUBLE PRECISION   BIGNUM, DA11, DB, EPS, SCALOC, SGN, SMIN,
095:      $                   SMLNUM
096:       COMPLEX*16         A11, SUML, SUMR, VEC, X11
097: *     ..
098: *     .. Local Arrays ..
099:       DOUBLE PRECISION   DUM( 1 )
100: *     ..
101: *     .. External Functions ..
102:       LOGICAL            LSAME
103:       DOUBLE PRECISION   DLAMCH, ZLANGE
104:       COMPLEX*16         ZDOTC, ZDOTU, ZLADIV
105:       EXTERNAL           LSAME, DLAMCH, ZLANGE, ZDOTC, ZDOTU, ZLADIV
106: *     ..
107: *     .. External Subroutines ..
108:       EXTERNAL           DLABAD, XERBLA, ZDSCAL
109: *     ..
110: *     .. Intrinsic Functions ..
111:       INTRINSIC          ABS, DBLE, DCMPLX, DCONJG, DIMAG, MAX, MIN
112: *     ..
113: *     .. Executable Statements ..
114: *
115: *     Decode and Test input parameters
116: *
117:       NOTRNA = LSAME( TRANA, 'N' )
118:       NOTRNB = LSAME( TRANB, 'N' )
119: *
120:       INFO = 0
121:       IF( .NOT.NOTRNA .AND. .NOT.LSAME( TRANA, 'C' ) ) THEN
122:          INFO = -1
123:       ELSE IF( .NOT.NOTRNB .AND. .NOT.LSAME( TRANB, 'C' ) ) THEN
124:          INFO = -2
125:       ELSE IF( ISGN.NE.1 .AND. ISGN.NE.-1 ) THEN
126:          INFO = -3
127:       ELSE IF( M.LT.0 ) THEN
128:          INFO = -4
129:       ELSE IF( N.LT.0 ) THEN
130:          INFO = -5
131:       ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
132:          INFO = -7
133:       ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
134:          INFO = -9
135:       ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
136:          INFO = -11
137:       END IF
138:       IF( INFO.NE.0 ) THEN
139:          CALL XERBLA( 'ZTRSYL', -INFO )
140:          RETURN
141:       END IF
142: *
143: *     Quick return if possible
144: *
145:       IF( M.EQ.0 .OR. N.EQ.0 )
146:      $   RETURN
147: *
148: *     Set constants to control overflow
149: *
150:       EPS = DLAMCH( 'P' )
151:       SMLNUM = DLAMCH( 'S' )
152:       BIGNUM = ONE / SMLNUM
153:       CALL DLABAD( SMLNUM, BIGNUM )
154:       SMLNUM = SMLNUM*DBLE( M*N ) / EPS
155:       BIGNUM = ONE / SMLNUM
156:       SMIN = MAX( SMLNUM, EPS*ZLANGE( 'M', M, M, A, LDA, DUM ),
157:      $       EPS*ZLANGE( 'M', N, N, B, LDB, DUM ) )
158:       SCALE = ONE
159:       SGN = ISGN
160: *
161:       IF( NOTRNA .AND. NOTRNB ) THEN
162: *
163: *        Solve    A*X + ISGN*X*B = scale*C.
164: *
165: *        The (K,L)th block of X is determined starting from
166: *        bottom-left corner column by column by
167: *
168: *            A(K,K)*X(K,L) + ISGN*X(K,L)*B(L,L) = C(K,L) - R(K,L)
169: *
170: *        Where
171: *                    M                        L-1
172: *          R(K,L) = SUM [A(K,I)*X(I,L)] +ISGN*SUM [X(K,J)*B(J,L)].
173: *                  I=K+1                      J=1
174: *
175:          DO 30 L = 1, N
176:             DO 20 K = M, 1, -1
177: *
178:                SUML = ZDOTU( M-K, A( K, MIN( K+1, M ) ), LDA,
179:      $                C( MIN( K+1, M ), L ), 1 )
180:                SUMR = ZDOTU( L-1, C( K, 1 ), LDC, B( 1, L ), 1 )
181:                VEC = C( K, L ) - ( SUML+SGN*SUMR )
182: *
183:                SCALOC = ONE
184:                A11 = A( K, K ) + SGN*B( L, L )
185:                DA11 = ABS( DBLE( A11 ) ) + ABS( DIMAG( A11 ) )
186:                IF( DA11.LE.SMIN ) THEN
187:                   A11 = SMIN
188:                   DA11 = SMIN
189:                   INFO = 1
190:                END IF
191:                DB = ABS( DBLE( VEC ) ) + ABS( DIMAG( VEC ) )
192:                IF( DA11.LT.ONE .AND. DB.GT.ONE ) THEN
193:                   IF( DB.GT.BIGNUM*DA11 )
194:      $               SCALOC = ONE / DB
195:                END IF
196:                X11 = ZLADIV( VEC*DCMPLX( SCALOC ), A11 )
197: *
198:                IF( SCALOC.NE.ONE ) THEN
199:                   DO 10 J = 1, N
200:                      CALL ZDSCAL( M, SCALOC, C( 1, J ), 1 )
201:    10             CONTINUE
202:                   SCALE = SCALE*SCALOC
203:                END IF
204:                C( K, L ) = X11
205: *
206:    20       CONTINUE
207:    30    CONTINUE
208: *
209:       ELSE IF( .NOT.NOTRNA .AND. NOTRNB ) THEN
210: *
211: *        Solve    A' *X + ISGN*X*B = scale*C.
212: *
213: *        The (K,L)th block of X is determined starting from
214: *        upper-left corner column by column by
215: *
216: *            A'(K,K)*X(K,L) + ISGN*X(K,L)*B(L,L) = C(K,L) - R(K,L)
217: *
218: *        Where
219: *                   K-1                         L-1
220: *          R(K,L) = SUM [A'(I,K)*X(I,L)] + ISGN*SUM [X(K,J)*B(J,L)]
221: *                   I=1                         J=1
222: *
223:          DO 60 L = 1, N
224:             DO 50 K = 1, M
225: *
226:                SUML = ZDOTC( K-1, A( 1, K ), 1, C( 1, L ), 1 )
227:                SUMR = ZDOTU( L-1, C( K, 1 ), LDC, B( 1, L ), 1 )
228:                VEC = C( K, L ) - ( SUML+SGN*SUMR )
229: *
230:                SCALOC = ONE
231:                A11 = DCONJG( A( K, K ) ) + SGN*B( L, L )
232:                DA11 = ABS( DBLE( A11 ) ) + ABS( DIMAG( A11 ) )
233:                IF( DA11.LE.SMIN ) THEN
234:                   A11 = SMIN
235:                   DA11 = SMIN
236:                   INFO = 1
237:                END IF
238:                DB = ABS( DBLE( VEC ) ) + ABS( DIMAG( VEC ) )
239:                IF( DA11.LT.ONE .AND. DB.GT.ONE ) THEN
240:                   IF( DB.GT.BIGNUM*DA11 )
241:      $               SCALOC = ONE / DB
242:                END IF
243: *
244:                X11 = ZLADIV( VEC*DCMPLX( SCALOC ), A11 )
245: *
246:                IF( SCALOC.NE.ONE ) THEN
247:                   DO 40 J = 1, N
248:                      CALL ZDSCAL( M, SCALOC, C( 1, J ), 1 )
249:    40             CONTINUE
250:                   SCALE = SCALE*SCALOC
251:                END IF
252:                C( K, L ) = X11
253: *
254:    50       CONTINUE
255:    60    CONTINUE
256: *
257:       ELSE IF( .NOT.NOTRNA .AND. .NOT.NOTRNB ) THEN
258: *
259: *        Solve    A'*X + ISGN*X*B' = C.
260: *
261: *        The (K,L)th block of X is determined starting from
262: *        upper-right corner column by column by
263: *
264: *            A'(K,K)*X(K,L) + ISGN*X(K,L)*B'(L,L) = C(K,L) - R(K,L)
265: *
266: *        Where
267: *                    K-1
268: *           R(K,L) = SUM [A'(I,K)*X(I,L)] +
269: *                    I=1
270: *                           N
271: *                     ISGN*SUM [X(K,J)*B'(L,J)].
272: *                          J=L+1
273: *
274:          DO 90 L = N, 1, -1
275:             DO 80 K = 1, M
276: *
277:                SUML = ZDOTC( K-1, A( 1, K ), 1, C( 1, L ), 1 )
278:                SUMR = ZDOTC( N-L, C( K, MIN( L+1, N ) ), LDC,
279:      $                B( L, MIN( L+1, N ) ), LDB )
280:                VEC = C( K, L ) - ( SUML+SGN*DCONJG( SUMR ) )
281: *
282:                SCALOC = ONE
283:                A11 = DCONJG( A( K, K )+SGN*B( L, L ) )
284:                DA11 = ABS( DBLE( A11 ) ) + ABS( DIMAG( A11 ) )
285:                IF( DA11.LE.SMIN ) THEN
286:                   A11 = SMIN
287:                   DA11 = SMIN
288:                   INFO = 1
289:                END IF
290:                DB = ABS( DBLE( VEC ) ) + ABS( DIMAG( VEC ) )
291:                IF( DA11.LT.ONE .AND. DB.GT.ONE ) THEN
292:                   IF( DB.GT.BIGNUM*DA11 )
293:      $               SCALOC = ONE / DB
294:                END IF
295: *
296:                X11 = ZLADIV( VEC*DCMPLX( SCALOC ), A11 )
297: *
298:                IF( SCALOC.NE.ONE ) THEN
299:                   DO 70 J = 1, N
300:                      CALL ZDSCAL( M, SCALOC, C( 1, J ), 1 )
301:    70             CONTINUE
302:                   SCALE = SCALE*SCALOC
303:                END IF
304:                C( K, L ) = X11
305: *
306:    80       CONTINUE
307:    90    CONTINUE
308: *
309:       ELSE IF( NOTRNA .AND. .NOT.NOTRNB ) THEN
310: *
311: *        Solve    A*X + ISGN*X*B' = C.
312: *
313: *        The (K,L)th block of X is determined starting from
314: *        bottom-left corner column by column by
315: *
316: *           A(K,K)*X(K,L) + ISGN*X(K,L)*B'(L,L) = C(K,L) - R(K,L)
317: *
318: *        Where
319: *                    M                          N
320: *          R(K,L) = SUM [A(K,I)*X(I,L)] + ISGN*SUM [X(K,J)*B'(L,J)]
321: *                  I=K+1                      J=L+1
322: *
323:          DO 120 L = N, 1, -1
324:             DO 110 K = M, 1, -1
325: *
326:                SUML = ZDOTU( M-K, A( K, MIN( K+1, M ) ), LDA,
327:      $                C( MIN( K+1, M ), L ), 1 )
328:                SUMR = ZDOTC( N-L, C( K, MIN( L+1, N ) ), LDC,
329:      $                B( L, MIN( L+1, N ) ), LDB )
330:                VEC = C( K, L ) - ( SUML+SGN*DCONJG( SUMR ) )
331: *
332:                SCALOC = ONE
333:                A11 = A( K, K ) + SGN*DCONJG( B( L, L ) )
334:                DA11 = ABS( DBLE( A11 ) ) + ABS( DIMAG( A11 ) )
335:                IF( DA11.LE.SMIN ) THEN
336:                   A11 = SMIN
337:                   DA11 = SMIN
338:                   INFO = 1
339:                END IF
340:                DB = ABS( DBLE( VEC ) ) + ABS( DIMAG( VEC ) )
341:                IF( DA11.LT.ONE .AND. DB.GT.ONE ) THEN
342:                   IF( DB.GT.BIGNUM*DA11 )
343:      $               SCALOC = ONE / DB
344:                END IF
345: *
346:                X11 = ZLADIV( VEC*DCMPLX( SCALOC ), A11 )
347: *
348:                IF( SCALOC.NE.ONE ) THEN
349:                   DO 100 J = 1, N
350:                      CALL ZDSCAL( M, SCALOC, C( 1, J ), 1 )
351:   100             CONTINUE
352:                   SCALE = SCALE*SCALOC
353:                END IF
354:                C( K, L ) = X11
355: *
356:   110       CONTINUE
357:   120    CONTINUE
358: *
359:       END IF
360: *
361:       RETURN
362: *
363: *     End of ZTRSYL
364: *
365:       END
366: