001:       SUBROUTINE DSPMV(UPLO,N,ALPHA,AP,X,INCX,BETA,Y,INCY)
002: *     .. Scalar Arguments ..
003:       DOUBLE PRECISION ALPHA,BETA
004:       INTEGER INCX,INCY,N
005:       CHARACTER UPLO
006: *     ..
007: *     .. Array Arguments ..
008:       DOUBLE PRECISION AP(*),X(*),Y(*)
009: *     ..
010: *
011: *  Purpose
012: *  =======
013: *
014: *  DSPMV  performs the matrix-vector operation
015: *
016: *     y := alpha*A*x + beta*y,
017: *
018: *  where alpha and beta are scalars, x and y are n element vectors and
019: *  A is an n by n symmetric matrix, supplied in packed form.
020: *
021: *  Arguments
022: *  ==========
023: *
024: *  UPLO   - CHARACTER*1.
025: *           On entry, UPLO specifies whether the upper or lower
026: *           triangular part of the matrix A is supplied in the packed
027: *           array AP as follows:
028: *
029: *              UPLO = 'U' or 'u'   The upper triangular part of A is
030: *                                  supplied in AP.
031: *
032: *              UPLO = 'L' or 'l'   The lower triangular part of A is
033: *                                  supplied in AP.
034: *
035: *           Unchanged on exit.
036: *
037: *  N      - INTEGER.
038: *           On entry, N specifies the order of the matrix A.
039: *           N must be at least zero.
040: *           Unchanged on exit.
041: *
042: *  ALPHA  - DOUBLE PRECISION.
043: *           On entry, ALPHA specifies the scalar alpha.
044: *           Unchanged on exit.
045: *
046: *  AP     - DOUBLE PRECISION array of DIMENSION at least
047: *           ( ( n*( n + 1 ) )/2 ).
048: *           Before entry with UPLO = 'U' or 'u', the array AP must
049: *           contain the upper triangular part of the symmetric matrix
050: *           packed sequentially, column by column, so that AP( 1 )
051: *           contains a( 1, 1 ), AP( 2 ) and AP( 3 ) contain a( 1, 2 )
052: *           and a( 2, 2 ) respectively, and so on.
053: *           Before entry with UPLO = 'L' or 'l', the array AP must
054: *           contain the lower triangular part of the symmetric matrix
055: *           packed sequentially, column by column, so that AP( 1 )
056: *           contains a( 1, 1 ), AP( 2 ) and AP( 3 ) contain a( 2, 1 )
057: *           and a( 3, 1 ) respectively, and so on.
058: *           Unchanged on exit.
059: *
060: *  X      - DOUBLE PRECISION array of dimension at least
061: *           ( 1 + ( n - 1 )*abs( INCX ) ).
062: *           Before entry, the incremented array X must contain the n
063: *           element vector x.
064: *           Unchanged on exit.
065: *
066: *  INCX   - INTEGER.
067: *           On entry, INCX specifies the increment for the elements of
068: *           X. INCX must not be zero.
069: *           Unchanged on exit.
070: *
071: *  BETA   - DOUBLE PRECISION.
072: *           On entry, BETA specifies the scalar beta. When BETA is
073: *           supplied as zero then Y need not be set on input.
074: *           Unchanged on exit.
075: *
076: *  Y      - DOUBLE PRECISION array of dimension at least
077: *           ( 1 + ( n - 1 )*abs( INCY ) ).
078: *           Before entry, the incremented array Y must contain the n
079: *           element vector y. On exit, Y is overwritten by the updated
080: *           vector y.
081: *
082: *  INCY   - INTEGER.
083: *           On entry, INCY specifies the increment for the elements of
084: *           Y. INCY must not be zero.
085: *           Unchanged on exit.
086: *
087: *
088: *  Level 2 Blas routine.
089: *
090: *  -- Written on 22-October-1986.
091: *     Jack Dongarra, Argonne National Lab.
092: *     Jeremy Du Croz, Nag Central Office.
093: *     Sven Hammarling, Nag Central Office.
094: *     Richard Hanson, Sandia National Labs.
095: *
096: *
097: *     .. Parameters ..
098:       DOUBLE PRECISION ONE,ZERO
099:       PARAMETER (ONE=1.0D+0,ZERO=0.0D+0)
100: *     ..
101: *     .. Local Scalars ..
102:       DOUBLE PRECISION TEMP1,TEMP2
103:       INTEGER I,INFO,IX,IY,J,JX,JY,K,KK,KX,KY
104: *     ..
105: *     .. External Functions ..
106:       LOGICAL LSAME
107:       EXTERNAL LSAME
108: *     ..
109: *     .. External Subroutines ..
110:       EXTERNAL XERBLA
111: *     ..
112: *
113: *     Test the input parameters.
114: *
115:       INFO = 0
116:       IF (.NOT.LSAME(UPLO,'U') .AND. .NOT.LSAME(UPLO,'L')) THEN
117:           INFO = 1
118:       ELSE IF (N.LT.0) THEN
119:           INFO = 2
120:       ELSE IF (INCX.EQ.0) THEN
121:           INFO = 6
122:       ELSE IF (INCY.EQ.0) THEN
123:           INFO = 9
124:       END IF
125:       IF (INFO.NE.0) THEN
126:           CALL XERBLA('DSPMV ',INFO)
127:           RETURN
128:       END IF
129: *
130: *     Quick return if possible.
131: *
132:       IF ((N.EQ.0) .OR. ((ALPHA.EQ.ZERO).AND. (BETA.EQ.ONE))) RETURN
133: *
134: *     Set up the start points in  X  and  Y.
135: *
136:       IF (INCX.GT.0) THEN
137:           KX = 1
138:       ELSE
139:           KX = 1 - (N-1)*INCX
140:       END IF
141:       IF (INCY.GT.0) THEN
142:           KY = 1
143:       ELSE
144:           KY = 1 - (N-1)*INCY
145:       END IF
146: *
147: *     Start the operations. In this version the elements of the array AP
148: *     are accessed sequentially with one pass through AP.
149: *
150: *     First form  y := beta*y.
151: *
152:       IF (BETA.NE.ONE) THEN
153:           IF (INCY.EQ.1) THEN
154:               IF (BETA.EQ.ZERO) THEN
155:                   DO 10 I = 1,N
156:                       Y(I) = ZERO
157:    10             CONTINUE
158:               ELSE
159:                   DO 20 I = 1,N
160:                       Y(I) = BETA*Y(I)
161:    20             CONTINUE
162:               END IF
163:           ELSE
164:               IY = KY
165:               IF (BETA.EQ.ZERO) THEN
166:                   DO 30 I = 1,N
167:                       Y(IY) = ZERO
168:                       IY = IY + INCY
169:    30             CONTINUE
170:               ELSE
171:                   DO 40 I = 1,N
172:                       Y(IY) = BETA*Y(IY)
173:                       IY = IY + INCY
174:    40             CONTINUE
175:               END IF
176:           END IF
177:       END IF
178:       IF (ALPHA.EQ.ZERO) RETURN
179:       KK = 1
180:       IF (LSAME(UPLO,'U')) THEN
181: *
182: *        Form  y  when AP contains the upper triangle.
183: *
184:           IF ((INCX.EQ.1) .AND. (INCY.EQ.1)) THEN
185:               DO 60 J = 1,N
186:                   TEMP1 = ALPHA*X(J)
187:                   TEMP2 = ZERO
188:                   K = KK
189:                   DO 50 I = 1,J - 1
190:                       Y(I) = Y(I) + TEMP1*AP(K)
191:                       TEMP2 = TEMP2 + AP(K)*X(I)
192:                       K = K + 1
193:    50             CONTINUE
194:                   Y(J) = Y(J) + TEMP1*AP(KK+J-1) + ALPHA*TEMP2
195:                   KK = KK + J
196:    60         CONTINUE
197:           ELSE
198:               JX = KX
199:               JY = KY
200:               DO 80 J = 1,N
201:                   TEMP1 = ALPHA*X(JX)
202:                   TEMP2 = ZERO
203:                   IX = KX
204:                   IY = KY
205:                   DO 70 K = KK,KK + J - 2
206:                       Y(IY) = Y(IY) + TEMP1*AP(K)
207:                       TEMP2 = TEMP2 + AP(K)*X(IX)
208:                       IX = IX + INCX
209:                       IY = IY + INCY
210:    70             CONTINUE
211:                   Y(JY) = Y(JY) + TEMP1*AP(KK+J-1) + ALPHA*TEMP2
212:                   JX = JX + INCX
213:                   JY = JY + INCY
214:                   KK = KK + J
215:    80         CONTINUE
216:           END IF
217:       ELSE
218: *
219: *        Form  y  when AP contains the lower triangle.
220: *
221:           IF ((INCX.EQ.1) .AND. (INCY.EQ.1)) THEN
222:               DO 100 J = 1,N
223:                   TEMP1 = ALPHA*X(J)
224:                   TEMP2 = ZERO
225:                   Y(J) = Y(J) + TEMP1*AP(KK)
226:                   K = KK + 1
227:                   DO 90 I = J + 1,N
228:                       Y(I) = Y(I) + TEMP1*AP(K)
229:                       TEMP2 = TEMP2 + AP(K)*X(I)
230:                       K = K + 1
231:    90             CONTINUE
232:                   Y(J) = Y(J) + ALPHA*TEMP2
233:                   KK = KK + (N-J+1)
234:   100         CONTINUE
235:           ELSE
236:               JX = KX
237:               JY = KY
238:               DO 120 J = 1,N
239:                   TEMP1 = ALPHA*X(JX)
240:                   TEMP2 = ZERO
241:                   Y(JY) = Y(JY) + TEMP1*AP(KK)
242:                   IX = JX
243:                   IY = JY
244:                   DO 110 K = KK + 1,KK + N - J
245:                       IX = IX + INCX
246:                       IY = IY + INCY
247:                       Y(IY) = Y(IY) + TEMP1*AP(K)
248:                       TEMP2 = TEMP2 + AP(K)*X(IX)
249:   110             CONTINUE
250:                   Y(JY) = Y(JY) + ALPHA*TEMP2
251:                   JX = JX + INCX
252:                   JY = JY + INCY
253:                   KK = KK + (N-J+1)
254:   120         CONTINUE
255:           END IF
256:       END IF
257: *
258:       RETURN
259: *
260: *     End of DSPMV .
261: *
262:       END
263: