001:       SUBROUTINE ZGEGS( JOBVSL, JOBVSR, N, A, LDA, B, LDB, ALPHA, BETA,
002:      $                  VSL, LDVSL, VSR, LDVSR, WORK, LWORK, RWORK,
003:      $                  INFO )
004: *
005: *  -- LAPACK driver routine (version 3.2) --
006: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
007: *     November 2006
008: *
009: *     .. Scalar Arguments ..
010:       CHARACTER          JOBVSL, JOBVSR
011:       INTEGER            INFO, LDA, LDB, LDVSL, LDVSR, LWORK, N
012: *     ..
013: *     .. Array Arguments ..
014:       DOUBLE PRECISION   RWORK( * )
015:       COMPLEX*16         A( LDA, * ), ALPHA( * ), B( LDB, * ),
016:      $                   BETA( * ), VSL( LDVSL, * ), VSR( LDVSR, * ),
017:      $                   WORK( * )
018: *     ..
019: *
020: *  Purpose
021: *  =======
022: *
023: *  This routine is deprecated and has been replaced by routine ZGGES.
024: *
025: *  ZGEGS computes the eigenvalues, Schur form, and, optionally, the
026: *  left and or/right Schur vectors of a complex matrix pair (A,B).
027: *  Given two square matrices A and B, the generalized Schur
028: *  factorization has the form
029: *  
030: *     A = Q*S*Z**H,  B = Q*T*Z**H
031: *  
032: *  where Q and Z are unitary matrices and S and T are upper triangular.
033: *  The columns of Q are the left Schur vectors
034: *  and the columns of Z are the right Schur vectors.
035: *  
036: *  If only the eigenvalues of (A,B) are needed, the driver routine
037: *  ZGEGV should be used instead.  See ZGEGV for a description of the
038: *  eigenvalues of the generalized nonsymmetric eigenvalue problem
039: *  (GNEP).
040: *
041: *  Arguments
042: *  =========
043: *
044: *  JOBVSL   (input) CHARACTER*1
045: *          = 'N':  do not compute the left Schur vectors;
046: *          = 'V':  compute the left Schur vectors (returned in VSL).
047: *
048: *  JOBVSR   (input) CHARACTER*1
049: *          = 'N':  do not compute the right Schur vectors;
050: *          = 'V':  compute the right Schur vectors (returned in VSR).
051: *
052: *  N       (input) INTEGER
053: *          The order of the matrices A, B, VSL, and VSR.  N >= 0.
054: *
055: *  A       (input/output) COMPLEX*16 array, dimension (LDA, N)
056: *          On entry, the matrix A.
057: *          On exit, the upper triangular matrix S from the generalized
058: *          Schur factorization.
059: *
060: *  LDA     (input) INTEGER
061: *          The leading dimension of A.  LDA >= max(1,N).
062: *
063: *  B       (input/output) COMPLEX*16 array, dimension (LDB, N)
064: *          On entry, the matrix B.
065: *          On exit, the upper triangular matrix T from the generalized
066: *          Schur factorization.
067: *
068: *  LDB     (input) INTEGER
069: *          The leading dimension of B.  LDB >= max(1,N).
070: *
071: *  ALPHA   (output) COMPLEX*16 array, dimension (N)
072: *          The complex scalars alpha that define the eigenvalues of
073: *          GNEP.  ALPHA(j) = S(j,j), the diagonal element of the Schur
074: *          form of A.
075: *
076: *  BETA    (output) COMPLEX*16 array, dimension (N)
077: *          The non-negative real scalars beta that define the
078: *          eigenvalues of GNEP.  BETA(j) = T(j,j), the diagonal element
079: *          of the triangular factor T.
080: *
081: *          Together, the quantities alpha = ALPHA(j) and beta = BETA(j)
082: *          represent the j-th eigenvalue of the matrix pair (A,B), in
083: *          one of the forms lambda = alpha/beta or mu = beta/alpha.
084: *          Since either lambda or mu may overflow, they should not,
085: *          in general, be computed.
086: *
087: *
088: *  VSL     (output) COMPLEX*16 array, dimension (LDVSL,N)
089: *          If JOBVSL = 'V', the matrix of left Schur vectors Q.
090: *          Not referenced if JOBVSL = 'N'.
091: *
092: *  LDVSL   (input) INTEGER
093: *          The leading dimension of the matrix VSL. LDVSL >= 1, and
094: *          if JOBVSL = 'V', LDVSL >= N.
095: *
096: *  VSR     (output) COMPLEX*16 array, dimension (LDVSR,N)
097: *          If JOBVSR = 'V', the matrix of right Schur vectors Z.
098: *          Not referenced if JOBVSR = 'N'.
099: *
100: *  LDVSR   (input) INTEGER
101: *          The leading dimension of the matrix VSR. LDVSR >= 1, and
102: *          if JOBVSR = 'V', LDVSR >= N.
103: *
104: *  WORK    (workspace/output) COMPLEX*16 array, dimension (MAX(1,LWORK))
105: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
106: *
107: *  LWORK   (input) INTEGER
108: *          The dimension of the array WORK.  LWORK >= max(1,2*N).
109: *          For good performance, LWORK must generally be larger.
110: *          To compute the optimal value of LWORK, call ILAENV to get
111: *          blocksizes (for ZGEQRF, ZUNMQR, and CUNGQR.)  Then compute:
112: *          NB  -- MAX of the blocksizes for ZGEQRF, ZUNMQR, and CUNGQR;
113: *          the optimal LWORK is N*(NB+1).
114: *
115: *          If LWORK = -1, then a workspace query is assumed; the routine
116: *          only calculates the optimal size of the WORK array, returns
117: *          this value as the first entry of the WORK array, and no error
118: *          message related to LWORK is issued by XERBLA.
119: *
120: *  RWORK   (workspace) DOUBLE PRECISION array, dimension (3*N)
121: *
122: *  INFO    (output) INTEGER
123: *          = 0:  successful exit
124: *          < 0:  if INFO = -i, the i-th argument had an illegal value.
125: *          =1,...,N:
126: *                The QZ iteration failed.  (A,B) are not in Schur
127: *                form, but ALPHA(j) and BETA(j) should be correct for
128: *                j=INFO+1,...,N.
129: *          > N:  errors that usually indicate LAPACK problems:
130: *                =N+1: error return from ZGGBAL
131: *                =N+2: error return from ZGEQRF
132: *                =N+3: error return from ZUNMQR
133: *                =N+4: error return from ZUNGQR
134: *                =N+5: error return from ZGGHRD
135: *                =N+6: error return from ZHGEQZ (other than failed
136: *                                               iteration)
137: *                =N+7: error return from ZGGBAK (computing VSL)
138: *                =N+8: error return from ZGGBAK (computing VSR)
139: *                =N+9: error return from ZLASCL (various places)
140: *
141: *  =====================================================================
142: *
143: *     .. Parameters ..
144:       DOUBLE PRECISION   ZERO, ONE
145:       PARAMETER          ( ZERO = 0.0D0, ONE = 1.0D0 )
146:       COMPLEX*16         CZERO, CONE
147:       PARAMETER          ( CZERO = ( 0.0D0, 0.0D0 ),
148:      $                   CONE = ( 1.0D0, 0.0D0 ) )
149: *     ..
150: *     .. Local Scalars ..
151:       LOGICAL            ILASCL, ILBSCL, ILVSL, ILVSR, LQUERY
152:       INTEGER            ICOLS, IHI, IINFO, IJOBVL, IJOBVR, ILEFT, ILO,
153:      $                   IRIGHT, IROWS, IRWORK, ITAU, IWORK, LOPT,
154:      $                   LWKMIN, LWKOPT, NB, NB1, NB2, NB3
155:       DOUBLE PRECISION   ANRM, ANRMTO, BIGNUM, BNRM, BNRMTO, EPS,
156:      $                   SAFMIN, SMLNUM
157: *     ..
158: *     .. External Subroutines ..
159:       EXTERNAL           XERBLA, ZGEQRF, ZGGBAK, ZGGBAL, ZGGHRD, ZHGEQZ,
160:      $                   ZLACPY, ZLASCL, ZLASET, ZUNGQR, ZUNMQR
161: *     ..
162: *     .. External Functions ..
163:       LOGICAL            LSAME
164:       INTEGER            ILAENV
165:       DOUBLE PRECISION   DLAMCH, ZLANGE
166:       EXTERNAL           LSAME, ILAENV, DLAMCH, ZLANGE
167: *     ..
168: *     .. Intrinsic Functions ..
169:       INTRINSIC          INT, MAX
170: *     ..
171: *     .. Executable Statements ..
172: *
173: *     Decode the input arguments
174: *
175:       IF( LSAME( JOBVSL, 'N' ) ) THEN
176:          IJOBVL = 1
177:          ILVSL = .FALSE.
178:       ELSE IF( LSAME( JOBVSL, 'V' ) ) THEN
179:          IJOBVL = 2
180:          ILVSL = .TRUE.
181:       ELSE
182:          IJOBVL = -1
183:          ILVSL = .FALSE.
184:       END IF
185: *
186:       IF( LSAME( JOBVSR, 'N' ) ) THEN
187:          IJOBVR = 1
188:          ILVSR = .FALSE.
189:       ELSE IF( LSAME( JOBVSR, 'V' ) ) THEN
190:          IJOBVR = 2
191:          ILVSR = .TRUE.
192:       ELSE
193:          IJOBVR = -1
194:          ILVSR = .FALSE.
195:       END IF
196: *
197: *     Test the input arguments
198: *
199:       LWKMIN = MAX( 2*N, 1 )
200:       LWKOPT = LWKMIN
201:       WORK( 1 ) = LWKOPT
202:       LQUERY = ( LWORK.EQ.-1 )
203:       INFO = 0
204:       IF( IJOBVL.LE.0 ) THEN
205:          INFO = -1
206:       ELSE IF( IJOBVR.LE.0 ) THEN
207:          INFO = -2
208:       ELSE IF( N.LT.0 ) THEN
209:          INFO = -3
210:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
211:          INFO = -5
212:       ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
213:          INFO = -7
214:       ELSE IF( LDVSL.LT.1 .OR. ( ILVSL .AND. LDVSL.LT.N ) ) THEN
215:          INFO = -11
216:       ELSE IF( LDVSR.LT.1 .OR. ( ILVSR .AND. LDVSR.LT.N ) ) THEN
217:          INFO = -13
218:       ELSE IF( LWORK.LT.LWKMIN .AND. .NOT.LQUERY ) THEN
219:          INFO = -15
220:       END IF
221: *
222:       IF( INFO.EQ.0 ) THEN
223:          NB1 = ILAENV( 1, 'ZGEQRF', ' ', N, N, -1, -1 )
224:          NB2 = ILAENV( 1, 'ZUNMQR', ' ', N, N, N, -1 )
225:          NB3 = ILAENV( 1, 'ZUNGQR', ' ', N, N, N, -1 )
226:          NB = MAX( NB1, NB2, NB3 )
227:          LOPT = N*( NB+1 )
228:          WORK( 1 ) = LOPT
229:       END IF
230: *
231:       IF( INFO.NE.0 ) THEN
232:          CALL XERBLA( 'ZGEGS ', -INFO )
233:          RETURN
234:       ELSE IF( LQUERY ) THEN
235:          RETURN
236:       END IF
237: *
238: *     Quick return if possible
239: *
240:       IF( N.EQ.0 )
241:      $   RETURN
242: *
243: *     Get machine constants
244: *
245:       EPS = DLAMCH( 'E' )*DLAMCH( 'B' )
246:       SAFMIN = DLAMCH( 'S' )
247:       SMLNUM = N*SAFMIN / EPS
248:       BIGNUM = ONE / SMLNUM
249: *
250: *     Scale A if max element outside range [SMLNUM,BIGNUM]
251: *
252:       ANRM = ZLANGE( 'M', N, N, A, LDA, RWORK )
253:       ILASCL = .FALSE.
254:       IF( ANRM.GT.ZERO .AND. ANRM.LT.SMLNUM ) THEN
255:          ANRMTO = SMLNUM
256:          ILASCL = .TRUE.
257:       ELSE IF( ANRM.GT.BIGNUM ) THEN
258:          ANRMTO = BIGNUM
259:          ILASCL = .TRUE.
260:       END IF
261: *
262:       IF( ILASCL ) THEN
263:          CALL ZLASCL( 'G', -1, -1, ANRM, ANRMTO, N, N, A, LDA, IINFO )
264:          IF( IINFO.NE.0 ) THEN
265:             INFO = N + 9
266:             RETURN
267:          END IF
268:       END IF
269: *
270: *     Scale B if max element outside range [SMLNUM,BIGNUM]
271: *
272:       BNRM = ZLANGE( 'M', N, N, B, LDB, RWORK )
273:       ILBSCL = .FALSE.
274:       IF( BNRM.GT.ZERO .AND. BNRM.LT.SMLNUM ) THEN
275:          BNRMTO = SMLNUM
276:          ILBSCL = .TRUE.
277:       ELSE IF( BNRM.GT.BIGNUM ) THEN
278:          BNRMTO = BIGNUM
279:          ILBSCL = .TRUE.
280:       END IF
281: *
282:       IF( ILBSCL ) THEN
283:          CALL ZLASCL( 'G', -1, -1, BNRM, BNRMTO, N, N, B, LDB, IINFO )
284:          IF( IINFO.NE.0 ) THEN
285:             INFO = N + 9
286:             RETURN
287:          END IF
288:       END IF
289: *
290: *     Permute the matrix to make it more nearly triangular
291: *
292:       ILEFT = 1
293:       IRIGHT = N + 1
294:       IRWORK = IRIGHT + N
295:       IWORK = 1
296:       CALL ZGGBAL( 'P', N, A, LDA, B, LDB, ILO, IHI, RWORK( ILEFT ),
297:      $             RWORK( IRIGHT ), RWORK( IRWORK ), IINFO )
298:       IF( IINFO.NE.0 ) THEN
299:          INFO = N + 1
300:          GO TO 10
301:       END IF
302: *
303: *     Reduce B to triangular form, and initialize VSL and/or VSR
304: *
305:       IROWS = IHI + 1 - ILO
306:       ICOLS = N + 1 - ILO
307:       ITAU = IWORK
308:       IWORK = ITAU + IROWS
309:       CALL ZGEQRF( IROWS, ICOLS, B( ILO, ILO ), LDB, WORK( ITAU ),
310:      $             WORK( IWORK ), LWORK+1-IWORK, IINFO )
311:       IF( IINFO.GE.0 )
312:      $   LWKOPT = MAX( LWKOPT, INT( WORK( IWORK ) )+IWORK-1 )
313:       IF( IINFO.NE.0 ) THEN
314:          INFO = N + 2
315:          GO TO 10
316:       END IF
317: *
318:       CALL ZUNMQR( 'L', 'C', IROWS, ICOLS, IROWS, B( ILO, ILO ), LDB,
319:      $             WORK( ITAU ), A( ILO, ILO ), LDA, WORK( IWORK ),
320:      $             LWORK+1-IWORK, IINFO )
321:       IF( IINFO.GE.0 )
322:      $   LWKOPT = MAX( LWKOPT, INT( WORK( IWORK ) )+IWORK-1 )
323:       IF( IINFO.NE.0 ) THEN
324:          INFO = N + 3
325:          GO TO 10
326:       END IF
327: *
328:       IF( ILVSL ) THEN
329:          CALL ZLASET( 'Full', N, N, CZERO, CONE, VSL, LDVSL )
330:          CALL ZLACPY( 'L', IROWS-1, IROWS-1, B( ILO+1, ILO ), LDB,
331:      $                VSL( ILO+1, ILO ), LDVSL )
332:          CALL ZUNGQR( IROWS, IROWS, IROWS, VSL( ILO, ILO ), LDVSL,
333:      $                WORK( ITAU ), WORK( IWORK ), LWORK+1-IWORK,
334:      $                IINFO )
335:          IF( IINFO.GE.0 )
336:      $      LWKOPT = MAX( LWKOPT, INT( WORK( IWORK ) )+IWORK-1 )
337:          IF( IINFO.NE.0 ) THEN
338:             INFO = N + 4
339:             GO TO 10
340:          END IF
341:       END IF
342: *
343:       IF( ILVSR )
344:      $   CALL ZLASET( 'Full', N, N, CZERO, CONE, VSR, LDVSR )
345: *
346: *     Reduce to generalized Hessenberg form
347: *
348:       CALL ZGGHRD( JOBVSL, JOBVSR, N, ILO, IHI, A, LDA, B, LDB, VSL,
349:      $             LDVSL, VSR, LDVSR, IINFO )
350:       IF( IINFO.NE.0 ) THEN
351:          INFO = N + 5
352:          GO TO 10
353:       END IF
354: *
355: *     Perform QZ algorithm, computing Schur vectors if desired
356: *
357:       IWORK = ITAU
358:       CALL ZHGEQZ( 'S', JOBVSL, JOBVSR, N, ILO, IHI, A, LDA, B, LDB,
359:      $             ALPHA, BETA, VSL, LDVSL, VSR, LDVSR, WORK( IWORK ),
360:      $             LWORK+1-IWORK, RWORK( IRWORK ), IINFO )
361:       IF( IINFO.GE.0 )
362:      $   LWKOPT = MAX( LWKOPT, INT( WORK( IWORK ) )+IWORK-1 )
363:       IF( IINFO.NE.0 ) THEN
364:          IF( IINFO.GT.0 .AND. IINFO.LE.N ) THEN
365:             INFO = IINFO
366:          ELSE IF( IINFO.GT.N .AND. IINFO.LE.2*N ) THEN
367:             INFO = IINFO - N
368:          ELSE
369:             INFO = N + 6
370:          END IF
371:          GO TO 10
372:       END IF
373: *
374: *     Apply permutation to VSL and VSR
375: *
376:       IF( ILVSL ) THEN
377:          CALL ZGGBAK( 'P', 'L', N, ILO, IHI, RWORK( ILEFT ),
378:      $                RWORK( IRIGHT ), N, VSL, LDVSL, IINFO )
379:          IF( IINFO.NE.0 ) THEN
380:             INFO = N + 7
381:             GO TO 10
382:          END IF
383:       END IF
384:       IF( ILVSR ) THEN
385:          CALL ZGGBAK( 'P', 'R', N, ILO, IHI, RWORK( ILEFT ),
386:      $                RWORK( IRIGHT ), N, VSR, LDVSR, IINFO )
387:          IF( IINFO.NE.0 ) THEN
388:             INFO = N + 8
389:             GO TO 10
390:          END IF
391:       END IF
392: *
393: *     Undo scaling
394: *
395:       IF( ILASCL ) THEN
396:          CALL ZLASCL( 'U', -1, -1, ANRMTO, ANRM, N, N, A, LDA, IINFO )
397:          IF( IINFO.NE.0 ) THEN
398:             INFO = N + 9
399:             RETURN
400:          END IF
401:          CALL ZLASCL( 'G', -1, -1, ANRMTO, ANRM, N, 1, ALPHA, N, IINFO )
402:          IF( IINFO.NE.0 ) THEN
403:             INFO = N + 9
404:             RETURN
405:          END IF
406:       END IF
407: *
408:       IF( ILBSCL ) THEN
409:          CALL ZLASCL( 'U', -1, -1, BNRMTO, BNRM, N, N, B, LDB, IINFO )
410:          IF( IINFO.NE.0 ) THEN
411:             INFO = N + 9
412:             RETURN
413:          END IF
414:          CALL ZLASCL( 'G', -1, -1, BNRMTO, BNRM, N, 1, BETA, N, IINFO )
415:          IF( IINFO.NE.0 ) THEN
416:             INFO = N + 9
417:             RETURN
418:          END IF
419:       END IF
420: *
421:    10 CONTINUE
422:       WORK( 1 ) = LWKOPT
423: *
424:       RETURN
425: *
426: *     End of ZGEGS
427: *
428:       END
429: