001:       SUBROUTINE ZLAGS2( UPPER, A1, A2, A3, B1, B2, B3, CSU, SNU, CSV,
002:      $                   SNV, CSQ, SNQ )
003: *
004: *  -- LAPACK auxiliary routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       LOGICAL            UPPER
010:       DOUBLE PRECISION   A1, A3, B1, B3, CSQ, CSU, CSV
011:       COMPLEX*16         A2, B2, SNQ, SNU, SNV
012: *     ..
013: *
014: *  Purpose
015: *  =======
016: *
017: *  ZLAGS2 computes 2-by-2 unitary matrices U, V and Q, such
018: *  that if ( UPPER ) then
019: *
020: *            U'*A*Q = U'*( A1 A2 )*Q = ( x  0  )
021: *                        ( 0  A3 )     ( x  x  )
022: *  and
023: *            V'*B*Q = V'*( B1 B2 )*Q = ( x  0  )
024: *                        ( 0  B3 )     ( x  x  )
025: *
026: *  or if ( .NOT.UPPER ) then
027: *
028: *            U'*A*Q = U'*( A1 0  )*Q = ( x  x  )
029: *                        ( A2 A3 )     ( 0  x  )
030: *  and
031: *            V'*B*Q = V'*( B1 0  )*Q = ( x  x  )
032: *                        ( B2 B3 )     ( 0  x  )
033: *  where
034: *
035: *    U = (     CSU      SNU ), V = (     CSV     SNV ),
036: *        ( -CONJG(SNU)  CSU )      ( -CONJG(SNV) CSV )
037: *
038: *    Q = (     CSQ      SNQ )
039: *        ( -CONJG(SNQ)  CSQ )
040: *
041: *  Z' denotes the conjugate transpose of Z.
042: *
043: *  The rows of the transformed A and B are parallel. Moreover, if the
044: *  input 2-by-2 matrix A is not zero, then the transformed (1,1) entry
045: *  of A is not zero. If the input matrices A and B are both not zero,
046: *  then the transformed (2,2) element of B is not zero, except when the
047: *  first rows of input A and B are parallel and the second rows are
048: *  zero.
049: *
050: *  Arguments
051: *  =========
052: *
053: *  UPPER   (input) LOGICAL
054: *          = .TRUE.: the input matrices A and B are upper triangular.
055: *          = .FALSE.: the input matrices A and B are lower triangular.
056: *
057: *  A1      (input) DOUBLE PRECISION
058: *  A2      (input) COMPLEX*16
059: *  A3      (input) DOUBLE PRECISION
060: *          On entry, A1, A2 and A3 are elements of the input 2-by-2
061: *          upper (lower) triangular matrix A.
062: *
063: *  B1      (input) DOUBLE PRECISION
064: *  B2      (input) COMPLEX*16
065: *  B3      (input) DOUBLE PRECISION
066: *          On entry, B1, B2 and B3 are elements of the input 2-by-2
067: *          upper (lower) triangular matrix B.
068: *
069: *  CSU     (output) DOUBLE PRECISION
070: *  SNU     (output) COMPLEX*16
071: *          The desired unitary matrix U.
072: *
073: *  CSV     (output) DOUBLE PRECISION
074: *  SNV     (output) COMPLEX*16
075: *          The desired unitary matrix V.
076: *
077: *  CSQ     (output) DOUBLE PRECISION
078: *  SNQ     (output) COMPLEX*16
079: *          The desired unitary matrix Q.
080: *
081: *  =====================================================================
082: *
083: *     .. Parameters ..
084:       DOUBLE PRECISION   ZERO, ONE
085:       PARAMETER          ( ZERO = 0.0D+0, ONE = 1.0D+0 )
086: *     ..
087: *     .. Local Scalars ..
088:       DOUBLE PRECISION   A, AUA11, AUA12, AUA21, AUA22, AVB12, AVB11, 
089:      $                   AVB21, AVB22, CSL, CSR, D, FB, FC, S1, S2, 
090:      $                   SNL, SNR, UA11R, UA22R, VB11R, VB22R
091:       COMPLEX*16         B, C, D1, R, T, UA11, UA12, UA21, UA22, VB11,
092:      $                   VB12, VB21, VB22
093: *     ..
094: *     .. External Subroutines ..
095:       EXTERNAL           DLASV2, ZLARTG
096: *     ..
097: *     .. Intrinsic Functions ..
098:       INTRINSIC          ABS, DBLE, DCMPLX, DCONJG, DIMAG
099: *     ..
100: *     .. Statement Functions ..
101:       DOUBLE PRECISION   ABS1
102: *     ..
103: *     .. Statement Function definitions ..
104:       ABS1( T ) = ABS( DBLE( T ) ) + ABS( DIMAG( T ) )
105: *     ..
106: *     .. Executable Statements ..
107: *
108:       IF( UPPER ) THEN
109: *
110: *        Input matrices A and B are upper triangular matrices
111: *
112: *        Form matrix C = A*adj(B) = ( a b )
113: *                                   ( 0 d )
114: *
115:          A = A1*B3
116:          D = A3*B1
117:          B = A2*B1 - A1*B2
118:          FB = ABS( B )
119: *
120: *        Transform complex 2-by-2 matrix C to real matrix by unitary
121: *        diagonal matrix diag(1,D1).
122: *
123:          D1 = ONE
124:          IF( FB.NE.ZERO )
125:      $      D1 = B / FB
126: *
127: *        The SVD of real 2 by 2 triangular C
128: *
129: *         ( CSL -SNL )*( A B )*(  CSR  SNR ) = ( R 0 )
130: *         ( SNL  CSL ) ( 0 D ) ( -SNR  CSR )   ( 0 T )
131: *
132:          CALL DLASV2( A, FB, D, S1, S2, SNR, CSR, SNL, CSL )
133: *
134:          IF( ABS( CSL ).GE.ABS( SNL ) .OR. ABS( CSR ).GE.ABS( SNR ) )
135:      $        THEN
136: *
137: *           Compute the (1,1) and (1,2) elements of U'*A and V'*B,
138: *           and (1,2) element of |U|'*|A| and |V|'*|B|.
139: *
140:             UA11R = CSL*A1
141:             UA12 = CSL*A2 + D1*SNL*A3
142: *
143:             VB11R = CSR*B1
144:             VB12 = CSR*B2 + D1*SNR*B3
145: *
146:             AUA12 = ABS( CSL )*ABS1( A2 ) + ABS( SNL )*ABS( A3 )
147:             AVB12 = ABS( CSR )*ABS1( B2 ) + ABS( SNR )*ABS( B3 )
148: *
149: *           zero (1,2) elements of U'*A and V'*B
150: *
151:             IF( ( ABS( UA11R )+ABS1( UA12 ) ).EQ.ZERO ) THEN
152:                CALL ZLARTG( -DCMPLX( VB11R ), DCONJG( VB12 ), CSQ, SNQ,
153:      $                      R )
154:             ELSE IF( ( ABS( VB11R )+ABS1( VB12 ) ).EQ.ZERO ) THEN
155:                CALL ZLARTG( -DCMPLX( UA11R ), DCONJG( UA12 ), CSQ, SNQ,
156:      $                      R )
157:             ELSE IF( AUA12 / ( ABS( UA11R )+ABS1( UA12 ) ).LE.AVB12 /
158:      $               ( ABS( VB11R )+ABS1( VB12 ) ) ) THEN
159:                CALL ZLARTG( -DCMPLX( UA11R ), DCONJG( UA12 ), CSQ, SNQ,
160:      $                      R )
161:             ELSE
162:                CALL ZLARTG( -DCMPLX( VB11R ), DCONJG( VB12 ), CSQ, SNQ,
163:      $                      R )
164:             END IF
165: *
166:             CSU = CSL
167:             SNU = -D1*SNL
168:             CSV = CSR
169:             SNV = -D1*SNR
170: *
171:          ELSE
172: *
173: *           Compute the (2,1) and (2,2) elements of U'*A and V'*B,
174: *           and (2,2) element of |U|'*|A| and |V|'*|B|.
175: *
176:             UA21 = -DCONJG( D1 )*SNL*A1
177:             UA22 = -DCONJG( D1 )*SNL*A2 + CSL*A3
178: *
179:             VB21 = -DCONJG( D1 )*SNR*B1
180:             VB22 = -DCONJG( D1 )*SNR*B2 + CSR*B3
181: *
182:             AUA22 = ABS( SNL )*ABS1( A2 ) + ABS( CSL )*ABS( A3 )
183:             AVB22 = ABS( SNR )*ABS1( B2 ) + ABS( CSR )*ABS( B3 )
184: *
185: *           zero (2,2) elements of U'*A and V'*B, and then swap.
186: *
187:             IF( ( ABS1( UA21 )+ABS1( UA22 ) ).EQ.ZERO ) THEN
188:                CALL ZLARTG( -DCONJG( VB21 ), DCONJG( VB22 ), CSQ, SNQ,
189:      $                      R )
190:             ELSE IF( ( ABS1( VB21 )+ABS( VB22 ) ).EQ.ZERO ) THEN
191:                CALL ZLARTG( -DCONJG( UA21 ), DCONJG( UA22 ), CSQ, SNQ,
192:      $                      R )
193:             ELSE IF( AUA22 / ( ABS1( UA21 )+ABS1( UA22 ) ).LE.AVB22 /
194:      $               ( ABS1( VB21 )+ABS1( VB22 ) ) ) THEN
195:                CALL ZLARTG( -DCONJG( UA21 ), DCONJG( UA22 ), CSQ, SNQ,
196:      $                      R )
197:             ELSE
198:                CALL ZLARTG( -DCONJG( VB21 ), DCONJG( VB22 ), CSQ, SNQ,
199:      $                      R )
200:             END IF
201: *
202:             CSU = SNL
203:             SNU = D1*CSL
204:             CSV = SNR
205:             SNV = D1*CSR
206: *
207:          END IF
208: *
209:       ELSE
210: *
211: *        Input matrices A and B are lower triangular matrices
212: *
213: *        Form matrix C = A*adj(B) = ( a 0 )
214: *                                   ( c d )
215: *
216:          A = A1*B3
217:          D = A3*B1
218:          C = A2*B3 - A3*B2
219:          FC = ABS( C )
220: *
221: *        Transform complex 2-by-2 matrix C to real matrix by unitary
222: *        diagonal matrix diag(d1,1).
223: *
224:          D1 = ONE
225:          IF( FC.NE.ZERO )
226:      $      D1 = C / FC
227: *
228: *        The SVD of real 2 by 2 triangular C
229: *
230: *         ( CSL -SNL )*( A 0 )*(  CSR  SNR ) = ( R 0 )
231: *         ( SNL  CSL ) ( C D ) ( -SNR  CSR )   ( 0 T )
232: *
233:          CALL DLASV2( A, FC, D, S1, S2, SNR, CSR, SNL, CSL )
234: *
235:          IF( ABS( CSR ).GE.ABS( SNR ) .OR. ABS( CSL ).GE.ABS( SNL ) )
236:      $        THEN
237: *
238: *           Compute the (2,1) and (2,2) elements of U'*A and V'*B,
239: *           and (2,1) element of |U|'*|A| and |V|'*|B|.
240: *
241:             UA21 = -D1*SNR*A1 + CSR*A2
242:             UA22R = CSR*A3
243: *
244:             VB21 = -D1*SNL*B1 + CSL*B2
245:             VB22R = CSL*B3
246: *
247:             AUA21 = ABS( SNR )*ABS( A1 ) + ABS( CSR )*ABS1( A2 )
248:             AVB21 = ABS( SNL )*ABS( B1 ) + ABS( CSL )*ABS1( B2 )
249: *
250: *           zero (2,1) elements of U'*A and V'*B.
251: *
252:             IF( ( ABS1( UA21 )+ABS( UA22R ) ).EQ.ZERO ) THEN
253:                CALL ZLARTG( DCMPLX( VB22R ), VB21, CSQ, SNQ, R )
254:             ELSE IF( ( ABS1( VB21 )+ABS( VB22R ) ).EQ.ZERO ) THEN
255:                CALL ZLARTG( DCMPLX( UA22R ), UA21, CSQ, SNQ, R )
256:             ELSE IF( AUA21 / ( ABS1( UA21 )+ABS( UA22R ) ).LE.AVB21 /
257:      $               ( ABS1( VB21 )+ABS( VB22R ) ) ) THEN
258:                CALL ZLARTG( DCMPLX( UA22R ), UA21, CSQ, SNQ, R )
259:             ELSE
260:                CALL ZLARTG( DCMPLX( VB22R ), VB21, CSQ, SNQ, R )
261:             END IF
262: *
263:             CSU = CSR
264:             SNU = -DCONJG( D1 )*SNR
265:             CSV = CSL
266:             SNV = -DCONJG( D1 )*SNL
267: *
268:          ELSE
269: *
270: *           Compute the (1,1) and (1,2) elements of U'*A and V'*B,
271: *           and (1,1) element of |U|'*|A| and |V|'*|B|.
272: *
273:             UA11 = CSR*A1 + DCONJG( D1 )*SNR*A2
274:             UA12 = DCONJG( D1 )*SNR*A3
275: *
276:             VB11 = CSL*B1 + DCONJG( D1 )*SNL*B2
277:             VB12 = DCONJG( D1 )*SNL*B3
278: *
279:             AUA11 = ABS( CSR )*ABS( A1 ) + ABS( SNR )*ABS1( A2 )
280:             AVB11 = ABS( CSL )*ABS( B1 ) + ABS( SNL )*ABS1( B2 )
281: *
282: *           zero (1,1) elements of U'*A and V'*B, and then swap.
283: *
284:             IF( ( ABS1( UA11 )+ABS1( UA12 ) ).EQ.ZERO ) THEN
285:                CALL ZLARTG( VB12, VB11, CSQ, SNQ, R )
286:             ELSE IF( ( ABS1( VB11 )+ABS1( VB12 ) ).EQ.ZERO ) THEN
287:                CALL ZLARTG( UA12, UA11, CSQ, SNQ, R )
288:             ELSE IF( AUA11 / ( ABS1( UA11 )+ABS1( UA12 ) ).LE.AVB11 /
289:      $               ( ABS1( VB11 )+ABS1( VB12 ) ) ) THEN
290:                CALL ZLARTG( UA12, UA11, CSQ, SNQ, R )
291:             ELSE
292:                CALL ZLARTG( VB12, VB11, CSQ, SNQ, R )
293:             END IF
294: *
295:             CSU = SNR
296:             SNU = DCONJG( D1 )*CSR
297:             CSV = SNL
298:             SNV = DCONJG( D1 )*CSL
299: *
300:          END IF
301: *
302:       END IF
303: *
304:       RETURN
305: *
306: *     End of ZLAGS2
307: *
308:       END
309: