001:       SUBROUTINE DTBRFS( UPLO, TRANS, DIAG, N, KD, NRHS, AB, LDAB, B,
002:      $                   LDB, X, LDX, FERR, BERR, WORK, IWORK, INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     Modified to call DLACN2 in place of DLACON, 5 Feb 03, SJH.
009: *
010: *     .. Scalar Arguments ..
011:       CHARACTER          DIAG, TRANS, UPLO
012:       INTEGER            INFO, KD, LDAB, LDB, LDX, N, NRHS
013: *     ..
014: *     .. Array Arguments ..
015:       INTEGER            IWORK( * )
016:       DOUBLE PRECISION   AB( LDAB, * ), B( LDB, * ), BERR( * ),
017:      $                   FERR( * ), WORK( * ), X( LDX, * )
018: *     ..
019: *
020: *  Purpose
021: *  =======
022: *
023: *  DTBRFS provides error bounds and backward error estimates for the
024: *  solution to a system of linear equations with a triangular band
025: *  coefficient matrix.
026: *
027: *  The solution matrix X must be computed by DTBTRS or some other
028: *  means before entering this routine.  DTBRFS does not do iterative
029: *  refinement because doing so cannot improve the backward error.
030: *
031: *  Arguments
032: *  =========
033: *
034: *  UPLO    (input) CHARACTER*1
035: *          = 'U':  A is upper triangular;
036: *          = 'L':  A is lower triangular.
037: *
038: *  TRANS   (input) CHARACTER*1
039: *          Specifies the form of the system of equations:
040: *          = 'N':  A * X = B  (No transpose)
041: *          = 'T':  A**T * X = B  (Transpose)
042: *          = 'C':  A**H * X = B  (Conjugate transpose = Transpose)
043: *
044: *  DIAG    (input) CHARACTER*1
045: *          = 'N':  A is non-unit triangular;
046: *          = 'U':  A is unit triangular.
047: *
048: *  N       (input) INTEGER
049: *          The order of the matrix A.  N >= 0.
050: *
051: *  KD      (input) INTEGER
052: *          The number of superdiagonals or subdiagonals of the
053: *          triangular band matrix A.  KD >= 0.
054: *
055: *  NRHS    (input) INTEGER
056: *          The number of right hand sides, i.e., the number of columns
057: *          of the matrices B and X.  NRHS >= 0.
058: *
059: *  AB      (input) DOUBLE PRECISION array, dimension (LDAB,N)
060: *          The upper or lower triangular band matrix A, stored in the
061: *          first kd+1 rows of the array. The j-th column of A is stored
062: *          in the j-th column of the array AB as follows:
063: *          if UPLO = 'U', AB(kd+1+i-j,j) = A(i,j) for max(1,j-kd)<=i<=j;
064: *          if UPLO = 'L', AB(1+i-j,j)    = A(i,j) for j<=i<=min(n,j+kd).
065: *          If DIAG = 'U', the diagonal elements of A are not referenced
066: *          and are assumed to be 1.
067: *
068: *  LDAB    (input) INTEGER
069: *          The leading dimension of the array AB.  LDAB >= KD+1.
070: *
071: *  B       (input) DOUBLE PRECISION array, dimension (LDB,NRHS)
072: *          The right hand side matrix B.
073: *
074: *  LDB     (input) INTEGER
075: *          The leading dimension of the array B.  LDB >= max(1,N).
076: *
077: *  X       (input) DOUBLE PRECISION array, dimension (LDX,NRHS)
078: *          The solution matrix X.
079: *
080: *  LDX     (input) INTEGER
081: *          The leading dimension of the array X.  LDX >= max(1,N).
082: *
083: *  FERR    (output) DOUBLE PRECISION array, dimension (NRHS)
084: *          The estimated forward error bound for each solution vector
085: *          X(j) (the j-th column of the solution matrix X).
086: *          If XTRUE is the true solution corresponding to X(j), FERR(j)
087: *          is an estimated upper bound for the magnitude of the largest
088: *          element in (X(j) - XTRUE) divided by the magnitude of the
089: *          largest element in X(j).  The estimate is as reliable as
090: *          the estimate for RCOND, and is almost always a slight
091: *          overestimate of the true error.
092: *
093: *  BERR    (output) DOUBLE PRECISION array, dimension (NRHS)
094: *          The componentwise relative backward error of each solution
095: *          vector X(j) (i.e., the smallest relative change in
096: *          any element of A or B that makes X(j) an exact solution).
097: *
098: *  WORK    (workspace) DOUBLE PRECISION array, dimension (3*N)
099: *
100: *  IWORK   (workspace) INTEGER array, dimension (N)
101: *
102: *  INFO    (output) INTEGER
103: *          = 0:  successful exit
104: *          < 0:  if INFO = -i, the i-th argument had an illegal value
105: *
106: *  =====================================================================
107: *
108: *     .. Parameters ..
109:       DOUBLE PRECISION   ZERO
110:       PARAMETER          ( ZERO = 0.0D+0 )
111:       DOUBLE PRECISION   ONE
112:       PARAMETER          ( ONE = 1.0D+0 )
113: *     ..
114: *     .. Local Scalars ..
115:       LOGICAL            NOTRAN, NOUNIT, UPPER
116:       CHARACTER          TRANST
117:       INTEGER            I, J, K, KASE, NZ
118:       DOUBLE PRECISION   EPS, LSTRES, S, SAFE1, SAFE2, SAFMIN, XK
119: *     ..
120: *     .. Local Arrays ..
121:       INTEGER            ISAVE( 3 )
122: *     ..
123: *     .. External Subroutines ..
124:       EXTERNAL           DAXPY, DCOPY, DLACN2, DTBMV, DTBSV, XERBLA
125: *     ..
126: *     .. Intrinsic Functions ..
127:       INTRINSIC          ABS, MAX, MIN
128: *     ..
129: *     .. External Functions ..
130:       LOGICAL            LSAME
131:       DOUBLE PRECISION   DLAMCH
132:       EXTERNAL           LSAME, DLAMCH
133: *     ..
134: *     .. Executable Statements ..
135: *
136: *     Test the input parameters.
137: *
138:       INFO = 0
139:       UPPER = LSAME( UPLO, 'U' )
140:       NOTRAN = LSAME( TRANS, 'N' )
141:       NOUNIT = LSAME( DIAG, 'N' )
142: *
143:       IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
144:          INFO = -1
145:       ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'T' ) .AND. .NOT.
146:      $         LSAME( TRANS, 'C' ) ) THEN
147:          INFO = -2
148:       ELSE IF( .NOT.NOUNIT .AND. .NOT.LSAME( DIAG, 'U' ) ) THEN
149:          INFO = -3
150:       ELSE IF( N.LT.0 ) THEN
151:          INFO = -4
152:       ELSE IF( KD.LT.0 ) THEN
153:          INFO = -5
154:       ELSE IF( NRHS.LT.0 ) THEN
155:          INFO = -6
156:       ELSE IF( LDAB.LT.KD+1 ) THEN
157:          INFO = -8
158:       ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
159:          INFO = -10
160:       ELSE IF( LDX.LT.MAX( 1, N ) ) THEN
161:          INFO = -12
162:       END IF
163:       IF( INFO.NE.0 ) THEN
164:          CALL XERBLA( 'DTBRFS', -INFO )
165:          RETURN
166:       END IF
167: *
168: *     Quick return if possible
169: *
170:       IF( N.EQ.0 .OR. NRHS.EQ.0 ) THEN
171:          DO 10 J = 1, NRHS
172:             FERR( J ) = ZERO
173:             BERR( J ) = ZERO
174:    10    CONTINUE
175:          RETURN
176:       END IF
177: *
178:       IF( NOTRAN ) THEN
179:          TRANST = 'T'
180:       ELSE
181:          TRANST = 'N'
182:       END IF
183: *
184: *     NZ = maximum number of nonzero elements in each row of A, plus 1
185: *
186:       NZ = KD + 2
187:       EPS = DLAMCH( 'Epsilon' )
188:       SAFMIN = DLAMCH( 'Safe minimum' )
189:       SAFE1 = NZ*SAFMIN
190:       SAFE2 = SAFE1 / EPS
191: *
192: *     Do for each right hand side
193: *
194:       DO 250 J = 1, NRHS
195: *
196: *        Compute residual R = B - op(A) * X,
197: *        where op(A) = A or A', depending on TRANS.
198: *
199:          CALL DCOPY( N, X( 1, J ), 1, WORK( N+1 ), 1 )
200:          CALL DTBMV( UPLO, TRANS, DIAG, N, KD, AB, LDAB, WORK( N+1 ),
201:      $               1 )
202:          CALL DAXPY( N, -ONE, B( 1, J ), 1, WORK( N+1 ), 1 )
203: *
204: *        Compute componentwise relative backward error from formula
205: *
206: *        max(i) ( abs(R(i)) / ( abs(op(A))*abs(X) + abs(B) )(i) )
207: *
208: *        where abs(Z) is the componentwise absolute value of the matrix
209: *        or vector Z.  If the i-th component of the denominator is less
210: *        than SAFE2, then SAFE1 is added to the i-th components of the
211: *        numerator and denominator before dividing.
212: *
213:          DO 20 I = 1, N
214:             WORK( I ) = ABS( B( I, J ) )
215:    20    CONTINUE
216: *
217:          IF( NOTRAN ) THEN
218: *
219: *           Compute abs(A)*abs(X) + abs(B).
220: *
221:             IF( UPPER ) THEN
222:                IF( NOUNIT ) THEN
223:                   DO 40 K = 1, N
224:                      XK = ABS( X( K, J ) )
225:                      DO 30 I = MAX( 1, K-KD ), K
226:                         WORK( I ) = WORK( I ) +
227:      $                              ABS( AB( KD+1+I-K, K ) )*XK
228:    30                CONTINUE
229:    40             CONTINUE
230:                ELSE
231:                   DO 60 K = 1, N
232:                      XK = ABS( X( K, J ) )
233:                      DO 50 I = MAX( 1, K-KD ), K - 1
234:                         WORK( I ) = WORK( I ) +
235:      $                              ABS( AB( KD+1+I-K, K ) )*XK
236:    50                CONTINUE
237:                      WORK( K ) = WORK( K ) + XK
238:    60             CONTINUE
239:                END IF
240:             ELSE
241:                IF( NOUNIT ) THEN
242:                   DO 80 K = 1, N
243:                      XK = ABS( X( K, J ) )
244:                      DO 70 I = K, MIN( N, K+KD )
245:                         WORK( I ) = WORK( I ) + ABS( AB( 1+I-K, K ) )*XK
246:    70                CONTINUE
247:    80             CONTINUE
248:                ELSE
249:                   DO 100 K = 1, N
250:                      XK = ABS( X( K, J ) )
251:                      DO 90 I = K + 1, MIN( N, K+KD )
252:                         WORK( I ) = WORK( I ) + ABS( AB( 1+I-K, K ) )*XK
253:    90                CONTINUE
254:                      WORK( K ) = WORK( K ) + XK
255:   100             CONTINUE
256:                END IF
257:             END IF
258:          ELSE
259: *
260: *           Compute abs(A')*abs(X) + abs(B).
261: *
262:             IF( UPPER ) THEN
263:                IF( NOUNIT ) THEN
264:                   DO 120 K = 1, N
265:                      S = ZERO
266:                      DO 110 I = MAX( 1, K-KD ), K
267:                         S = S + ABS( AB( KD+1+I-K, K ) )*
268:      $                      ABS( X( I, J ) )
269:   110                CONTINUE
270:                      WORK( K ) = WORK( K ) + S
271:   120             CONTINUE
272:                ELSE
273:                   DO 140 K = 1, N
274:                      S = ABS( X( K, J ) )
275:                      DO 130 I = MAX( 1, K-KD ), K - 1
276:                         S = S + ABS( AB( KD+1+I-K, K ) )*
277:      $                      ABS( X( I, J ) )
278:   130                CONTINUE
279:                      WORK( K ) = WORK( K ) + S
280:   140             CONTINUE
281:                END IF
282:             ELSE
283:                IF( NOUNIT ) THEN
284:                   DO 160 K = 1, N
285:                      S = ZERO
286:                      DO 150 I = K, MIN( N, K+KD )
287:                         S = S + ABS( AB( 1+I-K, K ) )*ABS( X( I, J ) )
288:   150                CONTINUE
289:                      WORK( K ) = WORK( K ) + S
290:   160             CONTINUE
291:                ELSE
292:                   DO 180 K = 1, N
293:                      S = ABS( X( K, J ) )
294:                      DO 170 I = K + 1, MIN( N, K+KD )
295:                         S = S + ABS( AB( 1+I-K, K ) )*ABS( X( I, J ) )
296:   170                CONTINUE
297:                      WORK( K ) = WORK( K ) + S
298:   180             CONTINUE
299:                END IF
300:             END IF
301:          END IF
302:          S = ZERO
303:          DO 190 I = 1, N
304:             IF( WORK( I ).GT.SAFE2 ) THEN
305:                S = MAX( S, ABS( WORK( N+I ) ) / WORK( I ) )
306:             ELSE
307:                S = MAX( S, ( ABS( WORK( N+I ) )+SAFE1 ) /
308:      $             ( WORK( I )+SAFE1 ) )
309:             END IF
310:   190    CONTINUE
311:          BERR( J ) = S
312: *
313: *        Bound error from formula
314: *
315: *        norm(X - XTRUE) / norm(X) .le. FERR =
316: *        norm( abs(inv(op(A)))*
317: *           ( abs(R) + NZ*EPS*( abs(op(A))*abs(X)+abs(B) ))) / norm(X)
318: *
319: *        where
320: *          norm(Z) is the magnitude of the largest component of Z
321: *          inv(op(A)) is the inverse of op(A)
322: *          abs(Z) is the componentwise absolute value of the matrix or
323: *             vector Z
324: *          NZ is the maximum number of nonzeros in any row of A, plus 1
325: *          EPS is machine epsilon
326: *
327: *        The i-th component of abs(R)+NZ*EPS*(abs(op(A))*abs(X)+abs(B))
328: *        is incremented by SAFE1 if the i-th component of
329: *        abs(op(A))*abs(X) + abs(B) is less than SAFE2.
330: *
331: *        Use DLACN2 to estimate the infinity-norm of the matrix
332: *           inv(op(A)) * diag(W),
333: *        where W = abs(R) + NZ*EPS*( abs(op(A))*abs(X)+abs(B) )))
334: *
335:          DO 200 I = 1, N
336:             IF( WORK( I ).GT.SAFE2 ) THEN
337:                WORK( I ) = ABS( WORK( N+I ) ) + NZ*EPS*WORK( I )
338:             ELSE
339:                WORK( I ) = ABS( WORK( N+I ) ) + NZ*EPS*WORK( I ) + SAFE1
340:             END IF
341:   200    CONTINUE
342: *
343:          KASE = 0
344:   210    CONTINUE
345:          CALL DLACN2( N, WORK( 2*N+1 ), WORK( N+1 ), IWORK, FERR( J ),
346:      $                KASE, ISAVE )
347:          IF( KASE.NE.0 ) THEN
348:             IF( KASE.EQ.1 ) THEN
349: *
350: *              Multiply by diag(W)*inv(op(A)').
351: *
352:                CALL DTBSV( UPLO, TRANST, DIAG, N, KD, AB, LDAB,
353:      $                     WORK( N+1 ), 1 )
354:                DO 220 I = 1, N
355:                   WORK( N+I ) = WORK( I )*WORK( N+I )
356:   220          CONTINUE
357:             ELSE
358: *
359: *              Multiply by inv(op(A))*diag(W).
360: *
361:                DO 230 I = 1, N
362:                   WORK( N+I ) = WORK( I )*WORK( N+I )
363:   230          CONTINUE
364:                CALL DTBSV( UPLO, TRANS, DIAG, N, KD, AB, LDAB,
365:      $                     WORK( N+1 ), 1 )
366:             END IF
367:             GO TO 210
368:          END IF
369: *
370: *        Normalize error.
371: *
372:          LSTRES = ZERO
373:          DO 240 I = 1, N
374:             LSTRES = MAX( LSTRES, ABS( X( I, J ) ) )
375:   240    CONTINUE
376:          IF( LSTRES.NE.ZERO )
377:      $      FERR( J ) = FERR( J ) / LSTRES
378: *
379:   250 CONTINUE
380: *
381:       RETURN
382: *
383: *     End of DTBRFS
384: *
385:       END
386: