001:       SUBROUTINE DTPMV(UPLO,TRANS,DIAG,N,AP,X,INCX)
002: *     .. Scalar Arguments ..
003:       INTEGER INCX,N
004:       CHARACTER DIAG,TRANS,UPLO
005: *     ..
006: *     .. Array Arguments ..
007:       DOUBLE PRECISION AP(*),X(*)
008: *     ..
009: *
010: *  Purpose
011: *  =======
012: *
013: *  DTPMV  performs one of the matrix-vector operations
014: *
015: *     x := A*x,   or   x := A'*x,
016: *
017: *  where x is an n element vector and  A is an n by n unit, or non-unit,
018: *  upper or lower triangular matrix, supplied in packed form.
019: *
020: *  Arguments
021: *  ==========
022: *
023: *  UPLO   - CHARACTER*1.
024: *           On entry, UPLO specifies whether the matrix is an upper or
025: *           lower triangular matrix as follows:
026: *
027: *              UPLO = 'U' or 'u'   A is an upper triangular matrix.
028: *
029: *              UPLO = 'L' or 'l'   A is a lower triangular matrix.
030: *
031: *           Unchanged on exit.
032: *
033: *  TRANS  - CHARACTER*1.
034: *           On entry, TRANS specifies the operation to be performed as
035: *           follows:
036: *
037: *              TRANS = 'N' or 'n'   x := A*x.
038: *
039: *              TRANS = 'T' or 't'   x := A'*x.
040: *
041: *              TRANS = 'C' or 'c'   x := A'*x.
042: *
043: *           Unchanged on exit.
044: *
045: *  DIAG   - CHARACTER*1.
046: *           On entry, DIAG specifies whether or not A is unit
047: *           triangular as follows:
048: *
049: *              DIAG = 'U' or 'u'   A is assumed to be unit triangular.
050: *
051: *              DIAG = 'N' or 'n'   A is not assumed to be unit
052: *                                  triangular.
053: *
054: *           Unchanged on exit.
055: *
056: *  N      - INTEGER.
057: *           On entry, N specifies the order of the matrix A.
058: *           N must be at least zero.
059: *           Unchanged on exit.
060: *
061: *  AP     - DOUBLE PRECISION array of DIMENSION at least
062: *           ( ( n*( n + 1 ) )/2 ).
063: *           Before entry with  UPLO = 'U' or 'u', the array AP must
064: *           contain the upper triangular matrix packed sequentially,
065: *           column by column, so that AP( 1 ) contains a( 1, 1 ),
066: *           AP( 2 ) and AP( 3 ) contain a( 1, 2 ) and a( 2, 2 )
067: *           respectively, and so on.
068: *           Before entry with UPLO = 'L' or 'l', the array AP must
069: *           contain the lower triangular matrix packed sequentially,
070: *           column by column, so that AP( 1 ) contains a( 1, 1 ),
071: *           AP( 2 ) and AP( 3 ) contain a( 2, 1 ) and a( 3, 1 )
072: *           respectively, and so on.
073: *           Note that when  DIAG = 'U' or 'u', the diagonal elements of
074: *           A are not referenced, but are assumed to be unity.
075: *           Unchanged on exit.
076: *
077: *  X      - DOUBLE PRECISION array of dimension at least
078: *           ( 1 + ( n - 1 )*abs( INCX ) ).
079: *           Before entry, the incremented array X must contain the n
080: *           element vector x. On exit, X is overwritten with the
081: *           tranformed vector x.
082: *
083: *  INCX   - INTEGER.
084: *           On entry, INCX specifies the increment for the elements of
085: *           X. INCX must not be zero.
086: *           Unchanged on exit.
087: *
088: *
089: *  Level 2 Blas routine.
090: *
091: *  -- Written on 22-October-1986.
092: *     Jack Dongarra, Argonne National Lab.
093: *     Jeremy Du Croz, Nag Central Office.
094: *     Sven Hammarling, Nag Central Office.
095: *     Richard Hanson, Sandia National Labs.
096: *
097: *
098: *     .. Parameters ..
099:       DOUBLE PRECISION ZERO
100:       PARAMETER (ZERO=0.0D+0)
101: *     ..
102: *     .. Local Scalars ..
103:       DOUBLE PRECISION TEMP
104:       INTEGER I,INFO,IX,J,JX,K,KK,KX
105:       LOGICAL NOUNIT
106: *     ..
107: *     .. External Functions ..
108:       LOGICAL LSAME
109:       EXTERNAL LSAME
110: *     ..
111: *     .. External Subroutines ..
112:       EXTERNAL XERBLA
113: *     ..
114: *
115: *     Test the input parameters.
116: *
117:       INFO = 0
118:       IF (.NOT.LSAME(UPLO,'U') .AND. .NOT.LSAME(UPLO,'L')) THEN
119:           INFO = 1
120:       ELSE IF (.NOT.LSAME(TRANS,'N') .AND. .NOT.LSAME(TRANS,'T') .AND.
121:      +         .NOT.LSAME(TRANS,'C')) THEN
122:           INFO = 2
123:       ELSE IF (.NOT.LSAME(DIAG,'U') .AND. .NOT.LSAME(DIAG,'N')) THEN
124:           INFO = 3
125:       ELSE IF (N.LT.0) THEN
126:           INFO = 4
127:       ELSE IF (INCX.EQ.0) THEN
128:           INFO = 7
129:       END IF
130:       IF (INFO.NE.0) THEN
131:           CALL XERBLA('DTPMV ',INFO)
132:           RETURN
133:       END IF
134: *
135: *     Quick return if possible.
136: *
137:       IF (N.EQ.0) RETURN
138: *
139:       NOUNIT = LSAME(DIAG,'N')
140: *
141: *     Set up the start point in X if the increment is not unity. This
142: *     will be  ( N - 1 )*INCX  too small for descending loops.
143: *
144:       IF (INCX.LE.0) THEN
145:           KX = 1 - (N-1)*INCX
146:       ELSE IF (INCX.NE.1) THEN
147:           KX = 1
148:       END IF
149: *
150: *     Start the operations. In this version the elements of AP are
151: *     accessed sequentially with one pass through AP.
152: *
153:       IF (LSAME(TRANS,'N')) THEN
154: *
155: *        Form  x:= A*x.
156: *
157:           IF (LSAME(UPLO,'U')) THEN
158:               KK = 1
159:               IF (INCX.EQ.1) THEN
160:                   DO 20 J = 1,N
161:                       IF (X(J).NE.ZERO) THEN
162:                           TEMP = X(J)
163:                           K = KK
164:                           DO 10 I = 1,J - 1
165:                               X(I) = X(I) + TEMP*AP(K)
166:                               K = K + 1
167:    10                     CONTINUE
168:                           IF (NOUNIT) X(J) = X(J)*AP(KK+J-1)
169:                       END IF
170:                       KK = KK + J
171:    20             CONTINUE
172:               ELSE
173:                   JX = KX
174:                   DO 40 J = 1,N
175:                       IF (X(JX).NE.ZERO) THEN
176:                           TEMP = X(JX)
177:                           IX = KX
178:                           DO 30 K = KK,KK + J - 2
179:                               X(IX) = X(IX) + TEMP*AP(K)
180:                               IX = IX + INCX
181:    30                     CONTINUE
182:                           IF (NOUNIT) X(JX) = X(JX)*AP(KK+J-1)
183:                       END IF
184:                       JX = JX + INCX
185:                       KK = KK + J
186:    40             CONTINUE
187:               END IF
188:           ELSE
189:               KK = (N* (N+1))/2
190:               IF (INCX.EQ.1) THEN
191:                   DO 60 J = N,1,-1
192:                       IF (X(J).NE.ZERO) THEN
193:                           TEMP = X(J)
194:                           K = KK
195:                           DO 50 I = N,J + 1,-1
196:                               X(I) = X(I) + TEMP*AP(K)
197:                               K = K - 1
198:    50                     CONTINUE
199:                           IF (NOUNIT) X(J) = X(J)*AP(KK-N+J)
200:                       END IF
201:                       KK = KK - (N-J+1)
202:    60             CONTINUE
203:               ELSE
204:                   KX = KX + (N-1)*INCX
205:                   JX = KX
206:                   DO 80 J = N,1,-1
207:                       IF (X(JX).NE.ZERO) THEN
208:                           TEMP = X(JX)
209:                           IX = KX
210:                           DO 70 K = KK,KK - (N- (J+1)),-1
211:                               X(IX) = X(IX) + TEMP*AP(K)
212:                               IX = IX - INCX
213:    70                     CONTINUE
214:                           IF (NOUNIT) X(JX) = X(JX)*AP(KK-N+J)
215:                       END IF
216:                       JX = JX - INCX
217:                       KK = KK - (N-J+1)
218:    80             CONTINUE
219:               END IF
220:           END IF
221:       ELSE
222: *
223: *        Form  x := A'*x.
224: *
225:           IF (LSAME(UPLO,'U')) THEN
226:               KK = (N* (N+1))/2
227:               IF (INCX.EQ.1) THEN
228:                   DO 100 J = N,1,-1
229:                       TEMP = X(J)
230:                       IF (NOUNIT) TEMP = TEMP*AP(KK)
231:                       K = KK - 1
232:                       DO 90 I = J - 1,1,-1
233:                           TEMP = TEMP + AP(K)*X(I)
234:                           K = K - 1
235:    90                 CONTINUE
236:                       X(J) = TEMP
237:                       KK = KK - J
238:   100             CONTINUE
239:               ELSE
240:                   JX = KX + (N-1)*INCX
241:                   DO 120 J = N,1,-1
242:                       TEMP = X(JX)
243:                       IX = JX
244:                       IF (NOUNIT) TEMP = TEMP*AP(KK)
245:                       DO 110 K = KK - 1,KK - J + 1,-1
246:                           IX = IX - INCX
247:                           TEMP = TEMP + AP(K)*X(IX)
248:   110                 CONTINUE
249:                       X(JX) = TEMP
250:                       JX = JX - INCX
251:                       KK = KK - J
252:   120             CONTINUE
253:               END IF
254:           ELSE
255:               KK = 1
256:               IF (INCX.EQ.1) THEN
257:                   DO 140 J = 1,N
258:                       TEMP = X(J)
259:                       IF (NOUNIT) TEMP = TEMP*AP(KK)
260:                       K = KK + 1
261:                       DO 130 I = J + 1,N
262:                           TEMP = TEMP + AP(K)*X(I)
263:                           K = K + 1
264:   130                 CONTINUE
265:                       X(J) = TEMP
266:                       KK = KK + (N-J+1)
267:   140             CONTINUE
268:               ELSE
269:                   JX = KX
270:                   DO 160 J = 1,N
271:                       TEMP = X(JX)
272:                       IX = JX
273:                       IF (NOUNIT) TEMP = TEMP*AP(KK)
274:                       DO 150 K = KK + 1,KK + N - J
275:                           IX = IX + INCX
276:                           TEMP = TEMP + AP(K)*X(IX)
277:   150                 CONTINUE
278:                       X(JX) = TEMP
279:                       JX = JX + INCX
280:                       KK = KK + (N-J+1)
281:   160             CONTINUE
282:               END IF
283:           END IF
284:       END IF
285: *
286:       RETURN
287: *
288: *     End of DTPMV .
289: *
290:       END
291: