001:       SUBROUTINE SORGRQ( M, N, K, A, LDA, TAU, WORK, LWORK, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
005: *     November 2006
006: *
007: *     .. Scalar Arguments ..
008:       INTEGER            INFO, K, LDA, LWORK, M, N
009: *     ..
010: *     .. Array Arguments ..
011:       REAL               A( LDA, * ), TAU( * ), WORK( * )
012: *     ..
013: *
014: *  Purpose
015: *  =======
016: *
017: *  SORGRQ generates an M-by-N real matrix Q with orthonormal rows,
018: *  which is defined as the last M rows of a product of K elementary
019: *  reflectors of order N
020: *
021: *        Q  =  H(1) H(2) . . . H(k)
022: *
023: *  as returned by SGERQF.
024: *
025: *  Arguments
026: *  =========
027: *
028: *  M       (input) INTEGER
029: *          The number of rows of the matrix Q. M >= 0.
030: *
031: *  N       (input) INTEGER
032: *          The number of columns of the matrix Q. N >= M.
033: *
034: *  K       (input) INTEGER
035: *          The number of elementary reflectors whose product defines the
036: *          matrix Q. M >= K >= 0.
037: *
038: *  A       (input/output) REAL array, dimension (LDA,N)
039: *          On entry, the (m-k+i)-th row must contain the vector which
040: *          defines the elementary reflector H(i), for i = 1,2,...,k, as
041: *          returned by SGERQF in the last k rows of its array argument
042: *          A.
043: *          On exit, the M-by-N matrix Q.
044: *
045: *  LDA     (input) INTEGER
046: *          The first dimension of the array A. LDA >= max(1,M).
047: *
048: *  TAU     (input) REAL array, dimension (K)
049: *          TAU(i) must contain the scalar factor of the elementary
050: *          reflector H(i), as returned by SGERQF.
051: *
052: *  WORK    (workspace/output) REAL array, dimension (MAX(1,LWORK))
053: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
054: *
055: *  LWORK   (input) INTEGER
056: *          The dimension of the array WORK. LWORK >= max(1,M).
057: *          For optimum performance LWORK >= M*NB, where NB is the
058: *          optimal blocksize.
059: *
060: *          If LWORK = -1, then a workspace query is assumed; the routine
061: *          only calculates the optimal size of the WORK array, returns
062: *          this value as the first entry of the WORK array, and no error
063: *          message related to LWORK is issued by XERBLA.
064: *
065: *  INFO    (output) INTEGER
066: *          = 0:  successful exit
067: *          < 0:  if INFO = -i, the i-th argument has an illegal value
068: *
069: *  =====================================================================
070: *
071: *     .. Parameters ..
072:       REAL               ZERO
073:       PARAMETER          ( ZERO = 0.0E+0 )
074: *     ..
075: *     .. Local Scalars ..
076:       LOGICAL            LQUERY
077:       INTEGER            I, IB, II, IINFO, IWS, J, KK, L, LDWORK,
078:      $                   LWKOPT, NB, NBMIN, NX
079: *     ..
080: *     .. External Subroutines ..
081:       EXTERNAL           SLARFB, SLARFT, SORGR2, XERBLA
082: *     ..
083: *     .. Intrinsic Functions ..
084:       INTRINSIC          MAX, MIN
085: *     ..
086: *     .. External Functions ..
087:       INTEGER            ILAENV
088:       EXTERNAL           ILAENV
089: *     ..
090: *     .. Executable Statements ..
091: *
092: *     Test the input arguments
093: *
094:       INFO = 0
095:       LQUERY = ( LWORK.EQ.-1 )
096:       IF( M.LT.0 ) THEN
097:          INFO = -1
098:       ELSE IF( N.LT.M ) THEN
099:          INFO = -2
100:       ELSE IF( K.LT.0 .OR. K.GT.M ) THEN
101:          INFO = -3
102:       ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
103:          INFO = -5
104:       END IF
105: *
106:       IF( INFO.EQ.0 ) THEN
107:          IF( M.LE.0 ) THEN
108:             LWKOPT = 1
109:          ELSE
110:             NB = ILAENV( 1, 'SORGRQ', ' ', M, N, K, -1 )
111:             LWKOPT = M*NB
112:          END IF
113:          WORK( 1 ) = LWKOPT
114: *
115:          IF( LWORK.LT.MAX( 1, M ) .AND. .NOT.LQUERY ) THEN
116:             INFO = -8
117:          END IF
118:       END IF
119: *
120:       IF( INFO.NE.0 ) THEN
121:          CALL XERBLA( 'SORGRQ', -INFO )
122:          RETURN
123:       ELSE IF( LQUERY ) THEN
124:          RETURN
125:       END IF
126: *
127: *     Quick return if possible
128: *
129:       IF( M.LE.0 ) THEN
130:          RETURN
131:       END IF
132: *
133:       NBMIN = 2
134:       NX = 0
135:       IWS = M
136:       IF( NB.GT.1 .AND. NB.LT.K ) THEN
137: *
138: *        Determine when to cross over from blocked to unblocked code.
139: *
140:          NX = MAX( 0, ILAENV( 3, 'SORGRQ', ' ', M, N, K, -1 ) )
141:          IF( NX.LT.K ) THEN
142: *
143: *           Determine if workspace is large enough for blocked code.
144: *
145:             LDWORK = M
146:             IWS = LDWORK*NB
147:             IF( LWORK.LT.IWS ) THEN
148: *
149: *              Not enough workspace to use optimal NB:  reduce NB and
150: *              determine the minimum value of NB.
151: *
152:                NB = LWORK / LDWORK
153:                NBMIN = MAX( 2, ILAENV( 2, 'SORGRQ', ' ', M, N, K, -1 ) )
154:             END IF
155:          END IF
156:       END IF
157: *
158:       IF( NB.GE.NBMIN .AND. NB.LT.K .AND. NX.LT.K ) THEN
159: *
160: *        Use blocked code after the first block.
161: *        The last kk rows are handled by the block method.
162: *
163:          KK = MIN( K, ( ( K-NX+NB-1 ) / NB )*NB )
164: *
165: *        Set A(1:m-kk,n-kk+1:n) to zero.
166: *
167:          DO 20 J = N - KK + 1, N
168:             DO 10 I = 1, M - KK
169:                A( I, J ) = ZERO
170:    10       CONTINUE
171:    20    CONTINUE
172:       ELSE
173:          KK = 0
174:       END IF
175: *
176: *     Use unblocked code for the first or only block.
177: *
178:       CALL SORGR2( M-KK, N-KK, K-KK, A, LDA, TAU, WORK, IINFO )
179: *
180:       IF( KK.GT.0 ) THEN
181: *
182: *        Use blocked code
183: *
184:          DO 50 I = K - KK + 1, K, NB
185:             IB = MIN( NB, K-I+1 )
186:             II = M - K + I
187:             IF( II.GT.1 ) THEN
188: *
189: *              Form the triangular factor of the block reflector
190: *              H = H(i+ib-1) . . . H(i+1) H(i)
191: *
192:                CALL SLARFT( 'Backward', 'Rowwise', N-K+I+IB-1, IB,
193:      $                      A( II, 1 ), LDA, TAU( I ), WORK, LDWORK )
194: *
195: *              Apply H' to A(1:m-k+i-1,1:n-k+i+ib-1) from the right
196: *
197:                CALL SLARFB( 'Right', 'Transpose', 'Backward', 'Rowwise',
198:      $                      II-1, N-K+I+IB-1, IB, A( II, 1 ), LDA, WORK,
199:      $                      LDWORK, A, LDA, WORK( IB+1 ), LDWORK )
200:             END IF
201: *
202: *           Apply H' to columns 1:n-k+i+ib-1 of current block
203: *
204:             CALL SORGR2( IB, N-K+I+IB-1, IB, A( II, 1 ), LDA, TAU( I ),
205:      $                   WORK, IINFO )
206: *
207: *           Set columns n-k+i+ib:n of current block to zero
208: *
209:             DO 40 L = N - K + I + IB, N
210:                DO 30 J = II, II + IB - 1
211:                   A( J, L ) = ZERO
212:    30          CONTINUE
213:    40       CONTINUE
214:    50    CONTINUE
215:       END IF
216: *
217:       WORK( 1 ) = IWS
218:       RETURN
219: *
220: *     End of SORGRQ
221: *
222:       END
223: