001:       SUBROUTINE ZLA_HERFSX_EXTENDED( PREC_TYPE, UPLO, N, NRHS, A, LDA,
002:      $                                AF, LDAF, IPIV, COLEQU, C, B, LDB,
003:      $                                Y, LDY, BERR_OUT, N_NORMS, ERRS_N,
004:      $                                ERRS_C, RES, AYB, DY, Y_TAIL,
005:      $                                RCOND, ITHRESH, RTHRESH, DZ_UB,
006:      $                                IGNORE_CWISE, INFO )
007: *
008: *     -- LAPACK routine (version 3.2)                                 --
009: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
010: *     -- Jason Riedy of Univ. of California Berkeley.                 --
011: *     -- November 2008                                                --
012: *
013: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
014: *     -- Univ. of California Berkeley and NAG Ltd.                    --
015: *
016:       IMPLICIT NONE
017: *     ..
018: *     .. Scalar Arguments ..
019:       INTEGER            INFO, LDA, LDAF, LDB, LDY, N, NRHS, PREC_TYPE,
020:      $                   N_NORMS, ITHRESH
021:       CHARACTER          UPLO
022:       LOGICAL            COLEQU, IGNORE_CWISE
023:       DOUBLE PRECISION   RTHRESH, DZ_UB
024: *     ..
025: *     .. Array Arguments ..
026:       INTEGER            IPIV( * )
027:       COMPLEX*16         A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
028:      $                   Y( LDY, * ), RES( * ), DY( * ), Y_TAIL( * )
029:       DOUBLE PRECISION   C( * ), AYB( * ), RCOND, BERR_OUT( * ),
030:      $                   ERRS_N( NRHS, * ), ERRS_C( NRHS, * )
031: *     ..
032: *     .. Local Scalars ..
033:       INTEGER            UPLO2, CNT, I, J, X_STATE, Z_STATE,
034:      $                   Y_PREC_STATE
035:       DOUBLE PRECISION   YK, DYK, YMIN, NORMY, NORMX, NORMDX, DXRAT,
036:      $                   DZRAT, PREVNORMDX, PREV_DZ_Z, DXRATMAX,
037:      $                   DZRATMAX, DX_X, DZ_Z, FINAL_DX_X, FINAL_DZ_Z,
038:      $                   EPS, HUGEVAL, INCR_THRESH
039:       LOGICAL            INCR_PREC
040:       COMPLEX*16         ZDUM
041: *     ..
042: *     .. Parameters ..
043:       INTEGER            UNSTABLE_STATE, WORKING_STATE, CONV_STATE,
044:      $                   NOPROG_STATE, BASE_RESIDUAL, EXTRA_RESIDUAL,
045:      $                   EXTRA_Y
046:       PARAMETER          ( UNSTABLE_STATE = 0, WORKING_STATE = 1,
047:      $                   CONV_STATE = 2, NOPROG_STATE = 3 )
048:       PARAMETER          ( BASE_RESIDUAL = 0, EXTRA_RESIDUAL = 1,
049:      $                   EXTRA_Y = 2 )
050:       INTEGER            FINAL_NRM_ERR_I, FINAL_CMP_ERR_I, BERR_I
051:       INTEGER            RCOND_I, NRM_RCOND_I, NRM_ERR_I, CMP_RCOND_I
052:       INTEGER            CMP_ERR_I, PIV_GROWTH_I
053:       PARAMETER          ( FINAL_NRM_ERR_I = 1, FINAL_CMP_ERR_I = 2,
054:      $                   BERR_I = 3 )
055:       PARAMETER          ( RCOND_I = 4, NRM_RCOND_I = 5, NRM_ERR_I = 6 )
056:       PARAMETER          ( CMP_RCOND_I = 7, CMP_ERR_I = 8,
057:      $                   PIV_GROWTH_I = 9 )
058:       INTEGER            LA_LINRX_ITREF_I, LA_LINRX_ITHRESH_I,
059:      $                   LA_LINRX_CWISE_I
060:       PARAMETER          ( LA_LINRX_ITREF_I = 1,
061:      $                   LA_LINRX_ITHRESH_I = 2 )
062:       PARAMETER          ( LA_LINRX_CWISE_I = 3 )
063:       INTEGER            LA_LINRX_TRUST_I, LA_LINRX_ERR_I,
064:      $                   LA_LINRX_RCOND_I
065:       PARAMETER          ( LA_LINRX_TRUST_I = 1, LA_LINRX_ERR_I = 2 )
066:       PARAMETER          ( LA_LINRX_RCOND_I = 3 )
067:       INTEGER            LA_LINRX_MAX_N_ERRS
068:       PARAMETER          ( LA_LINRX_MAX_N_ERRS = 3 )      
069: *     ..
070: *     .. External Functions ..
071:       LOGICAL            LSAME
072:       EXTERNAL           ILAUPLO
073:       INTEGER            ILAUPLO
074: *     ..
075: *     .. External Subroutines ..
076:       EXTERNAL           ZAXPY, ZCOPY, ZHETRS, ZHEMV, BLAS_ZHEMV_X,
077:      $                   BLAS_ZHEMV2_X, ZLA_HEAMV, ZLA_WWADDW,
078:      $                   ZLA_LIN_BERR
079:       DOUBLE PRECISION   DLAMCH
080: *     ..
081: *     .. Intrinsic Functions ..
082:       INTRINSIC          ABS, REAL, DIMAG, MAX, MIN
083: *     ..
084: *     .. Statement Functions ..
085:       DOUBLE PRECISION   CABS1
086: *     ..
087: *     .. Statement Function Definitions ..
088:       CABS1( ZDUM ) = ABS( DBLE( ZDUM ) ) + ABS( DIMAG( ZDUM ) )
089: *     ..
090: *     .. Executable Statements ..
091: *
092:       IF (INFO.NE.0) RETURN
093:       EPS = DLAMCH( 'Epsilon' )
094:       HUGEVAL = DLAMCH( 'Overflow' )
095: *     Force HUGEVAL to Inf
096:       HUGEVAL = HUGEVAL * HUGEVAL
097: *     Using HUGEVAL may lead to spurious underflows.
098:       INCR_THRESH = DBLE( N ) * EPS
099: 
100:       IF ( LSAME ( UPLO, 'L' ) ) THEN
101:          UPLO2 = ILAUPLO( 'L' )
102:       ELSE
103:          UPLO2 = ILAUPLO( 'U' )
104:       ENDIF
105: 
106:       DO J = 1, NRHS
107:          Y_PREC_STATE = EXTRA_RESIDUAL
108:          IF ( Y_PREC_STATE .EQ. EXTRA_Y ) THEN
109:             DO I = 1, N
110:                Y_TAIL( I ) = 0.0D+0
111:             END DO
112:          END IF
113: 
114:          DXRAT = 0.0D+0
115:          DXRATMAX = 0.0D+0
116:          DZRAT = 0.0D+0
117:          DZRATMAX = 0.0D+0
118:          FINAL_DX_X = HUGEVAL
119:          FINAL_DZ_Z = HUGEVAL
120:          PREVNORMDX = HUGEVAL
121:          PREV_DZ_Z = HUGEVAL
122:          DZ_Z = HUGEVAL
123:          DX_X = HUGEVAL
124: 
125:          X_STATE = WORKING_STATE
126:          Z_STATE = UNSTABLE_STATE
127:          INCR_PREC = .FALSE.
128: 
129:          DO CNT = 1, ITHRESH
130: *
131: *         Compute residual RES = B_s - op(A_s) * Y,
132: *             op(A) = A, A**T, or A**H depending on TRANS (and type).
133: *
134:             CALL ZCOPY( N, B( 1, J ), 1, RES, 1 )
135:             IF ( Y_PREC_STATE .EQ. BASE_RESIDUAL ) THEN
136:                CALL ZHEMV( UPLO, N, DCMPLX(-1.0D+0), A, LDA, Y( 1, J ), 
137:      $              1, DCMPLX(1.0D+0), RES, 1 )
138:             ELSE IF ( Y_PREC_STATE .EQ. EXTRA_RESIDUAL ) THEN
139:                CALL BLAS_ZHEMV_X( UPLO2, N, DCMPLX(-1.0D+0), A, LDA,
140:      $              Y( 1, J ), 1, DCMPLX(1.0D+0), RES, 1, PREC_TYPE)
141:             ELSE
142:                CALL BLAS_ZHEMV2_X(UPLO2, N, DCMPLX(-1.0D+0), A, LDA,
143:      $              Y(1, J), Y_TAIL, 1, DCMPLX(1.0D+0), RES, 1, 
144:      $     PREC_TYPE)
145:             END IF
146: 
147: !         XXX: RES is no longer needed.
148:             CALL ZCOPY( N, RES, 1, DY, 1 )
149:             CALL ZHETRS( UPLO, N, NRHS, AF, LDAF, IPIV, DY, N, INFO )
150: *
151: *         Calculate relative changes DX_X, DZ_Z and ratios DXRAT, DZRAT.
152: *
153:             NORMX = 0.0D+0
154:             NORMY = 0.0D+0
155:             NORMDX = 0.0D+0
156:             DZ_Z = 0.0D+0
157:             YMIN = HUGEVAL
158: 
159:             DO I = 1, N
160:                YK = CABS1( Y( I, J ) )
161:                DYK = CABS1( DY( I ) )
162: 
163:                IF (YK .NE. 0.0D+0) THEN
164:                   DZ_Z = MAX( DZ_Z, DYK / YK )
165:                ELSE IF ( DYK .NE. 0.0D+0 ) THEN
166:                   DZ_Z = HUGEVAL
167:                END IF
168: 
169:                YMIN = MIN( YMIN, YK )
170: 
171:                NORMY = MAX( NORMY, YK )
172: 
173:                IF ( COLEQU ) THEN
174:                   NORMX = MAX( NORMX, YK * C( I ) )
175:                   NORMDX = MAX( NORMDX, DYK * C( I ) )
176:                ELSE
177:                   NORMX = NORMY
178:                   NORMDX = MAX( NORMDX, DYK )
179:                END IF
180:             END DO
181: 
182:             IF ( NORMX .NE. 0.0D+0 ) THEN
183:                DX_X = NORMDX / NORMX
184:             ELSE IF ( NORMDX .EQ. 0.0D+0 ) THEN
185:                DX_X = 0.0D+0
186:             ELSE
187:                DX_X = HUGEVAL
188:             END IF
189: 
190:             DXRAT = NORMDX / PREVNORMDX
191:             DZRAT = DZ_Z / PREV_DZ_Z
192: *
193: *         Check termination criteria.
194: *
195:             IF ( YMIN*RCOND .LT. INCR_THRESH*NORMY
196:      $           .AND. Y_PREC_STATE .LT. EXTRA_Y )
197:      $           INCR_PREC = .TRUE.
198: 
199:             IF ( X_STATE .EQ. NOPROG_STATE .AND. DXRAT .LE. RTHRESH )
200:      $           X_STATE = WORKING_STATE
201:             IF ( X_STATE .EQ. WORKING_STATE ) THEN
202:                IF ( DX_X .LE. EPS ) THEN
203:                   X_STATE = CONV_STATE
204:                ELSE IF ( DXRAT .GT. RTHRESH ) THEN
205:                   IF ( Y_PREC_STATE .NE. EXTRA_Y ) THEN
206:                      INCR_PREC = .TRUE.
207:                   ELSE
208:                      X_STATE = NOPROG_STATE
209:                   END IF
210:                ELSE
211:                   IF (DXRAT .GT. DXRATMAX) DXRATMAX = DXRAT
212:                END IF
213:                IF ( X_STATE .GT. WORKING_STATE ) FINAL_DX_X = DX_X
214:             END IF
215: 
216:             IF ( Z_STATE .EQ. UNSTABLE_STATE .AND. DZ_Z .LE. DZ_UB )
217:      $           Z_STATE = WORKING_STATE
218:             IF ( Z_STATE .EQ. NOPROG_STATE .AND. DZRAT .LE. RTHRESH )
219:      $           Z_STATE = WORKING_STATE
220:             IF ( Z_STATE .EQ. WORKING_STATE ) THEN
221:                IF ( DZ_Z .LE. EPS ) THEN
222:                   Z_STATE = CONV_STATE
223:                ELSE IF ( DZ_Z .GT. DZ_UB ) THEN
224:                   Z_STATE = UNSTABLE_STATE
225:                   DZRATMAX = 0.0D+0
226:                   FINAL_DZ_Z = HUGEVAL
227:                ELSE IF ( DZRAT .GT. RTHRESH ) THEN
228:                   IF ( Y_PREC_STATE .NE. EXTRA_Y ) THEN
229:                      INCR_PREC = .TRUE.
230:                   ELSE
231:                      Z_STATE = NOPROG_STATE
232:                   END IF
233:                ELSE
234:                   IF ( DZRAT .GT. DZRATMAX ) DZRATMAX = DZRAT
235:                END IF
236:                IF ( Z_STATE .GT. WORKING_STATE ) FINAL_DZ_Z = DZ_Z
237:             END IF
238: 
239:             IF ( X_STATE.NE.WORKING_STATE.AND.
240:      $           ( IGNORE_CWISE.OR.Z_STATE.NE.WORKING_STATE ) )
241:      $           GOTO 666
242: 
243:             IF ( INCR_PREC ) THEN
244:                INCR_PREC = .FALSE.
245:                Y_PREC_STATE = Y_PREC_STATE + 1
246:                DO I = 1, N
247:                   Y_TAIL( I ) = 0.0D+0
248:                END DO
249:             END IF
250: 
251:             PREVNORMDX = NORMDX
252:             PREV_DZ_Z = DZ_Z
253: *
254: *           Update soluton.
255: *
256:             IF ( Y_PREC_STATE .LT. EXTRA_Y ) THEN
257:                CALL ZAXPY( N, DCMPLX(1.0D+0), DY, 1, Y(1,J), 1 )
258:             ELSE
259:                CALL ZLA_WWADDW( N, Y(1,J), Y_TAIL, DY )
260:             END IF
261: 
262:          END DO
263: *        Target of "IF (Z_STOP .AND. X_STOP)".  Sun's f77 won't EXIT.
264:  666     CONTINUE
265: *
266: *     Set final_* when cnt hits ithresh.
267: *
268:          IF ( X_STATE .EQ. WORKING_STATE ) FINAL_DX_X = DX_X
269:          IF ( Z_STATE .EQ. WORKING_STATE ) FINAL_DZ_Z = DZ_Z
270: *
271: *     Compute error bounds.
272: *
273:          IF ( N_NORMS .GE. 1 ) THEN
274:             ERRS_N( J, LA_LINRX_ERR_I ) = FINAL_DX_X / (1 - DXRATMAX)
275:          END IF
276:          IF (N_NORMS .GE. 2) THEN
277:             ERRS_C( J, LA_LINRX_ERR_I ) = FINAL_DZ_Z / (1 - DZRATMAX)
278:          END IF
279: *
280: *     Compute componentwise relative backward error from formula
281: *         max(i) ( abs(R(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
282: *     where abs(Z) is the componentwise absolute value of the matrix
283: *     or vector Z.
284: *
285: *         Compute residual RES = B_s - op(A_s) * Y,
286: *             op(A) = A, A**T, or A**H depending on TRANS (and type).
287: *
288:          CALL ZCOPY( N, B( 1, J ), 1, RES, 1 )
289:          CALL ZHEMV( UPLO, N, DCMPLX(-1.0D+0), A, LDA, Y(1,J), 1,
290:      $        DCMPLX(1.0D+0), RES, 1 )
291: 
292:          DO I = 1, N
293:             AYB( I ) = CABS1( B( I, J ) )
294:          END DO
295: *
296: *     Compute abs(op(A_s))*abs(Y) + abs(B_s).
297: *
298:          CALL ZLA_HEAMV( UPLO2, N, 1.0D+0,
299:      $        A, LDA, Y(1, J), 1, 1.0D+0, AYB, 1 )
300: 
301:          CALL ZLA_LIN_BERR( N, N, 1, RES, AYB, BERR_OUT( J ) )
302: *
303: *     End of loop for each RHS.
304: *
305:       END DO
306: *
307:       RETURN
308:       END
309: