001:       SUBROUTINE ZSYRK(UPLO,TRANS,N,K,ALPHA,A,LDA,BETA,C,LDC)
002: *     .. Scalar Arguments ..
003:       DOUBLE COMPLEX ALPHA,BETA
004:       INTEGER K,LDA,LDC,N
005:       CHARACTER TRANS,UPLO
006: *     ..
007: *     .. Array Arguments ..
008:       DOUBLE COMPLEX A(LDA,*),C(LDC,*)
009: *     ..
010: *
011: *  Purpose
012: *  =======
013: *
014: *  ZSYRK  performs one of the symmetric rank k operations
015: *
016: *     C := alpha*A*A' + beta*C,
017: *
018: *  or
019: *
020: *     C := alpha*A'*A + beta*C,
021: *
022: *  where  alpha and beta  are scalars,  C is an  n by n symmetric matrix
023: *  and  A  is an  n by k  matrix in the first case and a  k by n  matrix
024: *  in the second case.
025: *
026: *  Arguments
027: *  ==========
028: *
029: *  UPLO   - CHARACTER*1.
030: *           On  entry,   UPLO  specifies  whether  the  upper  or  lower
031: *           triangular  part  of the  array  C  is to be  referenced  as
032: *           follows:
033: *
034: *              UPLO = 'U' or 'u'   Only the  upper triangular part of  C
035: *                                  is to be referenced.
036: *
037: *              UPLO = 'L' or 'l'   Only the  lower triangular part of  C
038: *                                  is to be referenced.
039: *
040: *           Unchanged on exit.
041: *
042: *  TRANS  - CHARACTER*1.
043: *           On entry,  TRANS  specifies the operation to be performed as
044: *           follows:
045: *
046: *              TRANS = 'N' or 'n'   C := alpha*A*A' + beta*C.
047: *
048: *              TRANS = 'T' or 't'   C := alpha*A'*A + beta*C.
049: *
050: *           Unchanged on exit.
051: *
052: *  N      - INTEGER.
053: *           On entry,  N specifies the order of the matrix C.  N must be
054: *           at least zero.
055: *           Unchanged on exit.
056: *
057: *  K      - INTEGER.
058: *           On entry with  TRANS = 'N' or 'n',  K  specifies  the number
059: *           of  columns   of  the   matrix   A,   and  on   entry   with
060: *           TRANS = 'T' or 't',  K  specifies  the number of rows of the
061: *           matrix A.  K must be at least zero.
062: *           Unchanged on exit.
063: *
064: *  ALPHA  - COMPLEX*16      .
065: *           On entry, ALPHA specifies the scalar alpha.
066: *           Unchanged on exit.
067: *
068: *  A      - COMPLEX*16       array of DIMENSION ( LDA, ka ), where ka is
069: *           k  when  TRANS = 'N' or 'n',  and is  n  otherwise.
070: *           Before entry with  TRANS = 'N' or 'n',  the  leading  n by k
071: *           part of the array  A  must contain the matrix  A,  otherwise
072: *           the leading  k by n  part of the array  A  must contain  the
073: *           matrix A.
074: *           Unchanged on exit.
075: *
076: *  LDA    - INTEGER.
077: *           On entry, LDA specifies the first dimension of A as declared
078: *           in  the  calling  (sub)  program.   When  TRANS = 'N' or 'n'
079: *           then  LDA must be at least  max( 1, n ), otherwise  LDA must
080: *           be at least  max( 1, k ).
081: *           Unchanged on exit.
082: *
083: *  BETA   - COMPLEX*16      .
084: *           On entry, BETA specifies the scalar beta.
085: *           Unchanged on exit.
086: *
087: *  C      - COMPLEX*16       array of DIMENSION ( LDC, n ).
088: *           Before entry  with  UPLO = 'U' or 'u',  the leading  n by n
089: *           upper triangular part of the array C must contain the upper
090: *           triangular part  of the  symmetric matrix  and the strictly
091: *           lower triangular part of C is not referenced.  On exit, the
092: *           upper triangular part of the array  C is overwritten by the
093: *           upper triangular part of the updated matrix.
094: *           Before entry  with  UPLO = 'L' or 'l',  the leading  n by n
095: *           lower triangular part of the array C must contain the lower
096: *           triangular part  of the  symmetric matrix  and the strictly
097: *           upper triangular part of C is not referenced.  On exit, the
098: *           lower triangular part of the array  C is overwritten by the
099: *           lower triangular part of the updated matrix.
100: *
101: *  LDC    - INTEGER.
102: *           On entry, LDC specifies the first dimension of C as declared
103: *           in  the  calling  (sub)  program.   LDC  must  be  at  least
104: *           max( 1, n ).
105: *           Unchanged on exit.
106: *
107: *
108: *  Level 3 Blas routine.
109: *
110: *  -- Written on 8-February-1989.
111: *     Jack Dongarra, Argonne National Laboratory.
112: *     Iain Duff, AERE Harwell.
113: *     Jeremy Du Croz, Numerical Algorithms Group Ltd.
114: *     Sven Hammarling, Numerical Algorithms Group Ltd.
115: *
116: *
117: *     .. External Functions ..
118:       LOGICAL LSAME
119:       EXTERNAL LSAME
120: *     ..
121: *     .. External Subroutines ..
122:       EXTERNAL XERBLA
123: *     ..
124: *     .. Intrinsic Functions ..
125:       INTRINSIC MAX
126: *     ..
127: *     .. Local Scalars ..
128:       DOUBLE COMPLEX TEMP
129:       INTEGER I,INFO,J,L,NROWA
130:       LOGICAL UPPER
131: *     ..
132: *     .. Parameters ..
133:       DOUBLE COMPLEX ONE
134:       PARAMETER (ONE= (1.0D+0,0.0D+0))
135:       DOUBLE COMPLEX ZERO
136:       PARAMETER (ZERO= (0.0D+0,0.0D+0))
137: *     ..
138: *
139: *     Test the input parameters.
140: *
141:       IF (LSAME(TRANS,'N')) THEN
142:           NROWA = N
143:       ELSE
144:           NROWA = K
145:       END IF
146:       UPPER = LSAME(UPLO,'U')
147: *
148:       INFO = 0
149:       IF ((.NOT.UPPER) .AND. (.NOT.LSAME(UPLO,'L'))) THEN
150:           INFO = 1
151:       ELSE IF ((.NOT.LSAME(TRANS,'N')) .AND.
152:      +         (.NOT.LSAME(TRANS,'T'))) THEN
153:           INFO = 2
154:       ELSE IF (N.LT.0) THEN
155:           INFO = 3
156:       ELSE IF (K.LT.0) THEN
157:           INFO = 4
158:       ELSE IF (LDA.LT.MAX(1,NROWA)) THEN
159:           INFO = 7
160:       ELSE IF (LDC.LT.MAX(1,N)) THEN
161:           INFO = 10
162:       END IF
163:       IF (INFO.NE.0) THEN
164:           CALL XERBLA('ZSYRK ',INFO)
165:           RETURN
166:       END IF
167: *
168: *     Quick return if possible.
169: *
170:       IF ((N.EQ.0) .OR. (((ALPHA.EQ.ZERO).OR.
171:      +    (K.EQ.0)).AND. (BETA.EQ.ONE))) RETURN
172: *
173: *     And when  alpha.eq.zero.
174: *
175:       IF (ALPHA.EQ.ZERO) THEN
176:           IF (UPPER) THEN
177:               IF (BETA.EQ.ZERO) THEN
178:                   DO 20 J = 1,N
179:                       DO 10 I = 1,J
180:                           C(I,J) = ZERO
181:    10                 CONTINUE
182:    20             CONTINUE
183:               ELSE
184:                   DO 40 J = 1,N
185:                       DO 30 I = 1,J
186:                           C(I,J) = BETA*C(I,J)
187:    30                 CONTINUE
188:    40             CONTINUE
189:               END IF
190:           ELSE
191:               IF (BETA.EQ.ZERO) THEN
192:                   DO 60 J = 1,N
193:                       DO 50 I = J,N
194:                           C(I,J) = ZERO
195:    50                 CONTINUE
196:    60             CONTINUE
197:               ELSE
198:                   DO 80 J = 1,N
199:                       DO 70 I = J,N
200:                           C(I,J) = BETA*C(I,J)
201:    70                 CONTINUE
202:    80             CONTINUE
203:               END IF
204:           END IF
205:           RETURN
206:       END IF
207: *
208: *     Start the operations.
209: *
210:       IF (LSAME(TRANS,'N')) THEN
211: *
212: *        Form  C := alpha*A*A' + beta*C.
213: *
214:           IF (UPPER) THEN
215:               DO 130 J = 1,N
216:                   IF (BETA.EQ.ZERO) THEN
217:                       DO 90 I = 1,J
218:                           C(I,J) = ZERO
219:    90                 CONTINUE
220:                   ELSE IF (BETA.NE.ONE) THEN
221:                       DO 100 I = 1,J
222:                           C(I,J) = BETA*C(I,J)
223:   100                 CONTINUE
224:                   END IF
225:                   DO 120 L = 1,K
226:                       IF (A(J,L).NE.ZERO) THEN
227:                           TEMP = ALPHA*A(J,L)
228:                           DO 110 I = 1,J
229:                               C(I,J) = C(I,J) + TEMP*A(I,L)
230:   110                     CONTINUE
231:                       END IF
232:   120             CONTINUE
233:   130         CONTINUE
234:           ELSE
235:               DO 180 J = 1,N
236:                   IF (BETA.EQ.ZERO) THEN
237:                       DO 140 I = J,N
238:                           C(I,J) = ZERO
239:   140                 CONTINUE
240:                   ELSE IF (BETA.NE.ONE) THEN
241:                       DO 150 I = J,N
242:                           C(I,J) = BETA*C(I,J)
243:   150                 CONTINUE
244:                   END IF
245:                   DO 170 L = 1,K
246:                       IF (A(J,L).NE.ZERO) THEN
247:                           TEMP = ALPHA*A(J,L)
248:                           DO 160 I = J,N
249:                               C(I,J) = C(I,J) + TEMP*A(I,L)
250:   160                     CONTINUE
251:                       END IF
252:   170             CONTINUE
253:   180         CONTINUE
254:           END IF
255:       ELSE
256: *
257: *        Form  C := alpha*A'*A + beta*C.
258: *
259:           IF (UPPER) THEN
260:               DO 210 J = 1,N
261:                   DO 200 I = 1,J
262:                       TEMP = ZERO
263:                       DO 190 L = 1,K
264:                           TEMP = TEMP + A(L,I)*A(L,J)
265:   190                 CONTINUE
266:                       IF (BETA.EQ.ZERO) THEN
267:                           C(I,J) = ALPHA*TEMP
268:                       ELSE
269:                           C(I,J) = ALPHA*TEMP + BETA*C(I,J)
270:                       END IF
271:   200             CONTINUE
272:   210         CONTINUE
273:           ELSE
274:               DO 240 J = 1,N
275:                   DO 230 I = J,N
276:                       TEMP = ZERO
277:                       DO 220 L = 1,K
278:                           TEMP = TEMP + A(L,I)*A(L,J)
279:   220                 CONTINUE
280:                       IF (BETA.EQ.ZERO) THEN
281:                           C(I,J) = ALPHA*TEMP
282:                       ELSE
283:                           C(I,J) = ALPHA*TEMP + BETA*C(I,J)
284:                       END IF
285:   230             CONTINUE
286:   240         CONTINUE
287:           END IF
288:       END IF
289: *
290:       RETURN
291: *
292: *     End of ZSYRK .
293: *
294:       END
295: