001:       SUBROUTINE ZTPRFS( UPLO, TRANS, DIAG, N, NRHS, AP, B, LDB, X, LDX,
002:      $                   FERR, BERR, WORK, RWORK, INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     Modified to call ZLACN2 in place of ZLACON, 10 Feb 03, SJH.
009: *
010: *     .. Scalar Arguments ..
011:       CHARACTER          DIAG, TRANS, UPLO
012:       INTEGER            INFO, LDB, LDX, N, NRHS
013: *     ..
014: *     .. Array Arguments ..
015:       DOUBLE PRECISION   BERR( * ), FERR( * ), RWORK( * )
016:       COMPLEX*16         AP( * ), B( LDB, * ), WORK( * ), X( LDX, * )
017: *     ..
018: *
019: *  Purpose
020: *  =======
021: *
022: *  ZTPRFS provides error bounds and backward error estimates for the
023: *  solution to a system of linear equations with a triangular packed
024: *  coefficient matrix.
025: *
026: *  The solution matrix X must be computed by ZTPTRS or some other
027: *  means before entering this routine.  ZTPRFS does not do iterative
028: *  refinement because doing so cannot improve the backward error.
029: *
030: *  Arguments
031: *  =========
032: *
033: *  UPLO    (input) CHARACTER*1
034: *          = 'U':  A is upper triangular;
035: *          = 'L':  A is lower triangular.
036: *
037: *  TRANS   (input) CHARACTER*1
038: *          Specifies the form of the system of equations:
039: *          = 'N':  A * X = B     (No transpose)
040: *          = 'T':  A**T * X = B  (Transpose)
041: *          = 'C':  A**H * X = B  (Conjugate transpose)
042: *
043: *  DIAG    (input) CHARACTER*1
044: *          = 'N':  A is non-unit triangular;
045: *          = 'U':  A is unit triangular.
046: *
047: *  N       (input) INTEGER
048: *          The order of the matrix A.  N >= 0.
049: *
050: *  NRHS    (input) INTEGER
051: *          The number of right hand sides, i.e., the number of columns
052: *          of the matrices B and X.  NRHS >= 0.
053: *
054: *  AP      (input) COMPLEX*16 array, dimension (N*(N+1)/2)
055: *          The upper or lower triangular matrix A, packed columnwise in
056: *          a linear array.  The j-th column of A is stored in the array
057: *          AP as follows:
058: *          if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
059: *          if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n.
060: *          If DIAG = 'U', the diagonal elements of A are not referenced
061: *          and are assumed to be 1.
062: *
063: *  B       (input) COMPLEX*16 array, dimension (LDB,NRHS)
064: *          The right hand side matrix B.
065: *
066: *  LDB     (input) INTEGER
067: *          The leading dimension of the array B.  LDB >= max(1,N).
068: *
069: *  X       (input) COMPLEX*16 array, dimension (LDX,NRHS)
070: *          The solution matrix X.
071: *
072: *  LDX     (input) INTEGER
073: *          The leading dimension of the array X.  LDX >= max(1,N).
074: *
075: *  FERR    (output) DOUBLE PRECISION array, dimension (NRHS)
076: *          The estimated forward error bound for each solution vector
077: *          X(j) (the j-th column of the solution matrix X).
078: *          If XTRUE is the true solution corresponding to X(j), FERR(j)
079: *          is an estimated upper bound for the magnitude of the largest
080: *          element in (X(j) - XTRUE) divided by the magnitude of the
081: *          largest element in X(j).  The estimate is as reliable as
082: *          the estimate for RCOND, and is almost always a slight
083: *          overestimate of the true error.
084: *
085: *  BERR    (output) DOUBLE PRECISION array, dimension (NRHS)
086: *          The componentwise relative backward error of each solution
087: *          vector X(j) (i.e., the smallest relative change in
088: *          any element of A or B that makes X(j) an exact solution).
089: *
090: *  WORK    (workspace) COMPLEX*16 array, dimension (2*N)
091: *
092: *  RWORK   (workspace) DOUBLE PRECISION array, dimension (N)
093: *
094: *  INFO    (output) INTEGER
095: *          = 0:  successful exit
096: *          < 0:  if INFO = -i, the i-th argument had an illegal value
097: *
098: *  =====================================================================
099: *
100: *     .. Parameters ..
101:       DOUBLE PRECISION   ZERO
102:       PARAMETER          ( ZERO = 0.0D+0 )
103:       COMPLEX*16         ONE
104:       PARAMETER          ( ONE = ( 1.0D+0, 0.0D+0 ) )
105: *     ..
106: *     .. Local Scalars ..
107:       LOGICAL            NOTRAN, NOUNIT, UPPER
108:       CHARACTER          TRANSN, TRANST
109:       INTEGER            I, J, K, KASE, KC, NZ
110:       DOUBLE PRECISION   EPS, LSTRES, S, SAFE1, SAFE2, SAFMIN, XK
111:       COMPLEX*16         ZDUM
112: *     ..
113: *     .. Local Arrays ..
114:       INTEGER            ISAVE( 3 )
115: *     ..
116: *     .. External Subroutines ..
117:       EXTERNAL           XERBLA, ZAXPY, ZCOPY, ZLACN2, ZTPMV, ZTPSV
118: *     ..
119: *     .. Intrinsic Functions ..
120:       INTRINSIC          ABS, DBLE, DIMAG, MAX
121: *     ..
122: *     .. External Functions ..
123:       LOGICAL            LSAME
124:       DOUBLE PRECISION   DLAMCH
125:       EXTERNAL           LSAME, DLAMCH
126: *     ..
127: *     .. Statement Functions ..
128:       DOUBLE PRECISION   CABS1
129: *     ..
130: *     .. Statement Function definitions ..
131:       CABS1( ZDUM ) = ABS( DBLE( ZDUM ) ) + ABS( DIMAG( ZDUM ) )
132: *     ..
133: *     .. Executable Statements ..
134: *
135: *     Test the input parameters.
136: *
137:       INFO = 0
138:       UPPER = LSAME( UPLO, 'U' )
139:       NOTRAN = LSAME( TRANS, 'N' )
140:       NOUNIT = LSAME( DIAG, 'N' )
141: *
142:       IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
143:          INFO = -1
144:       ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'T' ) .AND. .NOT.
145:      $         LSAME( TRANS, 'C' ) ) THEN
146:          INFO = -2
147:       ELSE IF( .NOT.NOUNIT .AND. .NOT.LSAME( DIAG, 'U' ) ) THEN
148:          INFO = -3
149:       ELSE IF( N.LT.0 ) THEN
150:          INFO = -4
151:       ELSE IF( NRHS.LT.0 ) THEN
152:          INFO = -5
153:       ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
154:          INFO = -8
155:       ELSE IF( LDX.LT.MAX( 1, N ) ) THEN
156:          INFO = -10
157:       END IF
158:       IF( INFO.NE.0 ) THEN
159:          CALL XERBLA( 'ZTPRFS', -INFO )
160:          RETURN
161:       END IF
162: *
163: *     Quick return if possible
164: *
165:       IF( N.EQ.0 .OR. NRHS.EQ.0 ) THEN
166:          DO 10 J = 1, NRHS
167:             FERR( J ) = ZERO
168:             BERR( J ) = ZERO
169:    10    CONTINUE
170:          RETURN
171:       END IF
172: *
173:       IF( NOTRAN ) THEN
174:          TRANSN = 'N'
175:          TRANST = 'C'
176:       ELSE
177:          TRANSN = 'C'
178:          TRANST = 'N'
179:       END IF
180: *
181: *     NZ = maximum number of nonzero elements in each row of A, plus 1
182: *
183:       NZ = N + 1
184:       EPS = DLAMCH( 'Epsilon' )
185:       SAFMIN = DLAMCH( 'Safe minimum' )
186:       SAFE1 = NZ*SAFMIN
187:       SAFE2 = SAFE1 / EPS
188: *
189: *     Do for each right hand side
190: *
191:       DO 250 J = 1, NRHS
192: *
193: *        Compute residual R = B - op(A) * X,
194: *        where op(A) = A, A**T, or A**H, depending on TRANS.
195: *
196:          CALL ZCOPY( N, X( 1, J ), 1, WORK, 1 )
197:          CALL ZTPMV( UPLO, TRANS, DIAG, N, AP, WORK, 1 )
198:          CALL ZAXPY( N, -ONE, B( 1, J ), 1, WORK, 1 )
199: *
200: *        Compute componentwise relative backward error from formula
201: *
202: *        max(i) ( abs(R(i)) / ( abs(op(A))*abs(X) + abs(B) )(i) )
203: *
204: *        where abs(Z) is the componentwise absolute value of the matrix
205: *        or vector Z.  If the i-th component of the denominator is less
206: *        than SAFE2, then SAFE1 is added to the i-th components of the
207: *        numerator and denominator before dividing.
208: *
209:          DO 20 I = 1, N
210:             RWORK( I ) = CABS1( B( I, J ) )
211:    20    CONTINUE
212: *
213:          IF( NOTRAN ) THEN
214: *
215: *           Compute abs(A)*abs(X) + abs(B).
216: *
217:             IF( UPPER ) THEN
218:                KC = 1
219:                IF( NOUNIT ) THEN
220:                   DO 40 K = 1, N
221:                      XK = CABS1( X( K, J ) )
222:                      DO 30 I = 1, K
223:                         RWORK( I ) = RWORK( I ) +
224:      $                               CABS1( AP( KC+I-1 ) )*XK
225:    30                CONTINUE
226:                      KC = KC + K
227:    40             CONTINUE
228:                ELSE
229:                   DO 60 K = 1, N
230:                      XK = CABS1( X( K, J ) )
231:                      DO 50 I = 1, K - 1
232:                         RWORK( I ) = RWORK( I ) +
233:      $                               CABS1( AP( KC+I-1 ) )*XK
234:    50                CONTINUE
235:                      RWORK( K ) = RWORK( K ) + XK
236:                      KC = KC + K
237:    60             CONTINUE
238:                END IF
239:             ELSE
240:                KC = 1
241:                IF( NOUNIT ) THEN
242:                   DO 80 K = 1, N
243:                      XK = CABS1( X( K, J ) )
244:                      DO 70 I = K, N
245:                         RWORK( I ) = RWORK( I ) +
246:      $                               CABS1( AP( KC+I-K ) )*XK
247:    70                CONTINUE
248:                      KC = KC + N - K + 1
249:    80             CONTINUE
250:                ELSE
251:                   DO 100 K = 1, N
252:                      XK = CABS1( X( K, J ) )
253:                      DO 90 I = K + 1, N
254:                         RWORK( I ) = RWORK( I ) +
255:      $                               CABS1( AP( KC+I-K ) )*XK
256:    90                CONTINUE
257:                      RWORK( K ) = RWORK( K ) + XK
258:                      KC = KC + N - K + 1
259:   100             CONTINUE
260:                END IF
261:             END IF
262:          ELSE
263: *
264: *           Compute abs(A**H)*abs(X) + abs(B).
265: *
266:             IF( UPPER ) THEN
267:                KC = 1
268:                IF( NOUNIT ) THEN
269:                   DO 120 K = 1, N
270:                      S = ZERO
271:                      DO 110 I = 1, K
272:                         S = S + CABS1( AP( KC+I-1 ) )*CABS1( X( I, J ) )
273:   110                CONTINUE
274:                      RWORK( K ) = RWORK( K ) + S
275:                      KC = KC + K
276:   120             CONTINUE
277:                ELSE
278:                   DO 140 K = 1, N
279:                      S = CABS1( X( K, J ) )
280:                      DO 130 I = 1, K - 1
281:                         S = S + CABS1( AP( KC+I-1 ) )*CABS1( X( I, J ) )
282:   130                CONTINUE
283:                      RWORK( K ) = RWORK( K ) + S
284:                      KC = KC + K
285:   140             CONTINUE
286:                END IF
287:             ELSE
288:                KC = 1
289:                IF( NOUNIT ) THEN
290:                   DO 160 K = 1, N
291:                      S = ZERO
292:                      DO 150 I = K, N
293:                         S = S + CABS1( AP( KC+I-K ) )*CABS1( X( I, J ) )
294:   150                CONTINUE
295:                      RWORK( K ) = RWORK( K ) + S
296:                      KC = KC + N - K + 1
297:   160             CONTINUE
298:                ELSE
299:                   DO 180 K = 1, N
300:                      S = CABS1( X( K, J ) )
301:                      DO 170 I = K + 1, N
302:                         S = S + CABS1( AP( KC+I-K ) )*CABS1( X( I, J ) )
303:   170                CONTINUE
304:                      RWORK( K ) = RWORK( K ) + S
305:                      KC = KC + N - K + 1
306:   180             CONTINUE
307:                END IF
308:             END IF
309:          END IF
310:          S = ZERO
311:          DO 190 I = 1, N
312:             IF( RWORK( I ).GT.SAFE2 ) THEN
313:                S = MAX( S, CABS1( WORK( I ) ) / RWORK( I ) )
314:             ELSE
315:                S = MAX( S, ( CABS1( WORK( I ) )+SAFE1 ) /
316:      $             ( RWORK( I )+SAFE1 ) )
317:             END IF
318:   190    CONTINUE
319:          BERR( J ) = S
320: *
321: *        Bound error from formula
322: *
323: *        norm(X - XTRUE) / norm(X) .le. FERR =
324: *        norm( abs(inv(op(A)))*
325: *           ( abs(R) + NZ*EPS*( abs(op(A))*abs(X)+abs(B) ))) / norm(X)
326: *
327: *        where
328: *          norm(Z) is the magnitude of the largest component of Z
329: *          inv(op(A)) is the inverse of op(A)
330: *          abs(Z) is the componentwise absolute value of the matrix or
331: *             vector Z
332: *          NZ is the maximum number of nonzeros in any row of A, plus 1
333: *          EPS is machine epsilon
334: *
335: *        The i-th component of abs(R)+NZ*EPS*(abs(op(A))*abs(X)+abs(B))
336: *        is incremented by SAFE1 if the i-th component of
337: *        abs(op(A))*abs(X) + abs(B) is less than SAFE2.
338: *
339: *        Use ZLACN2 to estimate the infinity-norm of the matrix
340: *           inv(op(A)) * diag(W),
341: *        where W = abs(R) + NZ*EPS*( abs(op(A))*abs(X)+abs(B) )))
342: *
343:          DO 200 I = 1, N
344:             IF( RWORK( I ).GT.SAFE2 ) THEN
345:                RWORK( I ) = CABS1( WORK( I ) ) + NZ*EPS*RWORK( I )
346:             ELSE
347:                RWORK( I ) = CABS1( WORK( I ) ) + NZ*EPS*RWORK( I ) +
348:      $                      SAFE1
349:             END IF
350:   200    CONTINUE
351: *
352:          KASE = 0
353:   210    CONTINUE
354:          CALL ZLACN2( N, WORK( N+1 ), WORK, FERR( J ), KASE, ISAVE )
355:          IF( KASE.NE.0 ) THEN
356:             IF( KASE.EQ.1 ) THEN
357: *
358: *              Multiply by diag(W)*inv(op(A)**H).
359: *
360:                CALL ZTPSV( UPLO, TRANST, DIAG, N, AP, WORK, 1 )
361:                DO 220 I = 1, N
362:                   WORK( I ) = RWORK( I )*WORK( I )
363:   220          CONTINUE
364:             ELSE
365: *
366: *              Multiply by inv(op(A))*diag(W).
367: *
368:                DO 230 I = 1, N
369:                   WORK( I ) = RWORK( I )*WORK( I )
370:   230          CONTINUE
371:                CALL ZTPSV( UPLO, TRANSN, DIAG, N, AP, WORK, 1 )
372:             END IF
373:             GO TO 210
374:          END IF
375: *
376: *        Normalize error.
377: *
378:          LSTRES = ZERO
379:          DO 240 I = 1, N
380:             LSTRES = MAX( LSTRES, CABS1( X( I, J ) ) )
381:   240    CONTINUE
382:          IF( LSTRES.NE.ZERO )
383:      $      FERR( J ) = FERR( J ) / LSTRES
384: *
385:   250 CONTINUE
386: *
387:       RETURN
388: *
389: *     End of ZTPRFS
390: *
391:       END
392: