001:       SUBROUTINE SGELSD( M, N, NRHS, A, LDA, B, LDB, S, RCOND,
002:      $                   RANK, WORK, LWORK, IWORK, INFO )
003: *
004: *  -- LAPACK driver routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       INTEGER            INFO, LDA, LDB, LWORK, M, N, NRHS, RANK
010:       REAL               RCOND
011: *     ..
012: *     .. Array Arguments ..
013:       INTEGER            IWORK( * )
014:       REAL               A( LDA, * ), B( LDB, * ), S( * ), WORK( * )
015: *     ..
016: *
017: *  Purpose
018: *  =======
019: *
020: *  SGELSD computes the minimum-norm solution to a real linear least
021: *  squares problem:
022: *      minimize 2-norm(| b - A*x |)
023: *  using the singular value decomposition (SVD) of A. A is an M-by-N
024: *  matrix which may be rank-deficient.
025: *
026: *  Several right hand side vectors b and solution vectors x can be
027: *  handled in a single call; they are stored as the columns of the
028: *  M-by-NRHS right hand side matrix B and the N-by-NRHS solution
029: *  matrix X.
030: *
031: *  The problem is solved in three steps:
032: *  (1) Reduce the coefficient matrix A to bidiagonal form with
033: *      Householder transformations, reducing the original problem
034: *      into a "bidiagonal least squares problem" (BLS)
035: *  (2) Solve the BLS using a divide and conquer approach.
036: *  (3) Apply back all the Householder tranformations to solve
037: *      the original least squares problem.
038: *
039: *  The effective rank of A is determined by treating as zero those
040: *  singular values which are less than RCOND times the largest singular
041: *  value.
042: *
043: *  The divide and conquer algorithm makes very mild assumptions about
044: *  floating point arithmetic. It will work on machines with a guard
045: *  digit in add/subtract, or on those binary machines without guard
046: *  digits which subtract like the Cray X-MP, Cray Y-MP, Cray C-90, or
047: *  Cray-2. It could conceivably fail on hexadecimal or decimal machines
048: *  without guard digits, but we know of none.
049: *
050: *  Arguments
051: *  =========
052: *
053: *  M       (input) INTEGER
054: *          The number of rows of A. M >= 0.
055: *
056: *  N       (input) INTEGER
057: *          The number of columns of A. N >= 0.
058: *
059: *  NRHS    (input) INTEGER
060: *          The number of right hand sides, i.e., the number of columns
061: *          of the matrices B and X. NRHS >= 0.
062: *
063: *  A       (input) REAL array, dimension (LDA,N)
064: *          On entry, the M-by-N matrix A.
065: *          On exit, A has been destroyed.
066: *
067: *  LDA     (input) INTEGER
068: *          The leading dimension of the array A.  LDA >= max(1,M).
069: *
070: *  B       (input/output) REAL array, dimension (LDB,NRHS)
071: *          On entry, the M-by-NRHS right hand side matrix B.
072: *          On exit, B is overwritten by the N-by-NRHS solution
073: *          matrix X.  If m >= n and RANK = n, the residual
074: *          sum-of-squares for the solution in the i-th column is given
075: *          by the sum of squares of elements n+1:m in that column.
076: *
077: *  LDB     (input) INTEGER
078: *          The leading dimension of the array B. LDB >= max(1,max(M,N)).
079: *
080: *  S       (output) REAL array, dimension (min(M,N))
081: *          The singular values of A in decreasing order.
082: *          The condition number of A in the 2-norm = S(1)/S(min(m,n)).
083: *
084: *  RCOND   (input) REAL
085: *          RCOND is used to determine the effective rank of A.
086: *          Singular values S(i) <= RCOND*S(1) are treated as zero.
087: *          If RCOND < 0, machine precision is used instead.
088: *
089: *  RANK    (output) INTEGER
090: *          The effective rank of A, i.e., the number of singular values
091: *          which are greater than RCOND*S(1).
092: *
093: *  WORK    (workspace/output) REAL array, dimension (MAX(1,LWORK))
094: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
095: *
096: *  LWORK   (input) INTEGER
097: *          The dimension of the array WORK. LWORK must be at least 1.
098: *          The exact minimum amount of workspace needed depends on M,
099: *          N and NRHS. As long as LWORK is at least
100: *              12*N + 2*N*SMLSIZ + 8*N*NLVL + N*NRHS + (SMLSIZ+1)**2,
101: *          if M is greater than or equal to N or
102: *              12*M + 2*M*SMLSIZ + 8*M*NLVL + M*NRHS + (SMLSIZ+1)**2,
103: *          if M is less than N, the code will execute correctly.
104: *          SMLSIZ is returned by ILAENV and is equal to the maximum
105: *          size of the subproblems at the bottom of the computation
106: *          tree (usually about 25), and
107: *             NLVL = MAX( 0, INT( LOG_2( MIN( M,N )/(SMLSIZ+1) ) ) + 1 )
108: *          For good performance, LWORK should generally be larger.
109: *
110: *          If LWORK = -1, then a workspace query is assumed; the routine
111: *          only calculates the optimal size of the array WORK and the
112: *          minimum size of the array IWORK, and returns these values as
113: *          the first entries of the WORK and IWORK arrays, and no error
114: *          message related to LWORK is issued by XERBLA.
115: *
116: *  IWORK   (workspace) INTEGER array, dimension (MAX(1,LIWORK))
117: *          LIWORK >= max(1, 3*MINMN*NLVL + 11*MINMN),
118: *          where MINMN = MIN( M,N ).
119: *          On exit, if INFO = 0, IWORK(1) returns the minimum LIWORK.
120: *
121: *  INFO    (output) INTEGER
122: *          = 0:  successful exit
123: *          < 0:  if INFO = -i, the i-th argument had an illegal value.
124: *          > 0:  the algorithm for computing the SVD failed to converge;
125: *                if INFO = i, i off-diagonal elements of an intermediate
126: *                bidiagonal form did not converge to zero.
127: *
128: *  Further Details
129: *  ===============
130: *
131: *  Based on contributions by
132: *     Ming Gu and Ren-Cang Li, Computer Science Division, University of
133: *       California at Berkeley, USA
134: *     Osni Marques, LBNL/NERSC, USA
135: *
136: *  =====================================================================
137: *
138: *     .. Parameters ..
139:       REAL               ZERO, ONE, TWO
140:       PARAMETER          ( ZERO = 0.0E0, ONE = 1.0E0, TWO = 2.0E0 )
141: *     ..
142: *     .. Local Scalars ..
143:       LOGICAL            LQUERY
144:       INTEGER            IASCL, IBSCL, IE, IL, ITAU, ITAUP, ITAUQ,
145:      $                   LDWORK, LIWORK, MAXMN, MAXWRK, MINMN, MINWRK,
146:      $                   MM, MNTHR, NLVL, NWORK, SMLSIZ, WLALSD
147:       REAL               ANRM, BIGNUM, BNRM, EPS, SFMIN, SMLNUM
148: *     ..
149: *     .. External Subroutines ..
150:       EXTERNAL           SGEBRD, SGELQF, SGEQRF, SLABAD, SLACPY, SLALSD,
151:      $                   SLASCL, SLASET, SORMBR, SORMLQ, SORMQR, XERBLA
152: *     ..
153: *     .. External Functions ..
154:       INTEGER            ILAENV
155:       REAL               SLAMCH, SLANGE
156:       EXTERNAL           SLAMCH, SLANGE, ILAENV
157: *     ..
158: *     .. Intrinsic Functions ..
159:       INTRINSIC          INT, LOG, MAX, MIN, REAL
160: *     ..
161: *     .. Executable Statements ..
162: *
163: *     Test the input arguments.
164: *
165:       INFO = 0
166:       MINMN = MIN( M, N )
167:       MAXMN = MAX( M, N )
168:       LQUERY = ( LWORK.EQ.-1 )
169:       IF( M.LT.0 ) THEN
170:          INFO = -1
171:       ELSE IF( N.LT.0 ) THEN
172:          INFO = -2
173:       ELSE IF( NRHS.LT.0 ) THEN
174:          INFO = -3
175:       ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
176:          INFO = -5
177:       ELSE IF( LDB.LT.MAX( 1, MAXMN ) ) THEN
178:          INFO = -7
179:       END IF
180: *
181: *     Compute workspace.
182: *     (Note: Comments in the code beginning "Workspace:" describe the
183: *     minimal amount of workspace needed at that point in the code,
184: *     as well as the preferred amount for good performance.
185: *     NB refers to the optimal block size for the immediately
186: *     following subroutine, as returned by ILAENV.)
187: *
188:       IF( INFO.EQ.0 ) THEN
189:          MINWRK = 1
190:          MAXWRK = 1
191:          LIWORK = 1
192:          IF( MINMN.GT.0 ) THEN
193:             SMLSIZ = ILAENV( 9, 'SGELSD', ' ', 0, 0, 0, 0 )
194:             MNTHR = ILAENV( 6, 'SGELSD', ' ', M, N, NRHS, -1 )
195:             NLVL = MAX( INT( LOG( REAL( MINMN ) / REAL( SMLSIZ + 1 ) ) /
196:      $                  LOG( TWO ) ) + 1, 0 )
197:             LIWORK = 3*MINMN*NLVL + 11*MINMN
198:             MM = M
199:             IF( M.GE.N .AND. M.GE.MNTHR ) THEN
200: *
201: *              Path 1a - overdetermined, with many more rows than
202: *                        columns.
203: *
204:                MM = N
205:                MAXWRK = MAX( MAXWRK, N + N*ILAENV( 1, 'SGEQRF', ' ', M,
206:      $                       N, -1, -1 ) )
207:                MAXWRK = MAX( MAXWRK, N + NRHS*ILAENV( 1, 'SORMQR', 'LT',
208:      $                       M, NRHS, N, -1 ) )
209:             END IF
210:             IF( M.GE.N ) THEN
211: *
212: *              Path 1 - overdetermined or exactly determined.
213: *
214:                MAXWRK = MAX( MAXWRK, 3*N + ( MM + N )*ILAENV( 1,
215:      $                       'SGEBRD', ' ', MM, N, -1, -1 ) )
216:                MAXWRK = MAX( MAXWRK, 3*N + NRHS*ILAENV( 1, 'SORMBR',
217:      $                       'QLT', MM, NRHS, N, -1 ) )
218:                MAXWRK = MAX( MAXWRK, 3*N + ( N - 1 )*ILAENV( 1,
219:      $                       'SORMBR', 'PLN', N, NRHS, N, -1 ) )
220:                WLALSD = 9*N + 2*N*SMLSIZ + 8*N*NLVL + N*NRHS +
221:      $                  ( SMLSIZ + 1 )**2
222:                MAXWRK = MAX( MAXWRK, 3*N + WLALSD )
223:                MINWRK = MAX( 3*N + MM, 3*N + NRHS, 3*N + WLALSD )
224:             END IF
225:             IF( N.GT.M ) THEN
226:                WLALSD = 9*M + 2*M*SMLSIZ + 8*M*NLVL + M*NRHS +
227:      $                  ( SMLSIZ + 1 )**2
228:                IF( N.GE.MNTHR ) THEN
229: *
230: *                 Path 2a - underdetermined, with many more columns
231: *                           than rows.
232: *
233:                   MAXWRK = M + M*ILAENV( 1, 'SGELQF', ' ', M, N, -1,
234:      $                                  -1 )
235:                   MAXWRK = MAX( MAXWRK, M*M + 4*M + 2*M*ILAENV( 1,
236:      $                          'SGEBRD', ' ', M, M, -1, -1 ) )
237:                   MAXWRK = MAX( MAXWRK, M*M + 4*M + NRHS*ILAENV( 1,
238:      $                          'SORMBR', 'QLT', M, NRHS, M, -1 ) )
239:                   MAXWRK = MAX( MAXWRK, M*M + 4*M + ( M - 1 )*ILAENV( 1,
240:      $                          'SORMBR', 'PLN', M, NRHS, M, -1 ) )
241:                   IF( NRHS.GT.1 ) THEN
242:                      MAXWRK = MAX( MAXWRK, M*M + M + M*NRHS )
243:                   ELSE
244:                      MAXWRK = MAX( MAXWRK, M*M + 2*M )
245:                   END IF
246:                   MAXWRK = MAX( MAXWRK, M + NRHS*ILAENV( 1, 'SORMLQ',
247:      $                          'LT', N, NRHS, M, -1 ) )
248:                   MAXWRK = MAX( MAXWRK, M*M + 4*M + WLALSD )
249: !     XXX: Ensure the Path 2a case below is triggered.  The workspace
250: !     calculation should use queries for all routines eventually.
251:                   MAXWRK = MAX( MAXWRK,
252:      $                 4*M+M*M+MAX( M, 2*M-4, NRHS, N-3*M ) )
253:                ELSE
254: *
255: *                 Path 2 - remaining underdetermined cases.
256: *
257:                   MAXWRK = 3*M + ( N + M )*ILAENV( 1, 'SGEBRD', ' ', M,
258:      $                     N, -1, -1 )
259:                   MAXWRK = MAX( MAXWRK, 3*M + NRHS*ILAENV( 1, 'SORMBR',
260:      $                          'QLT', M, NRHS, N, -1 ) )
261:                   MAXWRK = MAX( MAXWRK, 3*M + M*ILAENV( 1, 'SORMBR',
262:      $                          'PLN', N, NRHS, M, -1 ) )
263:                   MAXWRK = MAX( MAXWRK, 3*M + WLALSD )
264:                END IF
265:                MINWRK = MAX( 3*M + NRHS, 3*M + M, 3*M + WLALSD )
266:             END IF
267:          END IF
268:          MINWRK = MIN( MINWRK, MAXWRK )
269:          WORK( 1 ) = MAXWRK
270:          IWORK( 1 ) = LIWORK
271: *
272:          IF( LWORK.LT.MINWRK .AND. .NOT.LQUERY ) THEN
273:             INFO = -12
274:          END IF
275:       END IF
276: *
277:       IF( INFO.NE.0 ) THEN
278:          CALL XERBLA( 'SGELSD', -INFO )
279:          RETURN
280:       ELSE IF( LQUERY ) THEN
281:          RETURN
282:       END IF
283: *
284: *     Quick return if possible.
285: *
286:       IF( M.EQ.0 .OR. N.EQ.0 ) THEN
287:          RANK = 0
288:          RETURN
289:       END IF
290: *
291: *     Get machine parameters.
292: *
293:       EPS = SLAMCH( 'P' )
294:       SFMIN = SLAMCH( 'S' )
295:       SMLNUM = SFMIN / EPS
296:       BIGNUM = ONE / SMLNUM
297:       CALL SLABAD( SMLNUM, BIGNUM )
298: *
299: *     Scale A if max entry outside range [SMLNUM,BIGNUM].
300: *
301:       ANRM = SLANGE( 'M', M, N, A, LDA, WORK )
302:       IASCL = 0
303:       IF( ANRM.GT.ZERO .AND. ANRM.LT.SMLNUM ) THEN
304: *
305: *        Scale matrix norm up to SMLNUM.
306: *
307:          CALL SLASCL( 'G', 0, 0, ANRM, SMLNUM, M, N, A, LDA, INFO )
308:          IASCL = 1
309:       ELSE IF( ANRM.GT.BIGNUM ) THEN
310: *
311: *        Scale matrix norm down to BIGNUM.
312: *
313:          CALL SLASCL( 'G', 0, 0, ANRM, BIGNUM, M, N, A, LDA, INFO )
314:          IASCL = 2
315:       ELSE IF( ANRM.EQ.ZERO ) THEN
316: *
317: *        Matrix all zero. Return zero solution.
318: *
319:          CALL SLASET( 'F', MAX( M, N ), NRHS, ZERO, ZERO, B, LDB )
320:          CALL SLASET( 'F', MINMN, 1, ZERO, ZERO, S, 1 )
321:          RANK = 0
322:          GO TO 10
323:       END IF
324: *
325: *     Scale B if max entry outside range [SMLNUM,BIGNUM].
326: *
327:       BNRM = SLANGE( 'M', M, NRHS, B, LDB, WORK )
328:       IBSCL = 0
329:       IF( BNRM.GT.ZERO .AND. BNRM.LT.SMLNUM ) THEN
330: *
331: *        Scale matrix norm up to SMLNUM.
332: *
333:          CALL SLASCL( 'G', 0, 0, BNRM, SMLNUM, M, NRHS, B, LDB, INFO )
334:          IBSCL = 1
335:       ELSE IF( BNRM.GT.BIGNUM ) THEN
336: *
337: *        Scale matrix norm down to BIGNUM.
338: *
339:          CALL SLASCL( 'G', 0, 0, BNRM, BIGNUM, M, NRHS, B, LDB, INFO )
340:          IBSCL = 2
341:       END IF
342: *
343: *     If M < N make sure certain entries of B are zero.
344: *
345:       IF( M.LT.N )
346:      $   CALL SLASET( 'F', N-M, NRHS, ZERO, ZERO, B( M+1, 1 ), LDB )
347: *
348: *     Overdetermined case.
349: *
350:       IF( M.GE.N ) THEN
351: *
352: *        Path 1 - overdetermined or exactly determined.
353: *
354:          MM = M
355:          IF( M.GE.MNTHR ) THEN
356: *
357: *           Path 1a - overdetermined, with many more rows than columns.
358: *
359:             MM = N
360:             ITAU = 1
361:             NWORK = ITAU + N
362: *
363: *           Compute A=Q*R.
364: *           (Workspace: need 2*N, prefer N+N*NB)
365: *
366:             CALL SGEQRF( M, N, A, LDA, WORK( ITAU ), WORK( NWORK ),
367:      $                   LWORK-NWORK+1, INFO )
368: *
369: *           Multiply B by transpose(Q).
370: *           (Workspace: need N+NRHS, prefer N+NRHS*NB)
371: *
372:             CALL SORMQR( 'L', 'T', M, NRHS, N, A, LDA, WORK( ITAU ), B,
373:      $                   LDB, WORK( NWORK ), LWORK-NWORK+1, INFO )
374: *
375: *           Zero out below R.
376: *
377:             IF( N.GT.1 ) THEN
378:                CALL SLASET( 'L', N-1, N-1, ZERO, ZERO, A( 2, 1 ), LDA )
379:             END IF
380:          END IF
381: *
382:          IE = 1
383:          ITAUQ = IE + N
384:          ITAUP = ITAUQ + N
385:          NWORK = ITAUP + N
386: *
387: *        Bidiagonalize R in A.
388: *        (Workspace: need 3*N+MM, prefer 3*N+(MM+N)*NB)
389: *
390:          CALL SGEBRD( MM, N, A, LDA, S, WORK( IE ), WORK( ITAUQ ),
391:      $                WORK( ITAUP ), WORK( NWORK ), LWORK-NWORK+1,
392:      $                INFO )
393: *
394: *        Multiply B by transpose of left bidiagonalizing vectors of R.
395: *        (Workspace: need 3*N+NRHS, prefer 3*N+NRHS*NB)
396: *
397:          CALL SORMBR( 'Q', 'L', 'T', MM, NRHS, N, A, LDA, WORK( ITAUQ ),
398:      $                B, LDB, WORK( NWORK ), LWORK-NWORK+1, INFO )
399: *
400: *        Solve the bidiagonal least squares problem.
401: *
402:          CALL SLALSD( 'U', SMLSIZ, N, NRHS, S, WORK( IE ), B, LDB,
403:      $                RCOND, RANK, WORK( NWORK ), IWORK, INFO )
404:          IF( INFO.NE.0 ) THEN
405:             GO TO 10
406:          END IF
407: *
408: *        Multiply B by right bidiagonalizing vectors of R.
409: *
410:          CALL SORMBR( 'P', 'L', 'N', N, NRHS, N, A, LDA, WORK( ITAUP ),
411:      $                B, LDB, WORK( NWORK ), LWORK-NWORK+1, INFO )
412: *
413:       ELSE IF( N.GE.MNTHR .AND. LWORK.GE.4*M+M*M+
414:      $         MAX( M, 2*M-4, NRHS, N-3*M, WLALSD ) ) THEN
415: *
416: *        Path 2a - underdetermined, with many more columns than rows
417: *        and sufficient workspace for an efficient algorithm.
418: *
419:          LDWORK = M
420:          IF( LWORK.GE.MAX( 4*M+M*LDA+MAX( M, 2*M-4, NRHS, N-3*M ),
421:      $       M*LDA+M+M*NRHS, 4*M+M*LDA+WLALSD ) )LDWORK = LDA
422:          ITAU = 1
423:          NWORK = M + 1
424: *
425: *        Compute A=L*Q.
426: *        (Workspace: need 2*M, prefer M+M*NB)
427: *
428:          CALL SGELQF( M, N, A, LDA, WORK( ITAU ), WORK( NWORK ),
429:      $                LWORK-NWORK+1, INFO )
430:          IL = NWORK
431: *
432: *        Copy L to WORK(IL), zeroing out above its diagonal.
433: *
434:          CALL SLACPY( 'L', M, M, A, LDA, WORK( IL ), LDWORK )
435:          CALL SLASET( 'U', M-1, M-1, ZERO, ZERO, WORK( IL+LDWORK ),
436:      $                LDWORK )
437:          IE = IL + LDWORK*M
438:          ITAUQ = IE + M
439:          ITAUP = ITAUQ + M
440:          NWORK = ITAUP + M
441: *
442: *        Bidiagonalize L in WORK(IL).
443: *        (Workspace: need M*M+5*M, prefer M*M+4*M+2*M*NB)
444: *
445:          CALL SGEBRD( M, M, WORK( IL ), LDWORK, S, WORK( IE ),
446:      $                WORK( ITAUQ ), WORK( ITAUP ), WORK( NWORK ),
447:      $                LWORK-NWORK+1, INFO )
448: *
449: *        Multiply B by transpose of left bidiagonalizing vectors of L.
450: *        (Workspace: need M*M+4*M+NRHS, prefer M*M+4*M+NRHS*NB)
451: *
452:          CALL SORMBR( 'Q', 'L', 'T', M, NRHS, M, WORK( IL ), LDWORK,
453:      $                WORK( ITAUQ ), B, LDB, WORK( NWORK ),
454:      $                LWORK-NWORK+1, INFO )
455: *
456: *        Solve the bidiagonal least squares problem.
457: *
458:          CALL SLALSD( 'U', SMLSIZ, M, NRHS, S, WORK( IE ), B, LDB,
459:      $                RCOND, RANK, WORK( NWORK ), IWORK, INFO )
460:          IF( INFO.NE.0 ) THEN
461:             GO TO 10
462:          END IF
463: *
464: *        Multiply B by right bidiagonalizing vectors of L.
465: *
466:          CALL SORMBR( 'P', 'L', 'N', M, NRHS, M, WORK( IL ), LDWORK,
467:      $                WORK( ITAUP ), B, LDB, WORK( NWORK ),
468:      $                LWORK-NWORK+1, INFO )
469: *
470: *        Zero out below first M rows of B.
471: *
472:          CALL SLASET( 'F', N-M, NRHS, ZERO, ZERO, B( M+1, 1 ), LDB )
473:          NWORK = ITAU + M
474: *
475: *        Multiply transpose(Q) by B.
476: *        (Workspace: need M+NRHS, prefer M+NRHS*NB)
477: *
478:          CALL SORMLQ( 'L', 'T', N, NRHS, M, A, LDA, WORK( ITAU ), B,
479:      $                LDB, WORK( NWORK ), LWORK-NWORK+1, INFO )
480: *
481:       ELSE
482: *
483: *        Path 2 - remaining underdetermined cases.
484: *
485:          IE = 1
486:          ITAUQ = IE + M
487:          ITAUP = ITAUQ + M
488:          NWORK = ITAUP + M
489: *
490: *        Bidiagonalize A.
491: *        (Workspace: need 3*M+N, prefer 3*M+(M+N)*NB)
492: *
493:          CALL SGEBRD( M, N, A, LDA, S, WORK( IE ), WORK( ITAUQ ),
494:      $                WORK( ITAUP ), WORK( NWORK ), LWORK-NWORK+1,
495:      $                INFO )
496: *
497: *        Multiply B by transpose of left bidiagonalizing vectors.
498: *        (Workspace: need 3*M+NRHS, prefer 3*M+NRHS*NB)
499: *
500:          CALL SORMBR( 'Q', 'L', 'T', M, NRHS, N, A, LDA, WORK( ITAUQ ),
501:      $                B, LDB, WORK( NWORK ), LWORK-NWORK+1, INFO )
502: *
503: *        Solve the bidiagonal least squares problem.
504: *
505:          CALL SLALSD( 'L', SMLSIZ, M, NRHS, S, WORK( IE ), B, LDB,
506:      $                RCOND, RANK, WORK( NWORK ), IWORK, INFO )
507:          IF( INFO.NE.0 ) THEN
508:             GO TO 10
509:          END IF
510: *
511: *        Multiply B by right bidiagonalizing vectors of A.
512: *
513:          CALL SORMBR( 'P', 'L', 'N', N, NRHS, M, A, LDA, WORK( ITAUP ),
514:      $                B, LDB, WORK( NWORK ), LWORK-NWORK+1, INFO )
515: *
516:       END IF
517: *
518: *     Undo scaling.
519: *
520:       IF( IASCL.EQ.1 ) THEN
521:          CALL SLASCL( 'G', 0, 0, ANRM, SMLNUM, N, NRHS, B, LDB, INFO )
522:          CALL SLASCL( 'G', 0, 0, SMLNUM, ANRM, MINMN, 1, S, MINMN,
523:      $                INFO )
524:       ELSE IF( IASCL.EQ.2 ) THEN
525:          CALL SLASCL( 'G', 0, 0, ANRM, BIGNUM, N, NRHS, B, LDB, INFO )
526:          CALL SLASCL( 'G', 0, 0, BIGNUM, ANRM, MINMN, 1, S, MINMN,
527:      $                INFO )
528:       END IF
529:       IF( IBSCL.EQ.1 ) THEN
530:          CALL SLASCL( 'G', 0, 0, SMLNUM, BNRM, N, NRHS, B, LDB, INFO )
531:       ELSE IF( IBSCL.EQ.2 ) THEN
532:          CALL SLASCL( 'G', 0, 0, BIGNUM, BNRM, N, NRHS, B, LDB, INFO )
533:       END IF
534: *
535:    10 CONTINUE
536:       WORK( 1 ) = MAXWRK
537:       IWORK( 1 ) = LIWORK
538:       RETURN
539: *
540: *     End of SGELSD
541: *
542:       END
543: