001:       DOUBLE PRECISION FUNCTION DLA_GERCOND ( TRANS, N, A, LDA, AF, 
002:      $                            LDAF, IPIV, CMODE, C, INFO, WORK, 
003:      $     IWORK )
004: *
005: *     -- LAPACK routine (version 3.2)                                 --
006: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
007: *     -- Jason Riedy of Univ. of California Berkeley.                 --
008: *     -- November 2008                                                --
009: *
010: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
011: *     -- Univ. of California Berkeley and NAG Ltd.                    --
012: *
013:       IMPLICIT NONE
014: *     ..
015: *     .. Scalar Arguments ..
016:       CHARACTER          TRANS
017:       INTEGER            N, LDA, LDAF, INFO, CMODE
018: *     ..
019: *     .. Array Arguments ..
020:       INTEGER            IPIV( * ), IWORK( * )
021:       DOUBLE PRECISION   A( LDA, * ), AF( LDAF, * ), WORK( * ),
022:      $                   C( * )
023: *
024: *     DLA_GERCOND estimates the Skeel condition number of op(A) * op2(C)
025: *     where op2 is determined by CMODE as follows
026: *     CMODE =  1    op2(C) = C
027: *     CMODE =  0    op2(C) = I
028: *     CMODE = -1    op2(C) = inv(C)
029: *     The Skeel condition number cond(A) = norminf( |inv(A)||A| )
030: *     is computed by computing scaling factors R such that
031: *     diag(R)*A*op2(C) is row equilibrated and computing the standard
032: *     infinity-norm condition number.
033: *     WORK is a DOUBLE PRECISION workspace of size 3*N, and
034: *     IWORK is an INTEGER workspace of size N.
035: *     ..
036: *     .. Local Scalars ..
037:       LOGICAL            NOTRANS
038:       INTEGER            KASE, I, J
039:       DOUBLE PRECISION   AINVNM, TMP
040: *     ..
041: *     .. Local Arrays ..
042:       INTEGER            ISAVE( 3 )
043: *     ..
044: *     .. External Functions ..
045:       LOGICAL            LSAME
046:       EXTERNAL           LSAME
047: *     ..
048: *     .. External Subroutines ..
049:       EXTERNAL           DLACN2, DGETRS, XERBLA
050: *     ..
051: *     .. Intrinsic Functions ..
052:       INTRINSIC          ABS, MAX
053: *     ..
054: *     .. Executable Statements ..
055: *
056:       DLA_GERCOND = 0.0D+0
057: *
058:       INFO = 0
059:       NOTRANS = LSAME( TRANS, 'N' )
060:       IF ( .NOT. NOTRANS .AND. .NOT. LSAME(TRANS, 'T')
061:      $     .AND. .NOT. LSAME(TRANS, 'C') ) THEN
062:          INFO = -1
063:       ELSE IF( N.LT.0 ) THEN
064:          INFO = -2
065:       END IF
066:       IF( INFO.NE.0 ) THEN
067:          CALL XERBLA( 'DLA_GERCOND', -INFO )
068:          RETURN
069:       END IF
070:       IF( N.EQ.0 ) THEN
071:          DLA_GERCOND = 1.0D+0
072:          RETURN
073:       END IF
074: *
075: *     Compute the equilibration matrix R such that
076: *     inv(R)*A*C has unit 1-norm.
077: *
078:       IF (NOTRANS) THEN
079:          DO I = 1, N
080:             TMP = 0.0D+0
081:             IF ( CMODE .EQ. 1 ) THEN
082:                DO J = 1, N
083:                   TMP = TMP + ABS( A( I, J ) * C( J ) )
084:                END DO
085:             ELSE IF ( CMODE .EQ. 0 ) THEN
086:                DO J = 1, N
087:                   TMP = TMP + ABS( A( I, J ) )
088:                END DO
089:             ELSE
090:                DO J = 1, N
091:                   TMP = TMP + ABS( A( I, J ) / C( J ) )
092:                END DO
093:             END IF
094:             WORK( 2*N+I ) = TMP
095:          END DO
096:       ELSE
097:          DO I = 1, N
098:             TMP = 0.0D+0
099:             IF ( CMODE .EQ. 1 ) THEN
100:                DO J = 1, N
101:                   TMP = TMP + ABS( A( J, I ) * C( J ) )
102:                END DO
103:             ELSE IF ( CMODE .EQ. 0 ) THEN
104:                DO J = 1, N
105:                   TMP = TMP + ABS( A( J, I ) )
106:                END DO
107:             ELSE
108:                DO J = 1, N
109:                   TMP = TMP + ABS( A( J, I ) / C( J ) )
110:                END DO
111:             END IF
112:             WORK( 2*N+I ) = TMP
113:          END DO
114:       END IF
115: *
116: *     Estimate the norm of inv(op(A)).
117: *
118:       AINVNM = 0.0D+0
119: 
120:       KASE = 0
121:    10 CONTINUE
122:       CALL DLACN2( N, WORK( N+1 ), WORK, IWORK, AINVNM, KASE, ISAVE )
123:       IF( KASE.NE.0 ) THEN
124:          IF( KASE.EQ.2 ) THEN
125: *
126: *           Multiply by R.
127: *
128:             DO I = 1, N
129:                WORK(I) = WORK(I) * WORK(2*N+I)
130:             END DO
131: 
132:             IF (NOTRANS) THEN
133:                CALL DGETRS( 'No transpose', N, 1, AF, LDAF, IPIV,
134:      $            WORK, N, INFO )
135:             ELSE
136:                CALL DGETRS( 'Transpose', N, 1, AF, LDAF, IPIV,
137:      $            WORK, N, INFO )
138:             END IF
139: *
140: *           Multiply by inv(C).
141: *
142:             IF ( CMODE .EQ. 1 ) THEN
143:                DO I = 1, N
144:                   WORK( I ) = WORK( I ) / C( I )
145:                END DO
146:             ELSE IF ( CMODE .EQ. -1 ) THEN
147:                DO I = 1, N
148:                   WORK( I ) = WORK( I ) * C( I )
149:                END DO
150:             END IF
151:          ELSE
152: *
153: *           Multiply by inv(C').
154: *
155:             IF ( CMODE .EQ. 1 ) THEN
156:                DO I = 1, N
157:                   WORK( I ) = WORK( I ) / C( I )
158:                END DO
159:             ELSE IF ( CMODE .EQ. -1 ) THEN
160:                DO I = 1, N
161:                   WORK( I ) = WORK( I ) * C( I )
162:                END DO
163:             END IF
164: 
165:             IF (NOTRANS) THEN
166:                CALL DGETRS( 'Transpose', N, 1, AF, LDAF, IPIV,
167:      $            WORK, N, INFO )
168:             ELSE
169:                CALL DGETRS( 'No transpose', N, 1, AF, LDAF, IPIV,
170:      $            WORK, N, INFO )
171:             END IF
172: *
173: *           Multiply by R.
174: *
175:             DO I = 1, N
176:                WORK( I ) = WORK( I ) * WORK( 2*N+I )
177:             END DO
178:          END IF
179:          GO TO 10
180:       END IF
181: *
182: *     Compute the estimate of the reciprocal condition number.
183: *
184:       IF( AINVNM .NE. 0.0D+0 )
185:      $   DLA_GERCOND = ( 1.0D+0 / AINVNM )
186: *
187:       RETURN
188: *
189:       END
190: