001:       SUBROUTINE STGEX2( WANTQ, WANTZ, N, A, LDA, B, LDB, Q, LDQ, Z,
002:      $                   LDZ, J1, N1, N2, WORK, LWORK, INFO )
003: *
004: *  -- LAPACK auxiliary routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       LOGICAL            WANTQ, WANTZ
010:       INTEGER            INFO, J1, LDA, LDB, LDQ, LDZ, LWORK, N, N1, N2
011: *     ..
012: *     .. Array Arguments ..
013:       REAL               A( LDA, * ), B( LDB, * ), Q( LDQ, * ),
014:      $                   WORK( * ), Z( LDZ, * )
015: *     ..
016: *
017: *  Purpose
018: *  =======
019: *
020: *  STGEX2 swaps adjacent diagonal blocks (A11, B11) and (A22, B22)
021: *  of size 1-by-1 or 2-by-2 in an upper (quasi) triangular matrix pair
022: *  (A, B) by an orthogonal equivalence transformation.
023: *
024: *  (A, B) must be in generalized real Schur canonical form (as returned
025: *  by SGGES), i.e. A is block upper triangular with 1-by-1 and 2-by-2
026: *  diagonal blocks. B is upper triangular.
027: *
028: *  Optionally, the matrices Q and Z of generalized Schur vectors are
029: *  updated.
030: *
031: *         Q(in) * A(in) * Z(in)' = Q(out) * A(out) * Z(out)'
032: *         Q(in) * B(in) * Z(in)' = Q(out) * B(out) * Z(out)'
033: *
034: *
035: *  Arguments
036: *  =========
037: *
038: *  WANTQ   (input) LOGICAL
039: *          .TRUE. : update the left transformation matrix Q;
040: *          .FALSE.: do not update Q.
041: *
042: *  WANTZ   (input) LOGICAL
043: *          .TRUE. : update the right transformation matrix Z;
044: *          .FALSE.: do not update Z.
045: *
046: *  N       (input) INTEGER
047: *          The order of the matrices A and B. N >= 0.
048: *
049: *  A      (input/output) REAL arrays, dimensions (LDA,N)
050: *          On entry, the matrix A in the pair (A, B).
051: *          On exit, the updated matrix A.
052: *
053: *  LDA     (input)  INTEGER
054: *          The leading dimension of the array A. LDA >= max(1,N).
055: *
056: *  B      (input/output) REAL arrays, dimensions (LDB,N)
057: *          On entry, the matrix B in the pair (A, B).
058: *          On exit, the updated matrix B.
059: *
060: *  LDB     (input)  INTEGER
061: *          The leading dimension of the array B. LDB >= max(1,N).
062: *
063: *  Q       (input/output) REAL array, dimension (LDZ,N)
064: *          On entry, if WANTQ = .TRUE., the orthogonal matrix Q.
065: *          On exit, the updated matrix Q.
066: *          Not referenced if WANTQ = .FALSE..
067: *
068: *  LDQ     (input) INTEGER
069: *          The leading dimension of the array Q. LDQ >= 1.
070: *          If WANTQ = .TRUE., LDQ >= N.
071: *
072: *  Z       (input/output) REAL array, dimension (LDZ,N)
073: *          On entry, if WANTZ =.TRUE., the orthogonal matrix Z.
074: *          On exit, the updated matrix Z.
075: *          Not referenced if WANTZ = .FALSE..
076: *
077: *  LDZ     (input) INTEGER
078: *          The leading dimension of the array Z. LDZ >= 1.
079: *          If WANTZ = .TRUE., LDZ >= N.
080: *
081: *  J1      (input) INTEGER
082: *          The index to the first block (A11, B11). 1 <= J1 <= N.
083: *
084: *  N1      (input) INTEGER
085: *          The order of the first block (A11, B11). N1 = 0, 1 or 2.
086: *
087: *  N2      (input) INTEGER
088: *          The order of the second block (A22, B22). N2 = 0, 1 or 2.
089: *
090: *  WORK    (workspace) REAL array, dimension (MAX(1,LWORK)).
091: *
092: *  LWORK   (input) INTEGER
093: *          The dimension of the array WORK.
094: *          LWORK >=  MAX( N*(N2+N1), (N2+N1)*(N2+N1)*2 )
095: *
096: *  INFO    (output) INTEGER
097: *            =0: Successful exit
098: *            >0: If INFO = 1, the transformed matrix (A, B) would be
099: *                too far from generalized Schur form; the blocks are
100: *                not swapped and (A, B) and (Q, Z) are unchanged.
101: *                The problem of swapping is too ill-conditioned.
102: *            <0: If INFO = -16: LWORK is too small. Appropriate value
103: *                for LWORK is returned in WORK(1).
104: *
105: *  Further Details
106: *  ===============
107: *
108: *  Based on contributions by
109: *     Bo Kagstrom and Peter Poromaa, Department of Computing Science,
110: *     Umea University, S-901 87 Umea, Sweden.
111: *
112: *  In the current code both weak and strong stability tests are
113: *  performed. The user can omit the strong stability test by changing
114: *  the internal logical parameter WANDS to .FALSE.. See ref. [2] for
115: *  details.
116: *
117: *  [1] B. Kagstrom; A Direct Method for Reordering Eigenvalues in the
118: *      Generalized Real Schur Form of a Regular Matrix Pair (A, B), in
119: *      M.S. Moonen et al (eds), Linear Algebra for Large Scale and
120: *      Real-Time Applications, Kluwer Academic Publ. 1993, pp 195-218.
121: *
122: *  [2] B. Kagstrom and P. Poromaa; Computing Eigenspaces with Specified
123: *      Eigenvalues of a Regular Matrix Pair (A, B) and Condition
124: *      Estimation: Theory, Algorithms and Software,
125: *      Report UMINF - 94.04, Department of Computing Science, Umea
126: *      University, S-901 87 Umea, Sweden, 1994. Also as LAPACK Working
127: *      Note 87. To appear in Numerical Algorithms, 1996.
128: *
129: *  =====================================================================
130: *  Replaced various illegal calls to SCOPY by calls to SLASET, or by DO
131: *  loops. Sven Hammarling, 1/5/02.
132: *
133: *     .. Parameters ..
134:       REAL               ZERO, ONE
135:       PARAMETER          ( ZERO = 0.0E+0, ONE = 1.0E+0 )
136:       REAL               TEN
137:       PARAMETER          ( TEN = 1.0E+01 )
138:       INTEGER            LDST
139:       PARAMETER          ( LDST = 4 )
140:       LOGICAL            WANDS
141:       PARAMETER          ( WANDS = .TRUE. )
142: *     ..
143: *     .. Local Scalars ..
144:       LOGICAL            STRONG, WEAK
145:       INTEGER            I, IDUM, LINFO, M
146:       REAL               BQRA21, BRQA21, DDUM, DNORM, DSCALE, DSUM, EPS,
147:      $                   F, G, SA, SB, SCALE, SMLNUM, SS, THRESH, WS
148: *     ..
149: *     .. Local Arrays ..
150:       INTEGER            IWORK( LDST )
151:       REAL               AI( 2 ), AR( 2 ), BE( 2 ), IR( LDST, LDST ),
152:      $                   IRCOP( LDST, LDST ), LI( LDST, LDST ),
153:      $                   LICOP( LDST, LDST ), S( LDST, LDST ),
154:      $                   SCPY( LDST, LDST ), T( LDST, LDST ),
155:      $                   TAUL( LDST ), TAUR( LDST ), TCPY( LDST, LDST )
156: *     ..
157: *     .. External Functions ..
158:       REAL               SLAMCH
159:       EXTERNAL           SLAMCH
160: *     ..
161: *     .. External Subroutines ..
162:       EXTERNAL           SGEMM, SGEQR2, SGERQ2, SLACPY, SLAGV2, SLARTG,
163:      $                   SLASET, SLASSQ, SORG2R, SORGR2, SORM2R, SORMR2,
164:      $                   SROT, SSCAL, STGSY2
165: *     ..
166: *     .. Intrinsic Functions ..
167:       INTRINSIC          ABS, MAX, SQRT
168: *     ..
169: *     .. Executable Statements ..
170: *
171:       INFO = 0
172: *
173: *     Quick return if possible
174: *
175:       IF( N.LE.1 .OR. N1.LE.0 .OR. N2.LE.0 )
176:      $   RETURN
177:       IF( N1.GT.N .OR. ( J1+N1 ).GT.N )
178:      $   RETURN
179:       M = N1 + N2
180:       IF( LWORK.LT.MAX( N*M, M*M*2 ) ) THEN
181:          INFO = -16
182:          WORK( 1 ) = MAX( N*M, M*M*2 )
183:          RETURN
184:       END IF
185: *
186:       WEAK = .FALSE.
187:       STRONG = .FALSE.
188: *
189: *     Make a local copy of selected block
190: *
191:       CALL SLASET( 'Full', LDST, LDST, ZERO, ZERO, LI, LDST )
192:       CALL SLASET( 'Full', LDST, LDST, ZERO, ZERO, IR, LDST )
193:       CALL SLACPY( 'Full', M, M, A( J1, J1 ), LDA, S, LDST )
194:       CALL SLACPY( 'Full', M, M, B( J1, J1 ), LDB, T, LDST )
195: *
196: *     Compute threshold for testing acceptance of swapping.
197: *
198:       EPS = SLAMCH( 'P' )
199:       SMLNUM = SLAMCH( 'S' ) / EPS
200:       DSCALE = ZERO
201:       DSUM = ONE
202:       CALL SLACPY( 'Full', M, M, S, LDST, WORK, M )
203:       CALL SLASSQ( M*M, WORK, 1, DSCALE, DSUM )
204:       CALL SLACPY( 'Full', M, M, T, LDST, WORK, M )
205:       CALL SLASSQ( M*M, WORK, 1, DSCALE, DSUM )
206:       DNORM = DSCALE*SQRT( DSUM )
207:       THRESH = MAX( TEN*EPS*DNORM, SMLNUM )
208: *
209:       IF( M.EQ.2 ) THEN
210: *
211: *        CASE 1: Swap 1-by-1 and 1-by-1 blocks.
212: *
213: *        Compute orthogonal QL and RQ that swap 1-by-1 and 1-by-1 blocks
214: *        using Givens rotations and perform the swap tentatively.
215: *
216:          F = S( 2, 2 )*T( 1, 1 ) - T( 2, 2 )*S( 1, 1 )
217:          G = S( 2, 2 )*T( 1, 2 ) - T( 2, 2 )*S( 1, 2 )
218:          SB = ABS( T( 2, 2 ) )
219:          SA = ABS( S( 2, 2 ) )
220:          CALL SLARTG( F, G, IR( 1, 2 ), IR( 1, 1 ), DDUM )
221:          IR( 2, 1 ) = -IR( 1, 2 )
222:          IR( 2, 2 ) = IR( 1, 1 )
223:          CALL SROT( 2, S( 1, 1 ), 1, S( 1, 2 ), 1, IR( 1, 1 ),
224:      $              IR( 2, 1 ) )
225:          CALL SROT( 2, T( 1, 1 ), 1, T( 1, 2 ), 1, IR( 1, 1 ),
226:      $              IR( 2, 1 ) )
227:          IF( SA.GE.SB ) THEN
228:             CALL SLARTG( S( 1, 1 ), S( 2, 1 ), LI( 1, 1 ), LI( 2, 1 ),
229:      $                   DDUM )
230:          ELSE
231:             CALL SLARTG( T( 1, 1 ), T( 2, 1 ), LI( 1, 1 ), LI( 2, 1 ),
232:      $                   DDUM )
233:          END IF
234:          CALL SROT( 2, S( 1, 1 ), LDST, S( 2, 1 ), LDST, LI( 1, 1 ),
235:      $              LI( 2, 1 ) )
236:          CALL SROT( 2, T( 1, 1 ), LDST, T( 2, 1 ), LDST, LI( 1, 1 ),
237:      $              LI( 2, 1 ) )
238:          LI( 2, 2 ) = LI( 1, 1 )
239:          LI( 1, 2 ) = -LI( 2, 1 )
240: *
241: *        Weak stability test:
242: *           |S21| + |T21| <= O(EPS * F-norm((S, T)))
243: *
244:          WS = ABS( S( 2, 1 ) ) + ABS( T( 2, 1 ) )
245:          WEAK = WS.LE.THRESH
246:          IF( .NOT.WEAK )
247:      $      GO TO 70
248: *
249:          IF( WANDS ) THEN
250: *
251: *           Strong stability test:
252: *             F-norm((A-QL'*S*QR, B-QL'*T*QR)) <= O(EPS*F-norm((A,B)))
253: *
254:             CALL SLACPY( 'Full', M, M, A( J1, J1 ), LDA, WORK( M*M+1 ),
255:      $                   M )
256:             CALL SGEMM( 'N', 'N', M, M, M, ONE, LI, LDST, S, LDST, ZERO,
257:      $                  WORK, M )
258:             CALL SGEMM( 'N', 'T', M, M, M, -ONE, WORK, M, IR, LDST, ONE,
259:      $                  WORK( M*M+1 ), M )
260:             DSCALE = ZERO
261:             DSUM = ONE
262:             CALL SLASSQ( M*M, WORK( M*M+1 ), 1, DSCALE, DSUM )
263: *
264:             CALL SLACPY( 'Full', M, M, B( J1, J1 ), LDB, WORK( M*M+1 ),
265:      $                   M )
266:             CALL SGEMM( 'N', 'N', M, M, M, ONE, LI, LDST, T, LDST, ZERO,
267:      $                  WORK, M )
268:             CALL SGEMM( 'N', 'T', M, M, M, -ONE, WORK, M, IR, LDST, ONE,
269:      $                  WORK( M*M+1 ), M )
270:             CALL SLASSQ( M*M, WORK( M*M+1 ), 1, DSCALE, DSUM )
271:             SS = DSCALE*SQRT( DSUM )
272:             STRONG = SS.LE.THRESH
273:             IF( .NOT.STRONG )
274:      $         GO TO 70
275:          END IF
276: *
277: *        Update (A(J1:J1+M-1, M+J1:N), B(J1:J1+M-1, M+J1:N)) and
278: *               (A(1:J1-1, J1:J1+M), B(1:J1-1, J1:J1+M)).
279: *
280:          CALL SROT( J1+1, A( 1, J1 ), 1, A( 1, J1+1 ), 1, IR( 1, 1 ),
281:      $              IR( 2, 1 ) )
282:          CALL SROT( J1+1, B( 1, J1 ), 1, B( 1, J1+1 ), 1, IR( 1, 1 ),
283:      $              IR( 2, 1 ) )
284:          CALL SROT( N-J1+1, A( J1, J1 ), LDA, A( J1+1, J1 ), LDA,
285:      $              LI( 1, 1 ), LI( 2, 1 ) )
286:          CALL SROT( N-J1+1, B( J1, J1 ), LDB, B( J1+1, J1 ), LDB,
287:      $              LI( 1, 1 ), LI( 2, 1 ) )
288: *
289: *        Set  N1-by-N2 (2,1) - blocks to ZERO.
290: *
291:          A( J1+1, J1 ) = ZERO
292:          B( J1+1, J1 ) = ZERO
293: *
294: *        Accumulate transformations into Q and Z if requested.
295: *
296:          IF( WANTZ )
297:      $      CALL SROT( N, Z( 1, J1 ), 1, Z( 1, J1+1 ), 1, IR( 1, 1 ),
298:      $                 IR( 2, 1 ) )
299:          IF( WANTQ )
300:      $      CALL SROT( N, Q( 1, J1 ), 1, Q( 1, J1+1 ), 1, LI( 1, 1 ),
301:      $                 LI( 2, 1 ) )
302: *
303: *        Exit with INFO = 0 if swap was successfully performed.
304: *
305:          RETURN
306: *
307:       ELSE
308: *
309: *        CASE 2: Swap 1-by-1 and 2-by-2 blocks, or 2-by-2
310: *                and 2-by-2 blocks.
311: *
312: *        Solve the generalized Sylvester equation
313: *                 S11 * R - L * S22 = SCALE * S12
314: *                 T11 * R - L * T22 = SCALE * T12
315: *        for R and L. Solutions in LI and IR.
316: *
317:          CALL SLACPY( 'Full', N1, N2, T( 1, N1+1 ), LDST, LI, LDST )
318:          CALL SLACPY( 'Full', N1, N2, S( 1, N1+1 ), LDST,
319:      $                IR( N2+1, N1+1 ), LDST )
320:          CALL STGSY2( 'N', 0, N1, N2, S, LDST, S( N1+1, N1+1 ), LDST,
321:      $                IR( N2+1, N1+1 ), LDST, T, LDST, T( N1+1, N1+1 ),
322:      $                LDST, LI, LDST, SCALE, DSUM, DSCALE, IWORK, IDUM,
323:      $                LINFO )
324: *
325: *        Compute orthogonal matrix QL:
326: *
327: *                    QL' * LI = [ TL ]
328: *                               [ 0  ]
329: *        where
330: *                    LI =  [      -L              ]
331: *                          [ SCALE * identity(N2) ]
332: *
333:          DO 10 I = 1, N2
334:             CALL SSCAL( N1, -ONE, LI( 1, I ), 1 )
335:             LI( N1+I, I ) = SCALE
336:    10    CONTINUE
337:          CALL SGEQR2( M, N2, LI, LDST, TAUL, WORK, LINFO )
338:          IF( LINFO.NE.0 )
339:      $      GO TO 70
340:          CALL SORG2R( M, M, N2, LI, LDST, TAUL, WORK, LINFO )
341:          IF( LINFO.NE.0 )
342:      $      GO TO 70
343: *
344: *        Compute orthogonal matrix RQ:
345: *
346: *                    IR * RQ' =   [ 0  TR],
347: *
348: *         where IR = [ SCALE * identity(N1), R ]
349: *
350:          DO 20 I = 1, N1
351:             IR( N2+I, I ) = SCALE
352:    20    CONTINUE
353:          CALL SGERQ2( N1, M, IR( N2+1, 1 ), LDST, TAUR, WORK, LINFO )
354:          IF( LINFO.NE.0 )
355:      $      GO TO 70
356:          CALL SORGR2( M, M, N1, IR, LDST, TAUR, WORK, LINFO )
357:          IF( LINFO.NE.0 )
358:      $      GO TO 70
359: *
360: *        Perform the swapping tentatively:
361: *
362:          CALL SGEMM( 'T', 'N', M, M, M, ONE, LI, LDST, S, LDST, ZERO,
363:      $               WORK, M )
364:          CALL SGEMM( 'N', 'T', M, M, M, ONE, WORK, M, IR, LDST, ZERO, S,
365:      $               LDST )
366:          CALL SGEMM( 'T', 'N', M, M, M, ONE, LI, LDST, T, LDST, ZERO,
367:      $               WORK, M )
368:          CALL SGEMM( 'N', 'T', M, M, M, ONE, WORK, M, IR, LDST, ZERO, T,
369:      $               LDST )
370:          CALL SLACPY( 'F', M, M, S, LDST, SCPY, LDST )
371:          CALL SLACPY( 'F', M, M, T, LDST, TCPY, LDST )
372:          CALL SLACPY( 'F', M, M, IR, LDST, IRCOP, LDST )
373:          CALL SLACPY( 'F', M, M, LI, LDST, LICOP, LDST )
374: *
375: *        Triangularize the B-part by an RQ factorization.
376: *        Apply transformation (from left) to A-part, giving S.
377: *
378:          CALL SGERQ2( M, M, T, LDST, TAUR, WORK, LINFO )
379:          IF( LINFO.NE.0 )
380:      $      GO TO 70
381:          CALL SORMR2( 'R', 'T', M, M, M, T, LDST, TAUR, S, LDST, WORK,
382:      $                LINFO )
383:          IF( LINFO.NE.0 )
384:      $      GO TO 70
385:          CALL SORMR2( 'L', 'N', M, M, M, T, LDST, TAUR, IR, LDST, WORK,
386:      $                LINFO )
387:          IF( LINFO.NE.0 )
388:      $      GO TO 70
389: *
390: *        Compute F-norm(S21) in BRQA21. (T21 is 0.)
391: *
392:          DSCALE = ZERO
393:          DSUM = ONE
394:          DO 30 I = 1, N2
395:             CALL SLASSQ( N1, S( N2+1, I ), 1, DSCALE, DSUM )
396:    30    CONTINUE
397:          BRQA21 = DSCALE*SQRT( DSUM )
398: *
399: *        Triangularize the B-part by a QR factorization.
400: *        Apply transformation (from right) to A-part, giving S.
401: *
402:          CALL SGEQR2( M, M, TCPY, LDST, TAUL, WORK, LINFO )
403:          IF( LINFO.NE.0 )
404:      $      GO TO 70
405:          CALL SORM2R( 'L', 'T', M, M, M, TCPY, LDST, TAUL, SCPY, LDST,
406:      $                WORK, INFO )
407:          CALL SORM2R( 'R', 'N', M, M, M, TCPY, LDST, TAUL, LICOP, LDST,
408:      $                WORK, INFO )
409:          IF( LINFO.NE.0 )
410:      $      GO TO 70
411: *
412: *        Compute F-norm(S21) in BQRA21. (T21 is 0.)
413: *
414:          DSCALE = ZERO
415:          DSUM = ONE
416:          DO 40 I = 1, N2
417:             CALL SLASSQ( N1, SCPY( N2+1, I ), 1, DSCALE, DSUM )
418:    40    CONTINUE
419:          BQRA21 = DSCALE*SQRT( DSUM )
420: *
421: *        Decide which method to use.
422: *          Weak stability test:
423: *             F-norm(S21) <= O(EPS * F-norm((S, T)))
424: *
425:          IF( BQRA21.LE.BRQA21 .AND. BQRA21.LE.THRESH ) THEN
426:             CALL SLACPY( 'F', M, M, SCPY, LDST, S, LDST )
427:             CALL SLACPY( 'F', M, M, TCPY, LDST, T, LDST )
428:             CALL SLACPY( 'F', M, M, IRCOP, LDST, IR, LDST )
429:             CALL SLACPY( 'F', M, M, LICOP, LDST, LI, LDST )
430:          ELSE IF( BRQA21.GE.THRESH ) THEN
431:             GO TO 70
432:          END IF
433: *
434: *        Set lower triangle of B-part to zero
435: *
436:          CALL SLASET( 'Lower', M-1, M-1, ZERO, ZERO, T(2,1), LDST )
437: *
438:          IF( WANDS ) THEN
439: *
440: *           Strong stability test:
441: *              F-norm((A-QL*S*QR', B-QL*T*QR')) <= O(EPS*F-norm((A,B)))
442: *
443:             CALL SLACPY( 'Full', M, M, A( J1, J1 ), LDA, WORK( M*M+1 ),
444:      $                   M )
445:             CALL SGEMM( 'N', 'N', M, M, M, ONE, LI, LDST, S, LDST, ZERO,
446:      $                  WORK, M )
447:             CALL SGEMM( 'N', 'N', M, M, M, -ONE, WORK, M, IR, LDST, ONE,
448:      $                  WORK( M*M+1 ), M )
449:             DSCALE = ZERO
450:             DSUM = ONE
451:             CALL SLASSQ( M*M, WORK( M*M+1 ), 1, DSCALE, DSUM )
452: *
453:             CALL SLACPY( 'Full', M, M, B( J1, J1 ), LDB, WORK( M*M+1 ),
454:      $                   M )
455:             CALL SGEMM( 'N', 'N', M, M, M, ONE, LI, LDST, T, LDST, ZERO,
456:      $                  WORK, M )
457:             CALL SGEMM( 'N', 'N', M, M, M, -ONE, WORK, M, IR, LDST, ONE,
458:      $                  WORK( M*M+1 ), M )
459:             CALL SLASSQ( M*M, WORK( M*M+1 ), 1, DSCALE, DSUM )
460:             SS = DSCALE*SQRT( DSUM )
461:             STRONG = ( SS.LE.THRESH )
462:             IF( .NOT.STRONG )
463:      $         GO TO 70
464: *
465:          END IF
466: *
467: *        If the swap is accepted ("weakly" and "strongly"), apply the
468: *        transformations and set N1-by-N2 (2,1)-block to zero.
469: *
470:          CALL SLASET( 'Full', N1, N2, ZERO, ZERO, S(N2+1,1), LDST )
471: *
472: *        copy back M-by-M diagonal block starting at index J1 of (A, B)
473: *
474:          CALL SLACPY( 'F', M, M, S, LDST, A( J1, J1 ), LDA )
475:          CALL SLACPY( 'F', M, M, T, LDST, B( J1, J1 ), LDB )
476:          CALL SLASET( 'Full', LDST, LDST, ZERO, ZERO, T, LDST )
477: *
478: *        Standardize existing 2-by-2 blocks.
479: *
480:          DO 50 I = 1, M*M
481:             WORK(I) = ZERO
482:    50    CONTINUE
483:          WORK( 1 ) = ONE
484:          T( 1, 1 ) = ONE
485:          IDUM = LWORK - M*M - 2
486:          IF( N2.GT.1 ) THEN
487:             CALL SLAGV2( A( J1, J1 ), LDA, B( J1, J1 ), LDB, AR, AI, BE,
488:      $                   WORK( 1 ), WORK( 2 ), T( 1, 1 ), T( 2, 1 ) )
489:             WORK( M+1 ) = -WORK( 2 )
490:             WORK( M+2 ) = WORK( 1 )
491:             T( N2, N2 ) = T( 1, 1 )
492:             T( 1, 2 ) = -T( 2, 1 )
493:          END IF
494:          WORK( M*M ) = ONE
495:          T( M, M ) = ONE
496: *
497:          IF( N1.GT.1 ) THEN
498:             CALL SLAGV2( A( J1+N2, J1+N2 ), LDA, B( J1+N2, J1+N2 ), LDB,
499:      $                   TAUR, TAUL, WORK( M*M+1 ), WORK( N2*M+N2+1 ),
500:      $                   WORK( N2*M+N2+2 ), T( N2+1, N2+1 ),
501:      $                   T( M, M-1 ) )
502:             WORK( M*M ) = WORK( N2*M+N2+1 )
503:             WORK( M*M-1 ) = -WORK( N2*M+N2+2 )
504:             T( M, M ) = T( N2+1, N2+1 )
505:             T( M-1, M ) = -T( M, M-1 )
506:          END IF
507:          CALL SGEMM( 'T', 'N', N2, N1, N2, ONE, WORK, M, A( J1, J1+N2 ),
508:      $               LDA, ZERO, WORK( M*M+1 ), N2 )
509:          CALL SLACPY( 'Full', N2, N1, WORK( M*M+1 ), N2, A( J1, J1+N2 ),
510:      $                LDA )
511:          CALL SGEMM( 'T', 'N', N2, N1, N2, ONE, WORK, M, B( J1, J1+N2 ),
512:      $               LDB, ZERO, WORK( M*M+1 ), N2 )
513:          CALL SLACPY( 'Full', N2, N1, WORK( M*M+1 ), N2, B( J1, J1+N2 ),
514:      $                LDB )
515:          CALL SGEMM( 'N', 'N', M, M, M, ONE, LI, LDST, WORK, M, ZERO,
516:      $               WORK( M*M+1 ), M )
517:          CALL SLACPY( 'Full', M, M, WORK( M*M+1 ), M, LI, LDST )
518:          CALL SGEMM( 'N', 'N', N2, N1, N1, ONE, A( J1, J1+N2 ), LDA,
519:      $               T( N2+1, N2+1 ), LDST, ZERO, WORK, N2 )
520:          CALL SLACPY( 'Full', N2, N1, WORK, N2, A( J1, J1+N2 ), LDA )
521:          CALL SGEMM( 'N', 'N', N2, N1, N1, ONE, B( J1, J1+N2 ), LDB,
522:      $               T( N2+1, N2+1 ), LDST, ZERO, WORK, N2 )
523:          CALL SLACPY( 'Full', N2, N1, WORK, N2, B( J1, J1+N2 ), LDB )
524:          CALL SGEMM( 'T', 'N', M, M, M, ONE, IR, LDST, T, LDST, ZERO,
525:      $               WORK, M )
526:          CALL SLACPY( 'Full', M, M, WORK, M, IR, LDST )
527: *
528: *        Accumulate transformations into Q and Z if requested.
529: *
530:          IF( WANTQ ) THEN
531:             CALL SGEMM( 'N', 'N', N, M, M, ONE, Q( 1, J1 ), LDQ, LI,
532:      $                  LDST, ZERO, WORK, N )
533:             CALL SLACPY( 'Full', N, M, WORK, N, Q( 1, J1 ), LDQ )
534: *
535:          END IF
536: *
537:          IF( WANTZ ) THEN
538:             CALL SGEMM( 'N', 'N', N, M, M, ONE, Z( 1, J1 ), LDZ, IR,
539:      $                  LDST, ZERO, WORK, N )
540:             CALL SLACPY( 'Full', N, M, WORK, N, Z( 1, J1 ), LDZ )
541: *
542:          END IF
543: *
544: *        Update (A(J1:J1+M-1, M+J1:N), B(J1:J1+M-1, M+J1:N)) and
545: *                (A(1:J1-1, J1:J1+M), B(1:J1-1, J1:J1+M)).
546: *
547:          I = J1 + M
548:          IF( I.LE.N ) THEN
549:             CALL SGEMM( 'T', 'N', M, N-I+1, M, ONE, LI, LDST,
550:      $                  A( J1, I ), LDA, ZERO, WORK, M )
551:             CALL SLACPY( 'Full', M, N-I+1, WORK, M, A( J1, I ), LDA )
552:             CALL SGEMM( 'T', 'N', M, N-I+1, M, ONE, LI, LDST,
553:      $                  B( J1, I ), LDB, ZERO, WORK, M )
554:             CALL SLACPY( 'Full', M, N-I+1, WORK, M, B( J1, I ), LDB )
555:          END IF
556:          I = J1 - 1
557:          IF( I.GT.0 ) THEN
558:             CALL SGEMM( 'N', 'N', I, M, M, ONE, A( 1, J1 ), LDA, IR,
559:      $                  LDST, ZERO, WORK, I )
560:             CALL SLACPY( 'Full', I, M, WORK, I, A( 1, J1 ), LDA )
561:             CALL SGEMM( 'N', 'N', I, M, M, ONE, B( 1, J1 ), LDB, IR,
562:      $                  LDST, ZERO, WORK, I )
563:             CALL SLACPY( 'Full', I, M, WORK, I, B( 1, J1 ), LDB )
564:          END IF
565: *
566: *        Exit with INFO = 0 if swap was successfully performed.
567: *
568:          RETURN
569: *
570:       END IF
571: *
572: *     Exit with INFO = 1 if swap was rejected.
573: *
574:    70 CONTINUE
575: *
576:       INFO = 1
577:       RETURN
578: *
579: *     End of STGEX2
580: *
581:       END
582: