01:       DOUBLE PRECISION FUNCTION ZLA_RPVGRW( N, NCOLS, A, LDA, AF, LDAF )
02: *
03: *     -- LAPACK routine (version 3.2)                                 --
04: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
05: *     -- Jason Riedy of Univ. of California Berkeley.                 --
06: *     -- November 2008                                                --
07: *
08: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
09: *     -- Univ. of California Berkeley and NAG Ltd.                    --
10: *
11:       IMPLICIT NONE
12: *     ..
13: *     .. Scalar Arguments ..
14:       INTEGER            N, NCOLS, LDA, LDAF
15: *     ..
16: *     .. Array Arguments ..
17:       COMPLEX*16         A( LDA, * ), AF( LDAF, * )
18: *     ..
19: *     .. Local Scalars ..
20:       INTEGER            I, J
21:       DOUBLE PRECISION   AMAX, UMAX, RPVGRW
22:       COMPLEX*16         ZDUM
23: *     ..
24: *     .. Intrinsic Functions ..
25:       INTRINSIC          MAX, MIN, ABS, REAL, DIMAG
26: *     ..
27: *     .. Statement Functions ..
28:       DOUBLE PRECISION   CABS1
29: *     ..
30: *     .. Statement Function Definitions ..
31:       CABS1( ZDUM ) = ABS( DBLE( ZDUM ) ) + ABS( DIMAG( ZDUM ) )
32: *     ..
33: *     .. Executable Statements ..
34: *
35:       RPVGRW = 1.0D+0
36: *
37:       DO J = 1, NCOLS
38:          AMAX = 0.0D+0
39:          UMAX = 0.0D+0
40:          DO I = 1, N
41:             AMAX = MAX( CABS1( A( I, J ) ), AMAX )
42:          END DO
43:          DO I = 1, J
44:             UMAX = MAX( CABS1( AF( I, J ) ), UMAX )
45:          END DO
46:          IF ( UMAX /= 0.0D+0 ) THEN
47:             RPVGRW = MIN( AMAX / UMAX, RPVGRW )
48:          END IF
49:       END DO
50:       ZLA_RPVGRW = RPVGRW
51:       END FUNCTION
52: