001:       SUBROUTINE ZLASR( SIDE, PIVOT, DIRECT, M, N, C, S, A, LDA )
002: *
003: *  -- LAPACK auxiliary routine (version 3.2) --
004: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
005: *     November 2006
006: *
007: *     .. Scalar Arguments ..
008:       CHARACTER          DIRECT, PIVOT, SIDE
009:       INTEGER            LDA, M, N
010: *     ..
011: *     .. Array Arguments ..
012:       DOUBLE PRECISION   C( * ), S( * )
013:       COMPLEX*16         A( LDA, * )
014: *     ..
015: *
016: *  Purpose
017: *  =======
018: *
019: *  ZLASR applies a sequence of real plane rotations to a complex matrix
020: *  A, from either the left or the right.
021: *
022: *  When SIDE = 'L', the transformation takes the form
023: *
024: *     A := P*A
025: *
026: *  and when SIDE = 'R', the transformation takes the form
027: *
028: *     A := A*P**T
029: *
030: *  where P is an orthogonal matrix consisting of a sequence of z plane
031: *  rotations, with z = M when SIDE = 'L' and z = N when SIDE = 'R',
032: *  and P**T is the transpose of P.
033: *  
034: *  When DIRECT = 'F' (Forward sequence), then
035: *  
036: *     P = P(z-1) * ... * P(2) * P(1)
037: *  
038: *  and when DIRECT = 'B' (Backward sequence), then
039: *  
040: *     P = P(1) * P(2) * ... * P(z-1)
041: *  
042: *  where P(k) is a plane rotation matrix defined by the 2-by-2 rotation
043: *  
044: *     R(k) = (  c(k)  s(k) )
045: *          = ( -s(k)  c(k) ).
046: *  
047: *  When PIVOT = 'V' (Variable pivot), the rotation is performed
048: *  for the plane (k,k+1), i.e., P(k) has the form
049: *  
050: *     P(k) = (  1                                            )
051: *            (       ...                                     )
052: *            (              1                                )
053: *            (                   c(k)  s(k)                  )
054: *            (                  -s(k)  c(k)                  )
055: *            (                                1              )
056: *            (                                     ...       )
057: *            (                                            1  )
058: *  
059: *  where R(k) appears as a rank-2 modification to the identity matrix in
060: *  rows and columns k and k+1.
061: *  
062: *  When PIVOT = 'T' (Top pivot), the rotation is performed for the
063: *  plane (1,k+1), so P(k) has the form
064: *  
065: *     P(k) = (  c(k)                    s(k)                 )
066: *            (         1                                     )
067: *            (              ...                              )
068: *            (                     1                         )
069: *            ( -s(k)                    c(k)                 )
070: *            (                                 1             )
071: *            (                                      ...      )
072: *            (                                             1 )
073: *  
074: *  where R(k) appears in rows and columns 1 and k+1.
075: *  
076: *  Similarly, when PIVOT = 'B' (Bottom pivot), the rotation is
077: *  performed for the plane (k,z), giving P(k) the form
078: *  
079: *     P(k) = ( 1                                             )
080: *            (      ...                                      )
081: *            (             1                                 )
082: *            (                  c(k)                    s(k) )
083: *            (                         1                     )
084: *            (                              ...              )
085: *            (                                     1         )
086: *            (                 -s(k)                    c(k) )
087: *  
088: *  where R(k) appears in rows and columns k and z.  The rotations are
089: *  performed without ever forming P(k) explicitly.
090: *
091: *  Arguments
092: *  =========
093: *
094: *  SIDE    (input) CHARACTER*1
095: *          Specifies whether the plane rotation matrix P is applied to
096: *          A on the left or the right.
097: *          = 'L':  Left, compute A := P*A
098: *          = 'R':  Right, compute A:= A*P**T
099: *
100: *  PIVOT   (input) CHARACTER*1
101: *          Specifies the plane for which P(k) is a plane rotation
102: *          matrix.
103: *          = 'V':  Variable pivot, the plane (k,k+1)
104: *          = 'T':  Top pivot, the plane (1,k+1)
105: *          = 'B':  Bottom pivot, the plane (k,z)
106: *
107: *  DIRECT  (input) CHARACTER*1
108: *          Specifies whether P is a forward or backward sequence of
109: *          plane rotations.
110: *          = 'F':  Forward, P = P(z-1)*...*P(2)*P(1)
111: *          = 'B':  Backward, P = P(1)*P(2)*...*P(z-1)
112: *
113: *  M       (input) INTEGER
114: *          The number of rows of the matrix A.  If m <= 1, an immediate
115: *          return is effected.
116: *
117: *  N       (input) INTEGER
118: *          The number of columns of the matrix A.  If n <= 1, an
119: *          immediate return is effected.
120: *
121: *  C       (input) DOUBLE PRECISION array, dimension
122: *                  (M-1) if SIDE = 'L'
123: *                  (N-1) if SIDE = 'R'
124: *          The cosines c(k) of the plane rotations.
125: *
126: *  S       (input) DOUBLE PRECISION array, dimension
127: *                  (M-1) if SIDE = 'L'
128: *                  (N-1) if SIDE = 'R'
129: *          The sines s(k) of the plane rotations.  The 2-by-2 plane
130: *          rotation part of the matrix P(k), R(k), has the form
131: *          R(k) = (  c(k)  s(k) )
132: *                 ( -s(k)  c(k) ).
133: *
134: *  A       (input/output) COMPLEX*16 array, dimension (LDA,N)
135: *          The M-by-N matrix A.  On exit, A is overwritten by P*A if
136: *          SIDE = 'R' or by A*P**T if SIDE = 'L'.
137: *
138: *  LDA     (input) INTEGER
139: *          The leading dimension of the array A.  LDA >= max(1,M).
140: *
141: *  =====================================================================
142: *
143: *     .. Parameters ..
144:       DOUBLE PRECISION   ONE, ZERO
145:       PARAMETER          ( ONE = 1.0D+0, ZERO = 0.0D+0 )
146: *     ..
147: *     .. Local Scalars ..
148:       INTEGER            I, INFO, J
149:       DOUBLE PRECISION   CTEMP, STEMP
150:       COMPLEX*16         TEMP
151: *     ..
152: *     .. Intrinsic Functions ..
153:       INTRINSIC          MAX
154: *     ..
155: *     .. External Functions ..
156:       LOGICAL            LSAME
157:       EXTERNAL           LSAME
158: *     ..
159: *     .. External Subroutines ..
160:       EXTERNAL           XERBLA
161: *     ..
162: *     .. Executable Statements ..
163: *
164: *     Test the input parameters
165: *
166:       INFO = 0
167:       IF( .NOT.( LSAME( SIDE, 'L' ) .OR. LSAME( SIDE, 'R' ) ) ) THEN
168:          INFO = 1
169:       ELSE IF( .NOT.( LSAME( PIVOT, 'V' ) .OR. LSAME( PIVOT,
170:      $         'T' ) .OR. LSAME( PIVOT, 'B' ) ) ) THEN
171:          INFO = 2
172:       ELSE IF( .NOT.( LSAME( DIRECT, 'F' ) .OR. LSAME( DIRECT, 'B' ) ) )
173:      $          THEN
174:          INFO = 3
175:       ELSE IF( M.LT.0 ) THEN
176:          INFO = 4
177:       ELSE IF( N.LT.0 ) THEN
178:          INFO = 5
179:       ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
180:          INFO = 9
181:       END IF
182:       IF( INFO.NE.0 ) THEN
183:          CALL XERBLA( 'ZLASR ', INFO )
184:          RETURN
185:       END IF
186: *
187: *     Quick return if possible
188: *
189:       IF( ( M.EQ.0 ) .OR. ( N.EQ.0 ) )
190:      $   RETURN
191:       IF( LSAME( SIDE, 'L' ) ) THEN
192: *
193: *        Form  P * A
194: *
195:          IF( LSAME( PIVOT, 'V' ) ) THEN
196:             IF( LSAME( DIRECT, 'F' ) ) THEN
197:                DO 20 J = 1, M - 1
198:                   CTEMP = C( J )
199:                   STEMP = S( J )
200:                   IF( ( CTEMP.NE.ONE ) .OR. ( STEMP.NE.ZERO ) ) THEN
201:                      DO 10 I = 1, N
202:                         TEMP = A( J+1, I )
203:                         A( J+1, I ) = CTEMP*TEMP - STEMP*A( J, I )
204:                         A( J, I ) = STEMP*TEMP + CTEMP*A( J, I )
205:    10                CONTINUE
206:                   END IF
207:    20          CONTINUE
208:             ELSE IF( LSAME( DIRECT, 'B' ) ) THEN
209:                DO 40 J = M - 1, 1, -1
210:                   CTEMP = C( J )
211:                   STEMP = S( J )
212:                   IF( ( CTEMP.NE.ONE ) .OR. ( STEMP.NE.ZERO ) ) THEN
213:                      DO 30 I = 1, N
214:                         TEMP = A( J+1, I )
215:                         A( J+1, I ) = CTEMP*TEMP - STEMP*A( J, I )
216:                         A( J, I ) = STEMP*TEMP + CTEMP*A( J, I )
217:    30                CONTINUE
218:                   END IF
219:    40          CONTINUE
220:             END IF
221:          ELSE IF( LSAME( PIVOT, 'T' ) ) THEN
222:             IF( LSAME( DIRECT, 'F' ) ) THEN
223:                DO 60 J = 2, M
224:                   CTEMP = C( J-1 )
225:                   STEMP = S( J-1 )
226:                   IF( ( CTEMP.NE.ONE ) .OR. ( STEMP.NE.ZERO ) ) THEN
227:                      DO 50 I = 1, N
228:                         TEMP = A( J, I )
229:                         A( J, I ) = CTEMP*TEMP - STEMP*A( 1, I )
230:                         A( 1, I ) = STEMP*TEMP + CTEMP*A( 1, I )
231:    50                CONTINUE
232:                   END IF
233:    60          CONTINUE
234:             ELSE IF( LSAME( DIRECT, 'B' ) ) THEN
235:                DO 80 J = M, 2, -1
236:                   CTEMP = C( J-1 )
237:                   STEMP = S( J-1 )
238:                   IF( ( CTEMP.NE.ONE ) .OR. ( STEMP.NE.ZERO ) ) THEN
239:                      DO 70 I = 1, N
240:                         TEMP = A( J, I )
241:                         A( J, I ) = CTEMP*TEMP - STEMP*A( 1, I )
242:                         A( 1, I ) = STEMP*TEMP + CTEMP*A( 1, I )
243:    70                CONTINUE
244:                   END IF
245:    80          CONTINUE
246:             END IF
247:          ELSE IF( LSAME( PIVOT, 'B' ) ) THEN
248:             IF( LSAME( DIRECT, 'F' ) ) THEN
249:                DO 100 J = 1, M - 1
250:                   CTEMP = C( J )
251:                   STEMP = S( J )
252:                   IF( ( CTEMP.NE.ONE ) .OR. ( STEMP.NE.ZERO ) ) THEN
253:                      DO 90 I = 1, N
254:                         TEMP = A( J, I )
255:                         A( J, I ) = STEMP*A( M, I ) + CTEMP*TEMP
256:                         A( M, I ) = CTEMP*A( M, I ) - STEMP*TEMP
257:    90                CONTINUE
258:                   END IF
259:   100          CONTINUE
260:             ELSE IF( LSAME( DIRECT, 'B' ) ) THEN
261:                DO 120 J = M - 1, 1, -1
262:                   CTEMP = C( J )
263:                   STEMP = S( J )
264:                   IF( ( CTEMP.NE.ONE ) .OR. ( STEMP.NE.ZERO ) ) THEN
265:                      DO 110 I = 1, N
266:                         TEMP = A( J, I )
267:                         A( J, I ) = STEMP*A( M, I ) + CTEMP*TEMP
268:                         A( M, I ) = CTEMP*A( M, I ) - STEMP*TEMP
269:   110                CONTINUE
270:                   END IF
271:   120          CONTINUE
272:             END IF
273:          END IF
274:       ELSE IF( LSAME( SIDE, 'R' ) ) THEN
275: *
276: *        Form A * P'
277: *
278:          IF( LSAME( PIVOT, 'V' ) ) THEN
279:             IF( LSAME( DIRECT, 'F' ) ) THEN
280:                DO 140 J = 1, N - 1
281:                   CTEMP = C( J )
282:                   STEMP = S( J )
283:                   IF( ( CTEMP.NE.ONE ) .OR. ( STEMP.NE.ZERO ) ) THEN
284:                      DO 130 I = 1, M
285:                         TEMP = A( I, J+1 )
286:                         A( I, J+1 ) = CTEMP*TEMP - STEMP*A( I, J )
287:                         A( I, J ) = STEMP*TEMP + CTEMP*A( I, J )
288:   130                CONTINUE
289:                   END IF
290:   140          CONTINUE
291:             ELSE IF( LSAME( DIRECT, 'B' ) ) THEN
292:                DO 160 J = N - 1, 1, -1
293:                   CTEMP = C( J )
294:                   STEMP = S( J )
295:                   IF( ( CTEMP.NE.ONE ) .OR. ( STEMP.NE.ZERO ) ) THEN
296:                      DO 150 I = 1, M
297:                         TEMP = A( I, J+1 )
298:                         A( I, J+1 ) = CTEMP*TEMP - STEMP*A( I, J )
299:                         A( I, J ) = STEMP*TEMP + CTEMP*A( I, J )
300:   150                CONTINUE
301:                   END IF
302:   160          CONTINUE
303:             END IF
304:          ELSE IF( LSAME( PIVOT, 'T' ) ) THEN
305:             IF( LSAME( DIRECT, 'F' ) ) THEN
306:                DO 180 J = 2, N
307:                   CTEMP = C( J-1 )
308:                   STEMP = S( J-1 )
309:                   IF( ( CTEMP.NE.ONE ) .OR. ( STEMP.NE.ZERO ) ) THEN
310:                      DO 170 I = 1, M
311:                         TEMP = A( I, J )
312:                         A( I, J ) = CTEMP*TEMP - STEMP*A( I, 1 )
313:                         A( I, 1 ) = STEMP*TEMP + CTEMP*A( I, 1 )
314:   170                CONTINUE
315:                   END IF
316:   180          CONTINUE
317:             ELSE IF( LSAME( DIRECT, 'B' ) ) THEN
318:                DO 200 J = N, 2, -1
319:                   CTEMP = C( J-1 )
320:                   STEMP = S( J-1 )
321:                   IF( ( CTEMP.NE.ONE ) .OR. ( STEMP.NE.ZERO ) ) THEN
322:                      DO 190 I = 1, M
323:                         TEMP = A( I, J )
324:                         A( I, J ) = CTEMP*TEMP - STEMP*A( I, 1 )
325:                         A( I, 1 ) = STEMP*TEMP + CTEMP*A( I, 1 )
326:   190                CONTINUE
327:                   END IF
328:   200          CONTINUE
329:             END IF
330:          ELSE IF( LSAME( PIVOT, 'B' ) ) THEN
331:             IF( LSAME( DIRECT, 'F' ) ) THEN
332:                DO 220 J = 1, N - 1
333:                   CTEMP = C( J )
334:                   STEMP = S( J )
335:                   IF( ( CTEMP.NE.ONE ) .OR. ( STEMP.NE.ZERO ) ) THEN
336:                      DO 210 I = 1, M
337:                         TEMP = A( I, J )
338:                         A( I, J ) = STEMP*A( I, N ) + CTEMP*TEMP
339:                         A( I, N ) = CTEMP*A( I, N ) - STEMP*TEMP
340:   210                CONTINUE
341:                   END IF
342:   220          CONTINUE
343:             ELSE IF( LSAME( DIRECT, 'B' ) ) THEN
344:                DO 240 J = N - 1, 1, -1
345:                   CTEMP = C( J )
346:                   STEMP = S( J )
347:                   IF( ( CTEMP.NE.ONE ) .OR. ( STEMP.NE.ZERO ) ) THEN
348:                      DO 230 I = 1, M
349:                         TEMP = A( I, J )
350:                         A( I, J ) = STEMP*A( I, N ) + CTEMP*TEMP
351:                         A( I, N ) = CTEMP*A( I, N ) - STEMP*TEMP
352:   230                CONTINUE
353:                   END IF
354:   240          CONTINUE
355:             END IF
356:          END IF
357:       END IF
358: *
359:       RETURN
360: *
361: *     End of ZLASR
362: *
363:       END
364: