001:       SUBROUTINE DOPMTR( SIDE, UPLO, TRANS, M, N, AP, TAU, C, LDC, WORK,
002:      $                   INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          SIDE, TRANS, UPLO
010:       INTEGER            INFO, LDC, M, N
011: *     ..
012: *     .. Array Arguments ..
013:       DOUBLE PRECISION   AP( * ), C( LDC, * ), TAU( * ), WORK( * )
014: *     ..
015: *
016: *  Purpose
017: *  =======
018: *
019: *  DOPMTR overwrites the general real M-by-N matrix C with
020: *
021: *                  SIDE = 'L'     SIDE = 'R'
022: *  TRANS = 'N':      Q * C          C * Q
023: *  TRANS = 'T':      Q**T * C       C * Q**T
024: *
025: *  where Q is a real orthogonal matrix of order nq, with nq = m if
026: *  SIDE = 'L' and nq = n if SIDE = 'R'. Q is defined as the product of
027: *  nq-1 elementary reflectors, as returned by DSPTRD using packed
028: *  storage:
029: *
030: *  if UPLO = 'U', Q = H(nq-1) . . . H(2) H(1);
031: *
032: *  if UPLO = 'L', Q = H(1) H(2) . . . H(nq-1).
033: *
034: *  Arguments
035: *  =========
036: *
037: *  SIDE    (input) CHARACTER*1
038: *          = 'L': apply Q or Q**T from the Left;
039: *          = 'R': apply Q or Q**T from the Right.
040: *
041: *  UPLO    (input) CHARACTER*1
042: *          = 'U': Upper triangular packed storage used in previous
043: *                 call to DSPTRD;
044: *          = 'L': Lower triangular packed storage used in previous
045: *                 call to DSPTRD.
046: *
047: *  TRANS   (input) CHARACTER*1
048: *          = 'N':  No transpose, apply Q;
049: *          = 'T':  Transpose, apply Q**T.
050: *
051: *  M       (input) INTEGER
052: *          The number of rows of the matrix C. M >= 0.
053: *
054: *  N       (input) INTEGER
055: *          The number of columns of the matrix C. N >= 0.
056: *
057: *  AP      (input) DOUBLE PRECISION array, dimension
058: *                               (M*(M+1)/2) if SIDE = 'L'
059: *                               (N*(N+1)/2) if SIDE = 'R'
060: *          The vectors which define the elementary reflectors, as
061: *          returned by DSPTRD.  AP is modified by the routine but
062: *          restored on exit.
063: *
064: *  TAU     (input) DOUBLE PRECISION array, dimension (M-1) if SIDE = 'L'
065: *                                     or (N-1) if SIDE = 'R'
066: *          TAU(i) must contain the scalar factor of the elementary
067: *          reflector H(i), as returned by DSPTRD.
068: *
069: *  C       (input/output) DOUBLE PRECISION array, dimension (LDC,N)
070: *          On entry, the M-by-N matrix C.
071: *          On exit, C is overwritten by Q*C or Q**T*C or C*Q**T or C*Q.
072: *
073: *  LDC     (input) INTEGER
074: *          The leading dimension of the array C. LDC >= max(1,M).
075: *
076: *  WORK    (workspace) DOUBLE PRECISION array, dimension
077: *                                   (N) if SIDE = 'L'
078: *                                   (M) if SIDE = 'R'
079: *
080: *  INFO    (output) INTEGER
081: *          = 0:  successful exit
082: *          < 0:  if INFO = -i, the i-th argument had an illegal value
083: *
084: *  =====================================================================
085: *
086: *     .. Parameters ..
087:       DOUBLE PRECISION   ONE
088:       PARAMETER          ( ONE = 1.0D+0 )
089: *     ..
090: *     .. Local Scalars ..
091:       LOGICAL            FORWRD, LEFT, NOTRAN, UPPER
092:       INTEGER            I, I1, I2, I3, IC, II, JC, MI, NI, NQ
093:       DOUBLE PRECISION   AII
094: *     ..
095: *     .. External Functions ..
096:       LOGICAL            LSAME
097:       EXTERNAL           LSAME
098: *     ..
099: *     .. External Subroutines ..
100:       EXTERNAL           DLARF, XERBLA
101: *     ..
102: *     .. Intrinsic Functions ..
103:       INTRINSIC          MAX
104: *     ..
105: *     .. Executable Statements ..
106: *
107: *     Test the input arguments
108: *
109:       INFO = 0
110:       LEFT = LSAME( SIDE, 'L' )
111:       NOTRAN = LSAME( TRANS, 'N' )
112:       UPPER = LSAME( UPLO, 'U' )
113: *
114: *     NQ is the order of Q
115: *
116:       IF( LEFT ) THEN
117:          NQ = M
118:       ELSE
119:          NQ = N
120:       END IF
121:       IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
122:          INFO = -1
123:       ELSE IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
124:          INFO = -2
125:       ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'T' ) ) THEN
126:          INFO = -3
127:       ELSE IF( M.LT.0 ) THEN
128:          INFO = -4
129:       ELSE IF( N.LT.0 ) THEN
130:          INFO = -5
131:       ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
132:          INFO = -9
133:       END IF
134:       IF( INFO.NE.0 ) THEN
135:          CALL XERBLA( 'DOPMTR', -INFO )
136:          RETURN
137:       END IF
138: *
139: *     Quick return if possible
140: *
141:       IF( M.EQ.0 .OR. N.EQ.0 )
142:      $   RETURN
143: *
144:       IF( UPPER ) THEN
145: *
146: *        Q was determined by a call to DSPTRD with UPLO = 'U'
147: *
148:          FORWRD = ( LEFT .AND. NOTRAN ) .OR.
149:      $            ( .NOT.LEFT .AND. .NOT.NOTRAN )
150: *
151:          IF( FORWRD ) THEN
152:             I1 = 1
153:             I2 = NQ - 1
154:             I3 = 1
155:             II = 2
156:          ELSE
157:             I1 = NQ - 1
158:             I2 = 1
159:             I3 = -1
160:             II = NQ*( NQ+1 ) / 2 - 1
161:          END IF
162: *
163:          IF( LEFT ) THEN
164:             NI = N
165:          ELSE
166:             MI = M
167:          END IF
168: *
169:          DO 10 I = I1, I2, I3
170:             IF( LEFT ) THEN
171: *
172: *              H(i) is applied to C(1:i,1:n)
173: *
174:                MI = I
175:             ELSE
176: *
177: *              H(i) is applied to C(1:m,1:i)
178: *
179:                NI = I
180:             END IF
181: *
182: *           Apply H(i)
183: *
184:             AII = AP( II )
185:             AP( II ) = ONE
186:             CALL DLARF( SIDE, MI, NI, AP( II-I+1 ), 1, TAU( I ), C, LDC,
187:      $                  WORK )
188:             AP( II ) = AII
189: *
190:             IF( FORWRD ) THEN
191:                II = II + I + 2
192:             ELSE
193:                II = II - I - 1
194:             END IF
195:    10    CONTINUE
196:       ELSE
197: *
198: *        Q was determined by a call to DSPTRD with UPLO = 'L'.
199: *
200:          FORWRD = ( LEFT .AND. .NOT.NOTRAN ) .OR.
201:      $            ( .NOT.LEFT .AND. NOTRAN )
202: *
203:          IF( FORWRD ) THEN
204:             I1 = 1
205:             I2 = NQ - 1
206:             I3 = 1
207:             II = 2
208:          ELSE
209:             I1 = NQ - 1
210:             I2 = 1
211:             I3 = -1
212:             II = NQ*( NQ+1 ) / 2 - 1
213:          END IF
214: *
215:          IF( LEFT ) THEN
216:             NI = N
217:             JC = 1
218:          ELSE
219:             MI = M
220:             IC = 1
221:          END IF
222: *
223:          DO 20 I = I1, I2, I3
224:             AII = AP( II )
225:             AP( II ) = ONE
226:             IF( LEFT ) THEN
227: *
228: *              H(i) is applied to C(i+1:m,1:n)
229: *
230:                MI = M - I
231:                IC = I + 1
232:             ELSE
233: *
234: *              H(i) is applied to C(1:m,i+1:n)
235: *
236:                NI = N - I
237:                JC = I + 1
238:             END IF
239: *
240: *           Apply H(i)
241: *
242:             CALL DLARF( SIDE, MI, NI, AP( II ), 1, TAU( I ),
243:      $                  C( IC, JC ), LDC, WORK )
244:             AP( II ) = AII
245: *
246:             IF( FORWRD ) THEN
247:                II = II + NQ - I + 1
248:             ELSE
249:                II = II - NQ + I - 2
250:             END IF
251:    20    CONTINUE
252:       END IF
253:       RETURN
254: *
255: *     End of DOPMTR
256: *
257:       END
258: