001:       SUBROUTINE CUPMTR( SIDE, UPLO, TRANS, M, N, AP, TAU, C, LDC, WORK,
002:      $                   INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          SIDE, TRANS, UPLO
010:       INTEGER            INFO, LDC, M, N
011: *     ..
012: *     .. Array Arguments ..
013:       COMPLEX            AP( * ), C( LDC, * ), TAU( * ), WORK( * )
014: *     ..
015: *
016: *  Purpose
017: *  =======
018: *
019: *  CUPMTR overwrites the general complex M-by-N matrix C with
020: *
021: *                  SIDE = 'L'     SIDE = 'R'
022: *  TRANS = 'N':      Q * C          C * Q
023: *  TRANS = 'C':      Q**H * C       C * Q**H
024: *
025: *  where Q is a complex unitary matrix of order nq, with nq = m if
026: *  SIDE = 'L' and nq = n if SIDE = 'R'. Q is defined as the product of
027: *  nq-1 elementary reflectors, as returned by CHPTRD using packed
028: *  storage:
029: *
030: *  if UPLO = 'U', Q = H(nq-1) . . . H(2) H(1);
031: *
032: *  if UPLO = 'L', Q = H(1) H(2) . . . H(nq-1).
033: *
034: *  Arguments
035: *  =========
036: *
037: *  SIDE    (input) CHARACTER*1
038: *          = 'L': apply Q or Q**H from the Left;
039: *          = 'R': apply Q or Q**H from the Right.
040: *
041: *  UPLO    (input) CHARACTER*1
042: *          = 'U': Upper triangular packed storage used in previous
043: *                 call to CHPTRD;
044: *          = 'L': Lower triangular packed storage used in previous
045: *                 call to CHPTRD.
046: *
047: *  TRANS   (input) CHARACTER*1
048: *          = 'N':  No transpose, apply Q;
049: *          = 'C':  Conjugate transpose, apply Q**H.
050: *
051: *  M       (input) INTEGER
052: *          The number of rows of the matrix C. M >= 0.
053: *
054: *  N       (input) INTEGER
055: *          The number of columns of the matrix C. N >= 0.
056: *
057: *  AP      (input) COMPLEX array, dimension
058: *                               (M*(M+1)/2) if SIDE = 'L'
059: *                               (N*(N+1)/2) if SIDE = 'R'
060: *          The vectors which define the elementary reflectors, as
061: *          returned by CHPTRD.  AP is modified by the routine but
062: *          restored on exit.
063: *
064: *  TAU     (input) COMPLEX array, dimension (M-1) if SIDE = 'L'
065: *                                     or (N-1) if SIDE = 'R'
066: *          TAU(i) must contain the scalar factor of the elementary
067: *          reflector H(i), as returned by CHPTRD.
068: *
069: *  C       (input/output) COMPLEX array, dimension (LDC,N)
070: *          On entry, the M-by-N matrix C.
071: *          On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
072: *
073: *  LDC     (input) INTEGER
074: *          The leading dimension of the array C. LDC >= max(1,M).
075: *
076: *  WORK    (workspace) COMPLEX array, dimension
077: *                                   (N) if SIDE = 'L'
078: *                                   (M) if SIDE = 'R'
079: *
080: *  INFO    (output) INTEGER
081: *          = 0:  successful exit
082: *          < 0:  if INFO = -i, the i-th argument had an illegal value
083: *
084: *  =====================================================================
085: *
086: *     .. Parameters ..
087:       COMPLEX            ONE
088:       PARAMETER          ( ONE = ( 1.0E+0, 0.0E+0 ) )
089: *     ..
090: *     .. Local Scalars ..
091:       LOGICAL            FORWRD, LEFT, NOTRAN, UPPER
092:       INTEGER            I, I1, I2, I3, IC, II, JC, MI, NI, NQ
093:       COMPLEX            AII, TAUI
094: *     ..
095: *     .. External Functions ..
096:       LOGICAL            LSAME
097:       EXTERNAL           LSAME
098: *     ..
099: *     .. External Subroutines ..
100:       EXTERNAL           CLARF, XERBLA
101: *     ..
102: *     .. Intrinsic Functions ..
103:       INTRINSIC          CONJG, MAX
104: *     ..
105: *     .. Executable Statements ..
106: *
107: *     Test the input arguments
108: *
109:       INFO = 0
110:       LEFT = LSAME( SIDE, 'L' )
111:       NOTRAN = LSAME( TRANS, 'N' )
112:       UPPER = LSAME( UPLO, 'U' )
113: *
114: *     NQ is the order of Q
115: *
116:       IF( LEFT ) THEN
117:          NQ = M
118:       ELSE
119:          NQ = N
120:       END IF
121:       IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
122:          INFO = -1
123:       ELSE IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
124:          INFO = -2
125:       ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'C' ) ) THEN
126:          INFO = -3
127:       ELSE IF( M.LT.0 ) THEN
128:          INFO = -4
129:       ELSE IF( N.LT.0 ) THEN
130:          INFO = -5
131:       ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
132:          INFO = -9
133:       END IF
134:       IF( INFO.NE.0 ) THEN
135:          CALL XERBLA( 'CUPMTR', -INFO )
136:          RETURN
137:       END IF
138: *
139: *     Quick return if possible
140: *
141:       IF( M.EQ.0 .OR. N.EQ.0 )
142:      $   RETURN
143: *
144:       IF( UPPER ) THEN
145: *
146: *        Q was determined by a call to CHPTRD with UPLO = 'U'
147: *
148:          FORWRD = ( LEFT .AND. NOTRAN ) .OR.
149:      $            ( .NOT.LEFT .AND. .NOT.NOTRAN )
150: *
151:          IF( FORWRD ) THEN
152:             I1 = 1
153:             I2 = NQ - 1
154:             I3 = 1
155:             II = 2
156:          ELSE
157:             I1 = NQ - 1
158:             I2 = 1
159:             I3 = -1
160:             II = NQ*( NQ+1 ) / 2 - 1
161:          END IF
162: *
163:          IF( LEFT ) THEN
164:             NI = N
165:          ELSE
166:             MI = M
167:          END IF
168: *
169:          DO 10 I = I1, I2, I3
170:             IF( LEFT ) THEN
171: *
172: *              H(i) or H(i)' is applied to C(1:i,1:n)
173: *
174:                MI = I
175:             ELSE
176: *
177: *              H(i) or H(i)' is applied to C(1:m,1:i)
178: *
179:                NI = I
180:             END IF
181: *
182: *           Apply H(i) or H(i)'
183: *
184:             IF( NOTRAN ) THEN
185:                TAUI = TAU( I )
186:             ELSE
187:                TAUI = CONJG( TAU( I ) )
188:             END IF
189:             AII = AP( II )
190:             AP( II ) = ONE
191:             CALL CLARF( SIDE, MI, NI, AP( II-I+1 ), 1, TAUI, C, LDC,
192:      $                  WORK )
193:             AP( II ) = AII
194: *
195:             IF( FORWRD ) THEN
196:                II = II + I + 2
197:             ELSE
198:                II = II - I - 1
199:             END IF
200:    10    CONTINUE
201:       ELSE
202: *
203: *        Q was determined by a call to CHPTRD with UPLO = 'L'.
204: *
205:          FORWRD = ( LEFT .AND. .NOT.NOTRAN ) .OR.
206:      $            ( .NOT.LEFT .AND. NOTRAN )
207: *
208:          IF( FORWRD ) THEN
209:             I1 = 1
210:             I2 = NQ - 1
211:             I3 = 1
212:             II = 2
213:          ELSE
214:             I1 = NQ - 1
215:             I2 = 1
216:             I3 = -1
217:             II = NQ*( NQ+1 ) / 2 - 1
218:          END IF
219: *
220:          IF( LEFT ) THEN
221:             NI = N
222:             JC = 1
223:          ELSE
224:             MI = M
225:             IC = 1
226:          END IF
227: *
228:          DO 20 I = I1, I2, I3
229:             AII = AP( II )
230:             AP( II ) = ONE
231:             IF( LEFT ) THEN
232: *
233: *              H(i) or H(i)' is applied to C(i+1:m,1:n)
234: *
235:                MI = M - I
236:                IC = I + 1
237:             ELSE
238: *
239: *              H(i) or H(i)' is applied to C(1:m,i+1:n)
240: *
241:                NI = N - I
242:                JC = I + 1
243:             END IF
244: *
245: *           Apply H(i) or H(i)'
246: *
247:             IF( NOTRAN ) THEN
248:                TAUI = TAU( I )
249:             ELSE
250:                TAUI = CONJG( TAU( I ) )
251:             END IF
252:             CALL CLARF( SIDE, MI, NI, AP( II ), 1, TAUI, C( IC, JC ),
253:      $                  LDC, WORK )
254:             AP( II ) = AII
255: *
256:             IF( FORWRD ) THEN
257:                II = II + NQ - I + 1
258:             ELSE
259:                II = II - NQ + I - 2
260:             END IF
261:    20    CONTINUE
262:       END IF
263:       RETURN
264: *
265: *     End of CUPMTR
266: *
267:       END
268: