001:       SUBROUTINE SPPTRS( UPLO, N, NRHS, AP, B, LDB, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
005: *     November 2006
006: *
007: *     .. Scalar Arguments ..
008:       CHARACTER          UPLO
009:       INTEGER            INFO, LDB, N, NRHS
010: *     ..
011: *     .. Array Arguments ..
012:       REAL               AP( * ), B( LDB, * )
013: *     ..
014: *
015: *  Purpose
016: *  =======
017: *
018: *  SPPTRS solves a system of linear equations A*X = B with a symmetric
019: *  positive definite matrix A in packed storage using the Cholesky
020: *  factorization A = U**T*U or A = L*L**T computed by SPPTRF.
021: *
022: *  Arguments
023: *  =========
024: *
025: *  UPLO    (input) CHARACTER*1
026: *          = 'U':  Upper triangle of A is stored;
027: *          = 'L':  Lower triangle of A is stored.
028: *
029: *  N       (input) INTEGER
030: *          The order of the matrix A.  N >= 0.
031: *
032: *  NRHS    (input) INTEGER
033: *          The number of right hand sides, i.e., the number of columns
034: *          of the matrix B.  NRHS >= 0.
035: *
036: *  AP      (input) REAL array, dimension (N*(N+1)/2)
037: *          The triangular factor U or L from the Cholesky factorization
038: *          A = U**T*U or A = L*L**T, packed columnwise in a linear
039: *          array.  The j-th column of U or L is stored in the array AP
040: *          as follows:
041: *          if UPLO = 'U', AP(i + (j-1)*j/2) = U(i,j) for 1<=i<=j;
042: *          if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = L(i,j) for j<=i<=n.
043: *
044: *  B       (input/output) REAL array, dimension (LDB,NRHS)
045: *          On entry, the right hand side matrix B.
046: *          On exit, the solution matrix X.
047: *
048: *  LDB     (input) INTEGER
049: *          The leading dimension of the array B.  LDB >= max(1,N).
050: *
051: *  INFO    (output) INTEGER
052: *          = 0:  successful exit
053: *          < 0:  if INFO = -i, the i-th argument had an illegal value
054: *
055: *  =====================================================================
056: *
057: *     .. Local Scalars ..
058:       LOGICAL            UPPER
059:       INTEGER            I
060: *     ..
061: *     .. External Functions ..
062:       LOGICAL            LSAME
063:       EXTERNAL           LSAME
064: *     ..
065: *     .. External Subroutines ..
066:       EXTERNAL           STPSV, XERBLA
067: *     ..
068: *     .. Intrinsic Functions ..
069:       INTRINSIC          MAX
070: *     ..
071: *     .. Executable Statements ..
072: *
073: *     Test the input parameters.
074: *
075:       INFO = 0
076:       UPPER = LSAME( UPLO, 'U' )
077:       IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
078:          INFO = -1
079:       ELSE IF( N.LT.0 ) THEN
080:          INFO = -2
081:       ELSE IF( NRHS.LT.0 ) THEN
082:          INFO = -3
083:       ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
084:          INFO = -6
085:       END IF
086:       IF( INFO.NE.0 ) THEN
087:          CALL XERBLA( 'SPPTRS', -INFO )
088:          RETURN
089:       END IF
090: *
091: *     Quick return if possible
092: *
093:       IF( N.EQ.0 .OR. NRHS.EQ.0 )
094:      $   RETURN
095: *
096:       IF( UPPER ) THEN
097: *
098: *        Solve A*X = B where A = U'*U.
099: *
100:          DO 10 I = 1, NRHS
101: *
102: *           Solve U'*X = B, overwriting B with X.
103: *
104:             CALL STPSV( 'Upper', 'Transpose', 'Non-unit', N, AP,
105:      $                  B( 1, I ), 1 )
106: *
107: *           Solve U*X = B, overwriting B with X.
108: *
109:             CALL STPSV( 'Upper', 'No transpose', 'Non-unit', N, AP,
110:      $                  B( 1, I ), 1 )
111:    10    CONTINUE
112:       ELSE
113: *
114: *        Solve A*X = B where A = L*L'.
115: *
116:          DO 20 I = 1, NRHS
117: *
118: *           Solve L*Y = B, overwriting B with X.
119: *
120:             CALL STPSV( 'Lower', 'No transpose', 'Non-unit', N, AP,
121:      $                  B( 1, I ), 1 )
122: *
123: *           Solve L'*X = Y, overwriting B with X.
124: *
125:             CALL STPSV( 'Lower', 'Transpose', 'Non-unit', N, AP,
126:      $                  B( 1, I ), 1 )
127:    20    CONTINUE
128:       END IF
129: *
130:       RETURN
131: *
132: *     End of SPPTRS
133: *
134:       END
135: