001:       SUBROUTINE ZLAED0( QSIZ, N, D, E, Q, LDQ, QSTORE, LDQS, RWORK,
002:      $                   IWORK, INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       INTEGER            INFO, LDQ, LDQS, N, QSIZ
010: *     ..
011: *     .. Array Arguments ..
012:       INTEGER            IWORK( * )
013:       DOUBLE PRECISION   D( * ), E( * ), RWORK( * )
014:       COMPLEX*16         Q( LDQ, * ), QSTORE( LDQS, * )
015: *     ..
016: *
017: *  Purpose
018: *  =======
019: *
020: *  Using the divide and conquer method, ZLAED0 computes all eigenvalues
021: *  of a symmetric tridiagonal matrix which is one diagonal block of
022: *  those from reducing a dense or band Hermitian matrix and
023: *  corresponding eigenvectors of the dense or band matrix.
024: *
025: *  Arguments
026: *  =========
027: *
028: *  QSIZ   (input) INTEGER
029: *         The dimension of the unitary matrix used to reduce
030: *         the full matrix to tridiagonal form.  QSIZ >= N if ICOMPQ = 1.
031: *
032: *  N      (input) INTEGER
033: *         The dimension of the symmetric tridiagonal matrix.  N >= 0.
034: *
035: *  D      (input/output) DOUBLE PRECISION array, dimension (N)
036: *         On entry, the diagonal elements of the tridiagonal matrix.
037: *         On exit, the eigenvalues in ascending order.
038: *
039: *  E      (input/output) DOUBLE PRECISION array, dimension (N-1)
040: *         On entry, the off-diagonal elements of the tridiagonal matrix.
041: *         On exit, E has been destroyed.
042: *
043: *  Q      (input/output) COMPLEX*16 array, dimension (LDQ,N)
044: *         On entry, Q must contain an QSIZ x N matrix whose columns
045: *         unitarily orthonormal. It is a part of the unitary matrix
046: *         that reduces the full dense Hermitian matrix to a
047: *         (reducible) symmetric tridiagonal matrix.
048: *
049: *  LDQ    (input) INTEGER
050: *         The leading dimension of the array Q.  LDQ >= max(1,N).
051: *
052: *  IWORK  (workspace) INTEGER array,
053: *         the dimension of IWORK must be at least
054: *                      6 + 6*N + 5*N*lg N
055: *                      ( lg( N ) = smallest integer k
056: *                                  such that 2^k >= N )
057: *
058: *  RWORK  (workspace) DOUBLE PRECISION array,
059: *                               dimension (1 + 3*N + 2*N*lg N + 3*N**2)
060: *                        ( lg( N ) = smallest integer k
061: *                                    such that 2^k >= N )
062: *
063: *  QSTORE (workspace) COMPLEX*16 array, dimension (LDQS, N)
064: *         Used to store parts of
065: *         the eigenvector matrix when the updating matrix multiplies
066: *         take place.
067: *
068: *  LDQS   (input) INTEGER
069: *         The leading dimension of the array QSTORE.
070: *         LDQS >= max(1,N).
071: *
072: *  INFO   (output) INTEGER
073: *          = 0:  successful exit.
074: *          < 0:  if INFO = -i, the i-th argument had an illegal value.
075: *          > 0:  The algorithm failed to compute an eigenvalue while
076: *                working on the submatrix lying in rows and columns
077: *                INFO/(N+1) through mod(INFO,N+1).
078: *
079: *  =====================================================================
080: *
081: *  Warning:      N could be as big as QSIZ!
082: *
083: *     .. Parameters ..
084:       DOUBLE PRECISION   TWO
085:       PARAMETER          ( TWO = 2.D+0 )
086: *     ..
087: *     .. Local Scalars ..
088:       INTEGER            CURLVL, CURPRB, CURR, I, IGIVCL, IGIVNM,
089:      $                   IGIVPT, INDXQ, IPERM, IPRMPT, IQ, IQPTR, IWREM,
090:      $                   J, K, LGN, LL, MATSIZ, MSD2, SMLSIZ, SMM1,
091:      $                   SPM1, SPM2, SUBMAT, SUBPBS, TLVLS
092:       DOUBLE PRECISION   TEMP
093: *     ..
094: *     .. External Subroutines ..
095:       EXTERNAL           DCOPY, DSTEQR, XERBLA, ZCOPY, ZLACRM, ZLAED7
096: *     ..
097: *     .. External Functions ..
098:       INTEGER            ILAENV
099:       EXTERNAL           ILAENV
100: *     ..
101: *     .. Intrinsic Functions ..
102:       INTRINSIC          ABS, DBLE, INT, LOG, MAX
103: *     ..
104: *     .. Executable Statements ..
105: *
106: *     Test the input parameters.
107: *
108:       INFO = 0
109: *
110: *     IF( ICOMPQ .LT. 0 .OR. ICOMPQ .GT. 2 ) THEN
111: *        INFO = -1
112: *     ELSE IF( ( ICOMPQ .EQ. 1 ) .AND. ( QSIZ .LT. MAX( 0, N ) ) )
113: *    $        THEN
114:       IF( QSIZ.LT.MAX( 0, N ) ) THEN
115:          INFO = -1
116:       ELSE IF( N.LT.0 ) THEN
117:          INFO = -2
118:       ELSE IF( LDQ.LT.MAX( 1, N ) ) THEN
119:          INFO = -6
120:       ELSE IF( LDQS.LT.MAX( 1, N ) ) THEN
121:          INFO = -8
122:       END IF
123:       IF( INFO.NE.0 ) THEN
124:          CALL XERBLA( 'ZLAED0', -INFO )
125:          RETURN
126:       END IF
127: *
128: *     Quick return if possible
129: *
130:       IF( N.EQ.0 )
131:      $   RETURN
132: *
133:       SMLSIZ = ILAENV( 9, 'ZLAED0', ' ', 0, 0, 0, 0 )
134: *
135: *     Determine the size and placement of the submatrices, and save in
136: *     the leading elements of IWORK.
137: *
138:       IWORK( 1 ) = N
139:       SUBPBS = 1
140:       TLVLS = 0
141:    10 CONTINUE
142:       IF( IWORK( SUBPBS ).GT.SMLSIZ ) THEN
143:          DO 20 J = SUBPBS, 1, -1
144:             IWORK( 2*J ) = ( IWORK( J )+1 ) / 2
145:             IWORK( 2*J-1 ) = IWORK( J ) / 2
146:    20    CONTINUE
147:          TLVLS = TLVLS + 1
148:          SUBPBS = 2*SUBPBS
149:          GO TO 10
150:       END IF
151:       DO 30 J = 2, SUBPBS
152:          IWORK( J ) = IWORK( J ) + IWORK( J-1 )
153:    30 CONTINUE
154: *
155: *     Divide the matrix into SUBPBS submatrices of size at most SMLSIZ+1
156: *     using rank-1 modifications (cuts).
157: *
158:       SPM1 = SUBPBS - 1
159:       DO 40 I = 1, SPM1
160:          SUBMAT = IWORK( I ) + 1
161:          SMM1 = SUBMAT - 1
162:          D( SMM1 ) = D( SMM1 ) - ABS( E( SMM1 ) )
163:          D( SUBMAT ) = D( SUBMAT ) - ABS( E( SMM1 ) )
164:    40 CONTINUE
165: *
166:       INDXQ = 4*N + 3
167: *
168: *     Set up workspaces for eigenvalues only/accumulate new vectors
169: *     routine
170: *
171:       TEMP = LOG( DBLE( N ) ) / LOG( TWO )
172:       LGN = INT( TEMP )
173:       IF( 2**LGN.LT.N )
174:      $   LGN = LGN + 1
175:       IF( 2**LGN.LT.N )
176:      $   LGN = LGN + 1
177:       IPRMPT = INDXQ + N + 1
178:       IPERM = IPRMPT + N*LGN
179:       IQPTR = IPERM + N*LGN
180:       IGIVPT = IQPTR + N + 2
181:       IGIVCL = IGIVPT + N*LGN
182: *
183:       IGIVNM = 1
184:       IQ = IGIVNM + 2*N*LGN
185:       IWREM = IQ + N**2 + 1
186: *     Initialize pointers
187:       DO 50 I = 0, SUBPBS
188:          IWORK( IPRMPT+I ) = 1
189:          IWORK( IGIVPT+I ) = 1
190:    50 CONTINUE
191:       IWORK( IQPTR ) = 1
192: *
193: *     Solve each submatrix eigenproblem at the bottom of the divide and
194: *     conquer tree.
195: *
196:       CURR = 0
197:       DO 70 I = 0, SPM1
198:          IF( I.EQ.0 ) THEN
199:             SUBMAT = 1
200:             MATSIZ = IWORK( 1 )
201:          ELSE
202:             SUBMAT = IWORK( I ) + 1
203:             MATSIZ = IWORK( I+1 ) - IWORK( I )
204:          END IF
205:          LL = IQ - 1 + IWORK( IQPTR+CURR )
206:          CALL DSTEQR( 'I', MATSIZ, D( SUBMAT ), E( SUBMAT ),
207:      $                RWORK( LL ), MATSIZ, RWORK, INFO )
208:          CALL ZLACRM( QSIZ, MATSIZ, Q( 1, SUBMAT ), LDQ, RWORK( LL ),
209:      $                MATSIZ, QSTORE( 1, SUBMAT ), LDQS,
210:      $                RWORK( IWREM ) )
211:          IWORK( IQPTR+CURR+1 ) = IWORK( IQPTR+CURR ) + MATSIZ**2
212:          CURR = CURR + 1
213:          IF( INFO.GT.0 ) THEN
214:             INFO = SUBMAT*( N+1 ) + SUBMAT + MATSIZ - 1
215:             RETURN
216:          END IF
217:          K = 1
218:          DO 60 J = SUBMAT, IWORK( I+1 )
219:             IWORK( INDXQ+J ) = K
220:             K = K + 1
221:    60    CONTINUE
222:    70 CONTINUE
223: *
224: *     Successively merge eigensystems of adjacent submatrices
225: *     into eigensystem for the corresponding larger matrix.
226: *
227: *     while ( SUBPBS > 1 )
228: *
229:       CURLVL = 1
230:    80 CONTINUE
231:       IF( SUBPBS.GT.1 ) THEN
232:          SPM2 = SUBPBS - 2
233:          DO 90 I = 0, SPM2, 2
234:             IF( I.EQ.0 ) THEN
235:                SUBMAT = 1
236:                MATSIZ = IWORK( 2 )
237:                MSD2 = IWORK( 1 )
238:                CURPRB = 0
239:             ELSE
240:                SUBMAT = IWORK( I ) + 1
241:                MATSIZ = IWORK( I+2 ) - IWORK( I )
242:                MSD2 = MATSIZ / 2
243:                CURPRB = CURPRB + 1
244:             END IF
245: *
246: *     Merge lower order eigensystems (of size MSD2 and MATSIZ - MSD2)
247: *     into an eigensystem of size MATSIZ.  ZLAED7 handles the case
248: *     when the eigenvectors of a full or band Hermitian matrix (which
249: *     was reduced to tridiagonal form) are desired.
250: *
251: *     I am free to use Q as a valuable working space until Loop 150.
252: *
253:             CALL ZLAED7( MATSIZ, MSD2, QSIZ, TLVLS, CURLVL, CURPRB,
254:      $                   D( SUBMAT ), QSTORE( 1, SUBMAT ), LDQS,
255:      $                   E( SUBMAT+MSD2-1 ), IWORK( INDXQ+SUBMAT ),
256:      $                   RWORK( IQ ), IWORK( IQPTR ), IWORK( IPRMPT ),
257:      $                   IWORK( IPERM ), IWORK( IGIVPT ),
258:      $                   IWORK( IGIVCL ), RWORK( IGIVNM ),
259:      $                   Q( 1, SUBMAT ), RWORK( IWREM ),
260:      $                   IWORK( SUBPBS+1 ), INFO )
261:             IF( INFO.GT.0 ) THEN
262:                INFO = SUBMAT*( N+1 ) + SUBMAT + MATSIZ - 1
263:                RETURN
264:             END IF
265:             IWORK( I / 2+1 ) = IWORK( I+2 )
266:    90    CONTINUE
267:          SUBPBS = SUBPBS / 2
268:          CURLVL = CURLVL + 1
269:          GO TO 80
270:       END IF
271: *
272: *     end while
273: *
274: *     Re-merge the eigenvalues/vectors which were deflated at the final
275: *     merge step.
276: *
277:       DO 100 I = 1, N
278:          J = IWORK( INDXQ+I )
279:          RWORK( I ) = D( J )
280:          CALL ZCOPY( QSIZ, QSTORE( 1, J ), 1, Q( 1, I ), 1 )
281:   100 CONTINUE
282:       CALL DCOPY( N, RWORK, 1, D, 1 )
283: *
284:       RETURN
285: *
286: *     End of ZLAED0
287: *
288:       END
289: