001:       SUBROUTINE SLA_SYRFSX_EXTENDED( PREC_TYPE, UPLO, N, NRHS, A, LDA,
002:      $                                AF, LDAF, IPIV, COLEQU, C, B, LDB,
003:      $                                Y, LDY, BERR_OUT, N_NORMS, ERRS_N,
004:      $                                ERRS_C, RES, AYB, DY, Y_TAIL,
005:      $                                RCOND, ITHRESH, RTHRESH, DZ_UB,
006:      $                                IGNORE_CWISE, INFO )
007: *
008: *     -- LAPACK routine (version 3.2)                                 --
009: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
010: *     -- Jason Riedy of Univ. of California Berkeley.                 --
011: *     -- November 2008                                                --
012: *
013: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
014: *     -- Univ. of California Berkeley and NAG Ltd.                    --
015: *
016:       IMPLICIT NONE
017: *     ..
018: *     .. Scalar Arguments ..
019:       INTEGER            INFO, LDA, LDAF, LDB, LDY, N, NRHS, PREC_TYPE,
020:      $                   N_NORMS, ITHRESH
021:       CHARACTER          UPLO
022:       LOGICAL            COLEQU, IGNORE_CWISE
023:       REAL               RTHRESH, DZ_UB
024: *     ..
025: *     .. Array Arguments ..
026:       INTEGER            IPIV( * )
027:       REAL               A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
028:      $                   Y( LDY, * ), RES( * ), DY( * ), Y_TAIL( * )
029:       REAL               C( * ), AYB( * ), RCOND, BERR_OUT( * ),
030:      $                   ERRS_N( NRHS, * ), ERRS_C( NRHS, * )
031: *     ..
032: *     .. Local Scalars ..
033:       INTEGER            UPLO2, CNT, I, J, X_STATE, Z_STATE
034:       REAL               YK, DYK, YMIN, NORMY, NORMX, NORMDX, DXRAT,
035:      $                   DZRAT, PREVNORMDX, PREV_DZ_Z, DXRATMAX,
036:      $                   DZRATMAX, DX_X, DZ_Z, FINAL_DX_X, FINAL_DZ_Z,
037:      $                   EPS, HUGEVAL, INCR_THRESH
038:       LOGICAL            INCR_PREC
039: *     ..
040: *     .. Parameters ..
041:       INTEGER            UNSTABLE_STATE, WORKING_STATE, CONV_STATE,
042:      $                   NOPROG_STATE, Y_PREC_STATE, BASE_RESIDUAL,
043:      $                   EXTRA_RESIDUAL, EXTRA_Y
044:       PARAMETER          ( UNSTABLE_STATE = 0, WORKING_STATE = 1,
045:      $                   CONV_STATE = 2, NOPROG_STATE = 3 )
046:       PARAMETER          ( BASE_RESIDUAL = 0, EXTRA_RESIDUAL = 1,
047:      $                   EXTRA_Y = 2 )
048:       INTEGER            FINAL_NRM_ERR_I, FINAL_CMP_ERR_I, BERR_I
049:       INTEGER            RCOND_I, NRM_RCOND_I, NRM_ERR_I, CMP_RCOND_I
050:       INTEGER            CMP_ERR_I, PIV_GROWTH_I
051:       PARAMETER          ( FINAL_NRM_ERR_I = 1, FINAL_CMP_ERR_I = 2,
052:      $                   BERR_I = 3 )
053:       PARAMETER          ( RCOND_I = 4, NRM_RCOND_I = 5, NRM_ERR_I = 6 )
054:       PARAMETER          ( CMP_RCOND_I = 7, CMP_ERR_I = 8,
055:      $                   PIV_GROWTH_I = 9 )
056:       INTEGER            LA_LINRX_ITREF_I, LA_LINRX_ITHRESH_I,
057:      $                   LA_LINRX_CWISE_I
058:       PARAMETER          ( LA_LINRX_ITREF_I = 1,
059:      $                   LA_LINRX_ITHRESH_I = 2 )
060:       PARAMETER          ( LA_LINRX_CWISE_I = 3 )
061:       INTEGER            LA_LINRX_TRUST_I, LA_LINRX_ERR_I,
062:      $                   LA_LINRX_RCOND_I
063:       PARAMETER          ( LA_LINRX_TRUST_I = 1, LA_LINRX_ERR_I = 2 )
064:       PARAMETER          ( LA_LINRX_RCOND_I = 3 )
065:       INTEGER            LA_LINRX_MAX_N_ERRS
066:       PARAMETER          ( LA_LINRX_MAX_N_ERRS = 3 )
067: *     ..
068: *     .. External Functions ..
069:       LOGICAL            LSAME
070:       EXTERNAL           ILAUPLO
071:       INTEGER            ILAUPLO
072: *     ..
073: *     .. External Subroutines ..
074:       EXTERNAL           SAXPY, SCOPY, SSYTRS, SSYMV, BLAS_SSYMV_X,
075:      $                   BLAS_SSYMV2_X, SLA_SYAMV, SLA_WWADDW,
076:      $                   SLA_LIN_BERR
077:       REAL               SLAMCH
078: *     ..
079: *     .. Intrinsic Functions ..
080:       INTRINSIC          ABS, MAX, MIN
081: *     ..
082: *     .. Executable Statements ..
083: *
084:       IF ( INFO.NE.0 ) RETURN
085:       EPS = SLAMCH( 'Epsilon' )
086:       HUGEVAL = SLAMCH( 'Overflow' )
087: *     Force HUGEVAL to Inf
088:       HUGEVAL = HUGEVAL * HUGEVAL
089: *     Using HUGEVAL may lead to spurious underflows.
090:       INCR_THRESH = REAL( N )*EPS
091: 
092:       IF ( LSAME ( UPLO, 'L' ) ) THEN
093:          UPLO2 = ILAUPLO( 'L' )
094:       ELSE
095:          UPLO2 = ILAUPLO( 'U' )
096:       ENDIF
097: 
098:       DO J = 1, NRHS
099:          Y_PREC_STATE = EXTRA_RESIDUAL
100:          IF ( Y_PREC_STATE .EQ. EXTRA_Y ) THEN
101:             DO I = 1, N
102:                Y_TAIL( I ) = 0.0
103:             END DO
104:          END IF
105: 
106:          DXRAT = 0.0
107:          DXRATMAX = 0.0
108:          DZRAT = 0.0
109:          DZRATMAX = 0.0
110:          FINAL_DX_X = HUGEVAL
111:          FINAL_DZ_Z = HUGEVAL
112:          PREVNORMDX = HUGEVAL
113:          PREV_DZ_Z = HUGEVAL
114:          DZ_Z = HUGEVAL
115:          DX_X = HUGEVAL
116: 
117:          X_STATE = WORKING_STATE
118:          Z_STATE = UNSTABLE_STATE
119:          INCR_PREC = .FALSE.
120: 
121:          DO CNT = 1, ITHRESH
122: *
123: *        Compute residual RES = B_s - op(A_s) * Y,
124: *            op(A) = A, A**T, or A**H depending on TRANS (and type).
125: *
126:             CALL SCOPY( N, B( 1, J ), 1, RES, 1 )
127:             IF (Y_PREC_STATE .EQ. BASE_RESIDUAL) THEN
128:                CALL SSYMV( UPLO, N, -1.0, A, LDA, Y(1,J), 1,
129:      $              1.0, RES, 1 )
130:             ELSE IF (Y_PREC_STATE .EQ. EXTRA_RESIDUAL) THEN
131:                CALL BLAS_SSYMV_X( UPLO2, N, -1.0, A, LDA,
132:      $              Y( 1, J ), 1, 1.0, RES, 1, PREC_TYPE )
133:             ELSE
134:                CALL BLAS_SSYMV2_X(UPLO2, N, -1.0, A, LDA,
135:      $              Y(1, J), Y_TAIL, 1, 1.0, RES, 1, PREC_TYPE)
136:             END IF
137:             
138: !         XXX: RES is no longer needed.
139:             CALL SCOPY( N, RES, 1, DY, 1 )
140:             CALL SSYTRS( UPLO, N, NRHS, AF, LDAF, IPIV, DY, N, INFO )
141: *
142: *         Calculate relative changes DX_X, DZ_Z and ratios DXRAT, DZRAT.
143: *
144:             NORMX = 0.0
145:             NORMY = 0.0
146:             NORMDX = 0.0
147:             DZ_Z = 0.0
148:             YMIN = HUGEVAL
149:             
150:             DO I = 1, N
151:                YK = ABS( Y( I, J ) )
152:                DYK = ABS( DY( I ) )
153:                
154:                IF ( YK .NE. 0.0 ) THEN
155:                   DZ_Z = MAX( DZ_Z, DYK / YK )
156:                ELSE IF ( DYK .NE. 0.0 ) THEN
157:                   DZ_Z = HUGEVAL
158:                END IF
159: 
160:                YMIN = MIN( YMIN, YK )
161: 
162:                NORMY = MAX( NORMY, YK )
163: 
164:                IF ( COLEQU ) THEN
165:                   NORMX = MAX( NORMX, YK * C( I ) )
166:                   NORMDX = MAX( NORMDX, DYK * C( I ) )
167:                ELSE
168:                   NORMX = NORMY
169:                   NORMDX = MAX(NORMDX, DYK)
170:                END IF
171:             END DO
172: 
173:             IF ( NORMX .NE. 0.0 ) THEN
174:                DX_X = NORMDX / NORMX
175:             ELSE IF ( NORMDX .EQ. 0.0 ) THEN
176:                DX_X = 0.0
177:             ELSE
178:                DX_X = HUGEVAL
179:             END IF
180: 
181:             DXRAT = NORMDX / PREVNORMDX
182:             DZRAT = DZ_Z / PREV_DZ_Z
183: *
184: *         Check termination criteria.
185: *
186:             IF ( YMIN*RCOND .LT. INCR_THRESH*NORMY
187:      $           .AND. Y_PREC_STATE .LT. EXTRA_Y )
188:      $           INCR_PREC = .TRUE.
189: 
190:             IF ( X_STATE .EQ. NOPROG_STATE .AND. DXRAT .LE. RTHRESH )
191:      $           X_STATE = WORKING_STATE
192:             IF ( X_STATE .EQ. WORKING_STATE ) THEN
193:                IF ( DX_X .LE. EPS ) THEN
194:                   X_STATE = CONV_STATE
195:                ELSE IF ( DXRAT .GT. RTHRESH ) THEN
196:                   IF ( Y_PREC_STATE .NE. EXTRA_Y ) THEN
197:                      INCR_PREC = .TRUE.
198:                   ELSE
199:                      X_STATE = NOPROG_STATE
200:                   END IF
201:                ELSE
202:                   IF ( DXRAT .GT. DXRATMAX ) DXRATMAX = DXRAT
203:                END IF
204:                IF ( X_STATE .GT. WORKING_STATE ) FINAL_DX_X = DX_X
205:             END IF
206: 
207:             IF ( Z_STATE .EQ. UNSTABLE_STATE .AND. DZ_Z .LE. DZ_UB )
208:      $           Z_STATE = WORKING_STATE
209:             IF ( Z_STATE .EQ. NOPROG_STATE .AND. DZRAT .LE. RTHRESH )
210:      $           Z_STATE = WORKING_STATE
211:             IF ( Z_STATE .EQ. WORKING_STATE ) THEN
212:                IF ( DZ_Z .LE. EPS ) THEN
213:                   Z_STATE = CONV_STATE
214:                ELSE IF ( DZ_Z .GT. DZ_UB ) THEN
215:                   Z_STATE = UNSTABLE_STATE
216:                   DZRATMAX = 0.0
217:                   FINAL_DZ_Z = HUGEVAL
218:                ELSE IF ( DZRAT .GT. RTHRESH ) THEN
219:                   IF ( Y_PREC_STATE .NE. EXTRA_Y ) THEN
220:                      INCR_PREC = .TRUE.
221:                   ELSE
222:                      Z_STATE = NOPROG_STATE
223:                   END IF
224:                ELSE
225:                   IF ( DZRAT .GT. DZRATMAX ) DZRATMAX = DZRAT
226:                END IF
227:                IF ( Z_STATE .GT. WORKING_STATE ) FINAL_DZ_Z = DZ_Z
228:             END IF
229: 
230:             IF ( X_STATE.NE.WORKING_STATE.AND.
231:      $           ( IGNORE_CWISE.OR.Z_STATE.NE.WORKING_STATE ) )
232:      $           GOTO 666
233: 
234:             IF ( INCR_PREC ) THEN
235:                INCR_PREC = .FALSE.
236:                Y_PREC_STATE = Y_PREC_STATE + 1
237:                DO I = 1, N
238:                   Y_TAIL( I ) = 0.0
239:                END DO
240:             END IF
241: 
242:             PREVNORMDX = NORMDX
243:             PREV_DZ_Z = DZ_Z
244: *
245: *           Update soluton.
246: *
247:             IF (Y_PREC_STATE .LT. EXTRA_Y) THEN
248:                CALL SAXPY( N, 1.0, DY, 1, Y(1,J), 1 )
249:             ELSE
250:                CALL SLA_WWADDW( N, Y(1,J), Y_TAIL, DY )
251:             END IF
252:             
253:          END DO
254: *        Target of "IF (Z_STOP .AND. X_STOP)".  Sun's f77 won't EXIT.
255:  666     CONTINUE
256: *
257: *     Set final_* when cnt hits ithresh.
258: *
259:          IF ( X_STATE .EQ. WORKING_STATE ) FINAL_DX_X = DX_X
260:          IF ( Z_STATE .EQ. WORKING_STATE ) FINAL_DZ_Z = DZ_Z
261: *
262: *     Compute error bounds.
263: *
264:          IF ( N_NORMS .GE. 1 ) THEN
265:             ERRS_N( J, LA_LINRX_ERR_I ) = FINAL_DX_X / (1 - DXRATMAX)
266:          END IF
267:          IF ( N_NORMS .GE. 2 ) THEN
268:             ERRS_C( J, LA_LINRX_ERR_I ) = FINAL_DZ_Z / (1 - DZRATMAX)
269:          END IF
270: *
271: *     Compute componentwise relative backward error from formula
272: *         max(i) ( abs(R(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
273: *     where abs(Z) is the componentwise absolute value of the matrix
274: *     or vector Z.
275: *
276: *        Compute residual RES = B_s - op(A_s) * Y,
277: *            op(A) = A, A**T, or A**H depending on TRANS (and type).
278:          CALL SCOPY( N, B( 1, J ), 1, RES, 1 )
279:          CALL SSYMV( UPLO, N, -1.0, A, LDA, Y(1,J), 1, 1.0, RES, 1 )
280:          
281:          DO I = 1, N
282:             AYB( I ) = ABS( B( I, J ) )
283:          END DO
284: *
285: *     Compute abs(op(A_s))*abs(Y) + abs(B_s).
286: *
287:          CALL SLA_SYAMV( UPLO2, N, 1.0,
288:      $        A, LDA, Y(1, J), 1, 1.0, AYB, 1 )
289:          
290:          CALL SLA_LIN_BERR( N, N, 1, RES, AYB, BERR_OUT( J ) )
291: *
292: *     End of loop for each RHS.
293: *
294:       END DO
295: *
296:       RETURN
297:       END
298: