001:       SUBROUTINE DORMQR( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
002:      $                   WORK, LWORK, INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          SIDE, TRANS
010:       INTEGER            INFO, K, LDA, LDC, LWORK, M, N
011: *     ..
012: *     .. Array Arguments ..
013:       DOUBLE PRECISION   A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
014: *     ..
015: *
016: *  Purpose
017: *  =======
018: *
019: *  DORMQR overwrites the general real M-by-N matrix C with
020: *
021: *                  SIDE = 'L'     SIDE = 'R'
022: *  TRANS = 'N':      Q * C          C * Q
023: *  TRANS = 'T':      Q**T * C       C * Q**T
024: *
025: *  where Q is a real orthogonal matrix defined as the product of k
026: *  elementary reflectors
027: *
028: *        Q = H(1) H(2) . . . H(k)
029: *
030: *  as returned by DGEQRF. Q is of order M if SIDE = 'L' and of order N
031: *  if SIDE = 'R'.
032: *
033: *  Arguments
034: *  =========
035: *
036: *  SIDE    (input) CHARACTER*1
037: *          = 'L': apply Q or Q**T from the Left;
038: *          = 'R': apply Q or Q**T from the Right.
039: *
040: *  TRANS   (input) CHARACTER*1
041: *          = 'N':  No transpose, apply Q;
042: *          = 'T':  Transpose, apply Q**T.
043: *
044: *  M       (input) INTEGER
045: *          The number of rows of the matrix C. M >= 0.
046: *
047: *  N       (input) INTEGER
048: *          The number of columns of the matrix C. N >= 0.
049: *
050: *  K       (input) INTEGER
051: *          The number of elementary reflectors whose product defines
052: *          the matrix Q.
053: *          If SIDE = 'L', M >= K >= 0;
054: *          if SIDE = 'R', N >= K >= 0.
055: *
056: *  A       (input) DOUBLE PRECISION array, dimension (LDA,K)
057: *          The i-th column must contain the vector which defines the
058: *          elementary reflector H(i), for i = 1,2,...,k, as returned by
059: *          DGEQRF in the first k columns of its array argument A.
060: *          A is modified by the routine but restored on exit.
061: *
062: *  LDA     (input) INTEGER
063: *          The leading dimension of the array A.
064: *          If SIDE = 'L', LDA >= max(1,M);
065: *          if SIDE = 'R', LDA >= max(1,N).
066: *
067: *  TAU     (input) DOUBLE PRECISION array, dimension (K)
068: *          TAU(i) must contain the scalar factor of the elementary
069: *          reflector H(i), as returned by DGEQRF.
070: *
071: *  C       (input/output) DOUBLE PRECISION array, dimension (LDC,N)
072: *          On entry, the M-by-N matrix C.
073: *          On exit, C is overwritten by Q*C or Q**T*C or C*Q**T or C*Q.
074: *
075: *  LDC     (input) INTEGER
076: *          The leading dimension of the array C. LDC >= max(1,M).
077: *
078: *  WORK    (workspace/output) DOUBLE PRECISION array, dimension (MAX(1,LWORK))
079: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
080: *
081: *  LWORK   (input) INTEGER
082: *          The dimension of the array WORK.
083: *          If SIDE = 'L', LWORK >= max(1,N);
084: *          if SIDE = 'R', LWORK >= max(1,M).
085: *          For optimum performance LWORK >= N*NB if SIDE = 'L', and
086: *          LWORK >= M*NB if SIDE = 'R', where NB is the optimal
087: *          blocksize.
088: *
089: *          If LWORK = -1, then a workspace query is assumed; the routine
090: *          only calculates the optimal size of the WORK array, returns
091: *          this value as the first entry of the WORK array, and no error
092: *          message related to LWORK is issued by XERBLA.
093: *
094: *  INFO    (output) INTEGER
095: *          = 0:  successful exit
096: *          < 0:  if INFO = -i, the i-th argument had an illegal value
097: *
098: *  =====================================================================
099: *
100: *     .. Parameters ..
101:       INTEGER            NBMAX, LDT
102:       PARAMETER          ( NBMAX = 64, LDT = NBMAX+1 )
103: *     ..
104: *     .. Local Scalars ..
105:       LOGICAL            LEFT, LQUERY, NOTRAN
106:       INTEGER            I, I1, I2, I3, IB, IC, IINFO, IWS, JC, LDWORK,
107:      $                   LWKOPT, MI, NB, NBMIN, NI, NQ, NW
108: *     ..
109: *     .. Local Arrays ..
110:       DOUBLE PRECISION   T( LDT, NBMAX )
111: *     ..
112: *     .. External Functions ..
113:       LOGICAL            LSAME
114:       INTEGER            ILAENV
115:       EXTERNAL           LSAME, ILAENV
116: *     ..
117: *     .. External Subroutines ..
118:       EXTERNAL           DLARFB, DLARFT, DORM2R, XERBLA
119: *     ..
120: *     .. Intrinsic Functions ..
121:       INTRINSIC          MAX, MIN
122: *     ..
123: *     .. Executable Statements ..
124: *
125: *     Test the input arguments
126: *
127:       INFO = 0
128:       LEFT = LSAME( SIDE, 'L' )
129:       NOTRAN = LSAME( TRANS, 'N' )
130:       LQUERY = ( LWORK.EQ.-1 )
131: *
132: *     NQ is the order of Q and NW is the minimum dimension of WORK
133: *
134:       IF( LEFT ) THEN
135:          NQ = M
136:          NW = N
137:       ELSE
138:          NQ = N
139:          NW = M
140:       END IF
141:       IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
142:          INFO = -1
143:       ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'T' ) ) THEN
144:          INFO = -2
145:       ELSE IF( M.LT.0 ) THEN
146:          INFO = -3
147:       ELSE IF( N.LT.0 ) THEN
148:          INFO = -4
149:       ELSE IF( K.LT.0 .OR. K.GT.NQ ) THEN
150:          INFO = -5
151:       ELSE IF( LDA.LT.MAX( 1, NQ ) ) THEN
152:          INFO = -7
153:       ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
154:          INFO = -10
155:       ELSE IF( LWORK.LT.MAX( 1, NW ) .AND. .NOT.LQUERY ) THEN
156:          INFO = -12
157:       END IF
158: *
159:       IF( INFO.EQ.0 ) THEN
160: *
161: *        Determine the block size.  NB may be at most NBMAX, where NBMAX
162: *        is used to define the local array T.
163: *
164:          NB = MIN( NBMAX, ILAENV( 1, 'DORMQR', SIDE // TRANS, M, N, K,
165:      $        -1 ) )
166:          LWKOPT = MAX( 1, NW )*NB
167:          WORK( 1 ) = LWKOPT
168:       END IF
169: *
170:       IF( INFO.NE.0 ) THEN
171:          CALL XERBLA( 'DORMQR', -INFO )
172:          RETURN
173:       ELSE IF( LQUERY ) THEN
174:          RETURN
175:       END IF
176: *
177: *     Quick return if possible
178: *
179:       IF( M.EQ.0 .OR. N.EQ.0 .OR. K.EQ.0 ) THEN
180:          WORK( 1 ) = 1
181:          RETURN
182:       END IF
183: *
184:       NBMIN = 2
185:       LDWORK = NW
186:       IF( NB.GT.1 .AND. NB.LT.K ) THEN
187:          IWS = NW*NB
188:          IF( LWORK.LT.IWS ) THEN
189:             NB = LWORK / LDWORK
190:             NBMIN = MAX( 2, ILAENV( 2, 'DORMQR', SIDE // TRANS, M, N, K,
191:      $              -1 ) )
192:          END IF
193:       ELSE
194:          IWS = NW
195:       END IF
196: *
197:       IF( NB.LT.NBMIN .OR. NB.GE.K ) THEN
198: *
199: *        Use unblocked code
200: *
201:          CALL DORM2R( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK,
202:      $                IINFO )
203:       ELSE
204: *
205: *        Use blocked code
206: *
207:          IF( ( LEFT .AND. .NOT.NOTRAN ) .OR.
208:      $       ( .NOT.LEFT .AND. NOTRAN ) ) THEN
209:             I1 = 1
210:             I2 = K
211:             I3 = NB
212:          ELSE
213:             I1 = ( ( K-1 ) / NB )*NB + 1
214:             I2 = 1
215:             I3 = -NB
216:          END IF
217: *
218:          IF( LEFT ) THEN
219:             NI = N
220:             JC = 1
221:          ELSE
222:             MI = M
223:             IC = 1
224:          END IF
225: *
226:          DO 10 I = I1, I2, I3
227:             IB = MIN( NB, K-I+1 )
228: *
229: *           Form the triangular factor of the block reflector
230: *           H = H(i) H(i+1) . . . H(i+ib-1)
231: *
232:             CALL DLARFT( 'Forward', 'Columnwise', NQ-I+1, IB, A( I, I ),
233:      $                   LDA, TAU( I ), T, LDT )
234:             IF( LEFT ) THEN
235: *
236: *              H or H' is applied to C(i:m,1:n)
237: *
238:                MI = M - I + 1
239:                IC = I
240:             ELSE
241: *
242: *              H or H' is applied to C(1:m,i:n)
243: *
244:                NI = N - I + 1
245:                JC = I
246:             END IF
247: *
248: *           Apply H or H'
249: *
250:             CALL DLARFB( SIDE, TRANS, 'Forward', 'Columnwise', MI, NI,
251:      $                   IB, A( I, I ), LDA, T, LDT, C( IC, JC ), LDC,
252:      $                   WORK, LDWORK )
253:    10    CONTINUE
254:       END IF
255:       WORK( 1 ) = LWKOPT
256:       RETURN
257: *
258: *     End of DORMQR
259: *
260:       END
261: