001:       SUBROUTINE DGGBAL( JOB, N, A, LDA, B, LDB, ILO, IHI, LSCALE,
002:      $                   RSCALE, WORK, INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          JOB
010:       INTEGER            IHI, ILO, INFO, LDA, LDB, N
011: *     ..
012: *     .. Array Arguments ..
013:       DOUBLE PRECISION   A( LDA, * ), B( LDB, * ), LSCALE( * ),
014:      $                   RSCALE( * ), WORK( * )
015: *     ..
016: *
017: *  Purpose
018: *  =======
019: *
020: *  DGGBAL balances a pair of general real matrices (A,B).  This
021: *  involves, first, permuting A and B by similarity transformations to
022: *  isolate eigenvalues in the first 1 to ILO$-$1 and last IHI+1 to N
023: *  elements on the diagonal; and second, applying a diagonal similarity
024: *  transformation to rows and columns ILO to IHI to make the rows
025: *  and columns as close in norm as possible. Both steps are optional.
026: *
027: *  Balancing may reduce the 1-norm of the matrices, and improve the
028: *  accuracy of the computed eigenvalues and/or eigenvectors in the
029: *  generalized eigenvalue problem A*x = lambda*B*x.
030: *
031: *  Arguments
032: *  =========
033: *
034: *  JOB     (input) CHARACTER*1
035: *          Specifies the operations to be performed on A and B:
036: *          = 'N':  none:  simply set ILO = 1, IHI = N, LSCALE(I) = 1.0
037: *                  and RSCALE(I) = 1.0 for i = 1,...,N.
038: *          = 'P':  permute only;
039: *          = 'S':  scale only;
040: *          = 'B':  both permute and scale.
041: *
042: *  N       (input) INTEGER
043: *          The order of the matrices A and B.  N >= 0.
044: *
045: *  A       (input/output) DOUBLE PRECISION array, dimension (LDA,N)
046: *          On entry, the input matrix A.
047: *          On exit,  A is overwritten by the balanced matrix.
048: *          If JOB = 'N', A is not referenced.
049: *
050: *  LDA     (input) INTEGER
051: *          The leading dimension of the array A. LDA >= max(1,N).
052: *
053: *  B       (input/output) DOUBLE PRECISION array, dimension (LDB,N)
054: *          On entry, the input matrix B.
055: *          On exit,  B is overwritten by the balanced matrix.
056: *          If JOB = 'N', B is not referenced.
057: *
058: *  LDB     (input) INTEGER
059: *          The leading dimension of the array B. LDB >= max(1,N).
060: *
061: *  ILO     (output) INTEGER
062: *  IHI     (output) INTEGER
063: *          ILO and IHI are set to integers such that on exit
064: *          A(i,j) = 0 and B(i,j) = 0 if i > j and
065: *          j = 1,...,ILO-1 or i = IHI+1,...,N.
066: *          If JOB = 'N' or 'S', ILO = 1 and IHI = N.
067: *
068: *  LSCALE  (output) DOUBLE PRECISION array, dimension (N)
069: *          Details of the permutations and scaling factors applied
070: *          to the left side of A and B.  If P(j) is the index of the
071: *          row interchanged with row j, and D(j)
072: *          is the scaling factor applied to row j, then
073: *            LSCALE(j) = P(j)    for J = 1,...,ILO-1
074: *                      = D(j)    for J = ILO,...,IHI
075: *                      = P(j)    for J = IHI+1,...,N.
076: *          The order in which the interchanges are made is N to IHI+1,
077: *          then 1 to ILO-1.
078: *
079: *  RSCALE  (output) DOUBLE PRECISION array, dimension (N)
080: *          Details of the permutations and scaling factors applied
081: *          to the right side of A and B.  If P(j) is the index of the
082: *          column interchanged with column j, and D(j)
083: *          is the scaling factor applied to column j, then
084: *            LSCALE(j) = P(j)    for J = 1,...,ILO-1
085: *                      = D(j)    for J = ILO,...,IHI
086: *                      = P(j)    for J = IHI+1,...,N.
087: *          The order in which the interchanges are made is N to IHI+1,
088: *          then 1 to ILO-1.
089: *
090: *  WORK    (workspace) REAL array, dimension (lwork)
091: *          lwork must be at least max(1,6*N) when JOB = 'S' or 'B', and
092: *          at least 1 when JOB = 'N' or 'P'.
093: *
094: *  INFO    (output) INTEGER
095: *          = 0:  successful exit
096: *          < 0:  if INFO = -i, the i-th argument had an illegal value.
097: *
098: *  Further Details
099: *  ===============
100: *
101: *  See R.C. WARD, Balancing the generalized eigenvalue problem,
102: *                 SIAM J. Sci. Stat. Comp. 2 (1981), 141-152.
103: *
104: *  =====================================================================
105: *
106: *     .. Parameters ..
107:       DOUBLE PRECISION   ZERO, HALF, ONE
108:       PARAMETER          ( ZERO = 0.0D+0, HALF = 0.5D+0, ONE = 1.0D+0 )
109:       DOUBLE PRECISION   THREE, SCLFAC
110:       PARAMETER          ( THREE = 3.0D+0, SCLFAC = 1.0D+1 )
111: *     ..
112: *     .. Local Scalars ..
113:       INTEGER            I, ICAB, IFLOW, IP1, IR, IRAB, IT, J, JC, JP1,
114:      $                   K, KOUNT, L, LCAB, LM1, LRAB, LSFMAX, LSFMIN,
115:      $                   M, NR, NRP2
116:       DOUBLE PRECISION   ALPHA, BASL, BETA, CAB, CMAX, COEF, COEF2,
117:      $                   COEF5, COR, EW, EWC, GAMMA, PGAMMA, RAB, SFMAX,
118:      $                   SFMIN, SUM, T, TA, TB, TC
119: *     ..
120: *     .. External Functions ..
121:       LOGICAL            LSAME
122:       INTEGER            IDAMAX
123:       DOUBLE PRECISION   DDOT, DLAMCH
124:       EXTERNAL           LSAME, IDAMAX, DDOT, DLAMCH
125: *     ..
126: *     .. External Subroutines ..
127:       EXTERNAL           DAXPY, DSCAL, DSWAP, XERBLA
128: *     ..
129: *     .. Intrinsic Functions ..
130:       INTRINSIC          ABS, DBLE, INT, LOG10, MAX, MIN, SIGN
131: *     ..
132: *     .. Executable Statements ..
133: *
134: *     Test the input parameters
135: *
136:       INFO = 0
137:       IF( .NOT.LSAME( JOB, 'N' ) .AND. .NOT.LSAME( JOB, 'P' ) .AND.
138:      $    .NOT.LSAME( JOB, 'S' ) .AND. .NOT.LSAME( JOB, 'B' ) ) THEN
139:          INFO = -1
140:       ELSE IF( N.LT.0 ) THEN
141:          INFO = -2
142:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
143:          INFO = -4
144:       ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
145:          INFO = -6
146:       END IF
147:       IF( INFO.NE.0 ) THEN
148:          CALL XERBLA( 'DGGBAL', -INFO )
149:          RETURN
150:       END IF
151: *
152: *     Quick return if possible
153: *
154:       IF( N.EQ.0 ) THEN
155:          ILO = 1
156:          IHI = N
157:          RETURN
158:       END IF
159: *
160:       IF( N.EQ.1 ) THEN
161:          ILO = 1
162:          IHI = N
163:          LSCALE( 1 ) = ONE
164:          RSCALE( 1 ) = ONE
165:          RETURN
166:       END IF
167: *
168:       IF( LSAME( JOB, 'N' ) ) THEN
169:          ILO = 1
170:          IHI = N
171:          DO 10 I = 1, N
172:             LSCALE( I ) = ONE
173:             RSCALE( I ) = ONE
174:    10    CONTINUE
175:          RETURN
176:       END IF
177: *
178:       K = 1
179:       L = N
180:       IF( LSAME( JOB, 'S' ) )
181:      $   GO TO 190
182: *
183:       GO TO 30
184: *
185: *     Permute the matrices A and B to isolate the eigenvalues.
186: *
187: *     Find row with one nonzero in columns 1 through L
188: *
189:    20 CONTINUE
190:       L = LM1
191:       IF( L.NE.1 )
192:      $   GO TO 30
193: *
194:       RSCALE( 1 ) = ONE
195:       LSCALE( 1 ) = ONE
196:       GO TO 190
197: *
198:    30 CONTINUE
199:       LM1 = L - 1
200:       DO 80 I = L, 1, -1
201:          DO 40 J = 1, LM1
202:             JP1 = J + 1
203:             IF( A( I, J ).NE.ZERO .OR. B( I, J ).NE.ZERO )
204:      $         GO TO 50
205:    40    CONTINUE
206:          J = L
207:          GO TO 70
208: *
209:    50    CONTINUE
210:          DO 60 J = JP1, L
211:             IF( A( I, J ).NE.ZERO .OR. B( I, J ).NE.ZERO )
212:      $         GO TO 80
213:    60    CONTINUE
214:          J = JP1 - 1
215: *
216:    70    CONTINUE
217:          M = L
218:          IFLOW = 1
219:          GO TO 160
220:    80 CONTINUE
221:       GO TO 100
222: *
223: *     Find column with one nonzero in rows K through N
224: *
225:    90 CONTINUE
226:       K = K + 1
227: *
228:   100 CONTINUE
229:       DO 150 J = K, L
230:          DO 110 I = K, LM1
231:             IP1 = I + 1
232:             IF( A( I, J ).NE.ZERO .OR. B( I, J ).NE.ZERO )
233:      $         GO TO 120
234:   110    CONTINUE
235:          I = L
236:          GO TO 140
237:   120    CONTINUE
238:          DO 130 I = IP1, L
239:             IF( A( I, J ).NE.ZERO .OR. B( I, J ).NE.ZERO )
240:      $         GO TO 150
241:   130    CONTINUE
242:          I = IP1 - 1
243:   140    CONTINUE
244:          M = K
245:          IFLOW = 2
246:          GO TO 160
247:   150 CONTINUE
248:       GO TO 190
249: *
250: *     Permute rows M and I
251: *
252:   160 CONTINUE
253:       LSCALE( M ) = I
254:       IF( I.EQ.M )
255:      $   GO TO 170
256:       CALL DSWAP( N-K+1, A( I, K ), LDA, A( M, K ), LDA )
257:       CALL DSWAP( N-K+1, B( I, K ), LDB, B( M, K ), LDB )
258: *
259: *     Permute columns M and J
260: *
261:   170 CONTINUE
262:       RSCALE( M ) = J
263:       IF( J.EQ.M )
264:      $   GO TO 180
265:       CALL DSWAP( L, A( 1, J ), 1, A( 1, M ), 1 )
266:       CALL DSWAP( L, B( 1, J ), 1, B( 1, M ), 1 )
267: *
268:   180 CONTINUE
269:       GO TO ( 20, 90 )IFLOW
270: *
271:   190 CONTINUE
272:       ILO = K
273:       IHI = L
274: *
275:       IF( LSAME( JOB, 'P' ) ) THEN
276:          DO 195 I = ILO, IHI
277:             LSCALE( I ) = ONE
278:             RSCALE( I ) = ONE
279:   195    CONTINUE
280:          RETURN
281:       END IF
282: *
283:       IF( ILO.EQ.IHI )
284:      $   RETURN
285: *
286: *     Balance the submatrix in rows ILO to IHI.
287: *
288:       NR = IHI - ILO + 1
289:       DO 200 I = ILO, IHI
290:          RSCALE( I ) = ZERO
291:          LSCALE( I ) = ZERO
292: *
293:          WORK( I ) = ZERO
294:          WORK( I+N ) = ZERO
295:          WORK( I+2*N ) = ZERO
296:          WORK( I+3*N ) = ZERO
297:          WORK( I+4*N ) = ZERO
298:          WORK( I+5*N ) = ZERO
299:   200 CONTINUE
300: *
301: *     Compute right side vector in resulting linear equations
302: *
303:       BASL = LOG10( SCLFAC )
304:       DO 240 I = ILO, IHI
305:          DO 230 J = ILO, IHI
306:             TB = B( I, J )
307:             TA = A( I, J )
308:             IF( TA.EQ.ZERO )
309:      $         GO TO 210
310:             TA = LOG10( ABS( TA ) ) / BASL
311:   210       CONTINUE
312:             IF( TB.EQ.ZERO )
313:      $         GO TO 220
314:             TB = LOG10( ABS( TB ) ) / BASL
315:   220       CONTINUE
316:             WORK( I+4*N ) = WORK( I+4*N ) - TA - TB
317:             WORK( J+5*N ) = WORK( J+5*N ) - TA - TB
318:   230    CONTINUE
319:   240 CONTINUE
320: *
321:       COEF = ONE / DBLE( 2*NR )
322:       COEF2 = COEF*COEF
323:       COEF5 = HALF*COEF2
324:       NRP2 = NR + 2
325:       BETA = ZERO
326:       IT = 1
327: *
328: *     Start generalized conjugate gradient iteration
329: *
330:   250 CONTINUE
331: *
332:       GAMMA = DDOT( NR, WORK( ILO+4*N ), 1, WORK( ILO+4*N ), 1 ) +
333:      $        DDOT( NR, WORK( ILO+5*N ), 1, WORK( ILO+5*N ), 1 )
334: *
335:       EW = ZERO
336:       EWC = ZERO
337:       DO 260 I = ILO, IHI
338:          EW = EW + WORK( I+4*N )
339:          EWC = EWC + WORK( I+5*N )
340:   260 CONTINUE
341: *
342:       GAMMA = COEF*GAMMA - COEF2*( EW**2+EWC**2 ) - COEF5*( EW-EWC )**2
343:       IF( GAMMA.EQ.ZERO )
344:      $   GO TO 350
345:       IF( IT.NE.1 )
346:      $   BETA = GAMMA / PGAMMA
347:       T = COEF5*( EWC-THREE*EW )
348:       TC = COEF5*( EW-THREE*EWC )
349: *
350:       CALL DSCAL( NR, BETA, WORK( ILO ), 1 )
351:       CALL DSCAL( NR, BETA, WORK( ILO+N ), 1 )
352: *
353:       CALL DAXPY( NR, COEF, WORK( ILO+4*N ), 1, WORK( ILO+N ), 1 )
354:       CALL DAXPY( NR, COEF, WORK( ILO+5*N ), 1, WORK( ILO ), 1 )
355: *
356:       DO 270 I = ILO, IHI
357:          WORK( I ) = WORK( I ) + TC
358:          WORK( I+N ) = WORK( I+N ) + T
359:   270 CONTINUE
360: *
361: *     Apply matrix to vector
362: *
363:       DO 300 I = ILO, IHI
364:          KOUNT = 0
365:          SUM = ZERO
366:          DO 290 J = ILO, IHI
367:             IF( A( I, J ).EQ.ZERO )
368:      $         GO TO 280
369:             KOUNT = KOUNT + 1
370:             SUM = SUM + WORK( J )
371:   280       CONTINUE
372:             IF( B( I, J ).EQ.ZERO )
373:      $         GO TO 290
374:             KOUNT = KOUNT + 1
375:             SUM = SUM + WORK( J )
376:   290    CONTINUE
377:          WORK( I+2*N ) = DBLE( KOUNT )*WORK( I+N ) + SUM
378:   300 CONTINUE
379: *
380:       DO 330 J = ILO, IHI
381:          KOUNT = 0
382:          SUM = ZERO
383:          DO 320 I = ILO, IHI
384:             IF( A( I, J ).EQ.ZERO )
385:      $         GO TO 310
386:             KOUNT = KOUNT + 1
387:             SUM = SUM + WORK( I+N )
388:   310       CONTINUE
389:             IF( B( I, J ).EQ.ZERO )
390:      $         GO TO 320
391:             KOUNT = KOUNT + 1
392:             SUM = SUM + WORK( I+N )
393:   320    CONTINUE
394:          WORK( J+3*N ) = DBLE( KOUNT )*WORK( J ) + SUM
395:   330 CONTINUE
396: *
397:       SUM = DDOT( NR, WORK( ILO+N ), 1, WORK( ILO+2*N ), 1 ) +
398:      $      DDOT( NR, WORK( ILO ), 1, WORK( ILO+3*N ), 1 )
399:       ALPHA = GAMMA / SUM
400: *
401: *     Determine correction to current iteration
402: *
403:       CMAX = ZERO
404:       DO 340 I = ILO, IHI
405:          COR = ALPHA*WORK( I+N )
406:          IF( ABS( COR ).GT.CMAX )
407:      $      CMAX = ABS( COR )
408:          LSCALE( I ) = LSCALE( I ) + COR
409:          COR = ALPHA*WORK( I )
410:          IF( ABS( COR ).GT.CMAX )
411:      $      CMAX = ABS( COR )
412:          RSCALE( I ) = RSCALE( I ) + COR
413:   340 CONTINUE
414:       IF( CMAX.LT.HALF )
415:      $   GO TO 350
416: *
417:       CALL DAXPY( NR, -ALPHA, WORK( ILO+2*N ), 1, WORK( ILO+4*N ), 1 )
418:       CALL DAXPY( NR, -ALPHA, WORK( ILO+3*N ), 1, WORK( ILO+5*N ), 1 )
419: *
420:       PGAMMA = GAMMA
421:       IT = IT + 1
422:       IF( IT.LE.NRP2 )
423:      $   GO TO 250
424: *
425: *     End generalized conjugate gradient iteration
426: *
427:   350 CONTINUE
428:       SFMIN = DLAMCH( 'S' )
429:       SFMAX = ONE / SFMIN
430:       LSFMIN = INT( LOG10( SFMIN ) / BASL+ONE )
431:       LSFMAX = INT( LOG10( SFMAX ) / BASL )
432:       DO 360 I = ILO, IHI
433:          IRAB = IDAMAX( N-ILO+1, A( I, ILO ), LDA )
434:          RAB = ABS( A( I, IRAB+ILO-1 ) )
435:          IRAB = IDAMAX( N-ILO+1, B( I, ILO ), LDB )
436:          RAB = MAX( RAB, ABS( B( I, IRAB+ILO-1 ) ) )
437:          LRAB = INT( LOG10( RAB+SFMIN ) / BASL+ONE )
438:          IR = LSCALE( I ) + SIGN( HALF, LSCALE( I ) )
439:          IR = MIN( MAX( IR, LSFMIN ), LSFMAX, LSFMAX-LRAB )
440:          LSCALE( I ) = SCLFAC**IR
441:          ICAB = IDAMAX( IHI, A( 1, I ), 1 )
442:          CAB = ABS( A( ICAB, I ) )
443:          ICAB = IDAMAX( IHI, B( 1, I ), 1 )
444:          CAB = MAX( CAB, ABS( B( ICAB, I ) ) )
445:          LCAB = INT( LOG10( CAB+SFMIN ) / BASL+ONE )
446:          JC = RSCALE( I ) + SIGN( HALF, RSCALE( I ) )
447:          JC = MIN( MAX( JC, LSFMIN ), LSFMAX, LSFMAX-LCAB )
448:          RSCALE( I ) = SCLFAC**JC
449:   360 CONTINUE
450: *
451: *     Row scaling of matrices A and B
452: *
453:       DO 370 I = ILO, IHI
454:          CALL DSCAL( N-ILO+1, LSCALE( I ), A( I, ILO ), LDA )
455:          CALL DSCAL( N-ILO+1, LSCALE( I ), B( I, ILO ), LDB )
456:   370 CONTINUE
457: *
458: *     Column scaling of matrices A and B
459: *
460:       DO 380 J = ILO, IHI
461:          CALL DSCAL( IHI, RSCALE( J ), A( 1, J ), 1 )
462:          CALL DSCAL( IHI, RSCALE( J ), B( 1, J ), 1 )
463:   380 CONTINUE
464: *
465:       RETURN
466: *
467: *     End of DGGBAL
468: *
469:       END
470: