001:       SUBROUTINE CUNMR3( SIDE, TRANS, M, N, K, L, A, LDA, TAU, C, LDC,
002:      $                   WORK, INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          SIDE, TRANS
010:       INTEGER            INFO, K, L, LDA, LDC, M, N
011: *     ..
012: *     .. Array Arguments ..
013:       COMPLEX            A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
014: *     ..
015: *
016: *  Purpose
017: *  =======
018: *
019: *  CUNMR3 overwrites the general complex m by n matrix C with
020: *
021: *        Q * C  if SIDE = 'L' and TRANS = 'N', or
022: *
023: *        Q'* C  if SIDE = 'L' and TRANS = 'C', or
024: *
025: *        C * Q  if SIDE = 'R' and TRANS = 'N', or
026: *
027: *        C * Q' if SIDE = 'R' and TRANS = 'C',
028: *
029: *  where Q is a complex unitary matrix defined as the product of k
030: *  elementary reflectors
031: *
032: *        Q = H(1) H(2) . . . H(k)
033: *
034: *  as returned by CTZRZF. Q is of order m if SIDE = 'L' and of order n
035: *  if SIDE = 'R'.
036: *
037: *  Arguments
038: *  =========
039: *
040: *  SIDE    (input) CHARACTER*1
041: *          = 'L': apply Q or Q' from the Left
042: *          = 'R': apply Q or Q' from the Right
043: *
044: *  TRANS   (input) CHARACTER*1
045: *          = 'N': apply Q  (No transpose)
046: *          = 'C': apply Q' (Conjugate transpose)
047: *
048: *  M       (input) INTEGER
049: *          The number of rows of the matrix C. M >= 0.
050: *
051: *  N       (input) INTEGER
052: *          The number of columns of the matrix C. N >= 0.
053: *
054: *  K       (input) INTEGER
055: *          The number of elementary reflectors whose product defines
056: *          the matrix Q.
057: *          If SIDE = 'L', M >= K >= 0;
058: *          if SIDE = 'R', N >= K >= 0.
059: *
060: *  L       (input) INTEGER
061: *          The number of columns of the matrix A containing
062: *          the meaningful part of the Householder reflectors.
063: *          If SIDE = 'L', M >= L >= 0, if SIDE = 'R', N >= L >= 0.
064: *
065: *  A       (input) COMPLEX array, dimension
066: *                               (LDA,M) if SIDE = 'L',
067: *                               (LDA,N) if SIDE = 'R'
068: *          The i-th row must contain the vector which defines the
069: *          elementary reflector H(i), for i = 1,2,...,k, as returned by
070: *          CTZRZF in the last k rows of its array argument A.
071: *          A is modified by the routine but restored on exit.
072: *
073: *  LDA     (input) INTEGER
074: *          The leading dimension of the array A. LDA >= max(1,K).
075: *
076: *  TAU     (input) COMPLEX array, dimension (K)
077: *          TAU(i) must contain the scalar factor of the elementary
078: *          reflector H(i), as returned by CTZRZF.
079: *
080: *  C       (input/output) COMPLEX array, dimension (LDC,N)
081: *          On entry, the m-by-n matrix C.
082: *          On exit, C is overwritten by Q*C or Q'*C or C*Q' or C*Q.
083: *
084: *  LDC     (input) INTEGER
085: *          The leading dimension of the array C. LDC >= max(1,M).
086: *
087: *  WORK    (workspace) COMPLEX array, dimension
088: *                                   (N) if SIDE = 'L',
089: *                                   (M) if SIDE = 'R'
090: *
091: *  INFO    (output) INTEGER
092: *          = 0: successful exit
093: *          < 0: if INFO = -i, the i-th argument had an illegal value
094: *
095: *  Further Details
096: *  ===============
097: *
098: *  Based on contributions by
099: *    A. Petitet, Computer Science Dept., Univ. of Tenn., Knoxville, USA
100: *
101: *  =====================================================================
102: *
103: *     .. Local Scalars ..
104:       LOGICAL            LEFT, NOTRAN
105:       INTEGER            I, I1, I2, I3, IC, JA, JC, MI, NI, NQ
106:       COMPLEX            TAUI
107: *     ..
108: *     .. External Functions ..
109:       LOGICAL            LSAME
110:       EXTERNAL           LSAME
111: *     ..
112: *     .. External Subroutines ..
113:       EXTERNAL           CLARZ, XERBLA
114: *     ..
115: *     .. Intrinsic Functions ..
116:       INTRINSIC          CONJG, MAX
117: *     ..
118: *     .. Executable Statements ..
119: *
120: *     Test the input arguments
121: *
122:       INFO = 0
123:       LEFT = LSAME( SIDE, 'L' )
124:       NOTRAN = LSAME( TRANS, 'N' )
125: *
126: *     NQ is the order of Q
127: *
128:       IF( LEFT ) THEN
129:          NQ = M
130:       ELSE
131:          NQ = N
132:       END IF
133:       IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
134:          INFO = -1
135:       ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'C' ) ) THEN
136:          INFO = -2
137:       ELSE IF( M.LT.0 ) THEN
138:          INFO = -3
139:       ELSE IF( N.LT.0 ) THEN
140:          INFO = -4
141:       ELSE IF( K.LT.0 .OR. K.GT.NQ ) THEN
142:          INFO = -5
143:       ELSE IF( L.LT.0 .OR. ( LEFT .AND. ( L.GT.M ) ) .OR.
144:      $         ( .NOT.LEFT .AND. ( L.GT.N ) ) ) THEN
145:          INFO = -6
146:       ELSE IF( LDA.LT.MAX( 1, K ) ) THEN
147:          INFO = -8
148:       ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
149:          INFO = -11
150:       END IF
151:       IF( INFO.NE.0 ) THEN
152:          CALL XERBLA( 'CUNMR3', -INFO )
153:          RETURN
154:       END IF
155: *
156: *     Quick return if possible
157: *
158:       IF( M.EQ.0 .OR. N.EQ.0 .OR. K.EQ.0 )
159:      $   RETURN
160: *
161:       IF( ( LEFT .AND. .NOT.NOTRAN .OR. .NOT.LEFT .AND. NOTRAN ) ) THEN
162:          I1 = 1
163:          I2 = K
164:          I3 = 1
165:       ELSE
166:          I1 = K
167:          I2 = 1
168:          I3 = -1
169:       END IF
170: *
171:       IF( LEFT ) THEN
172:          NI = N
173:          JA = M - L + 1
174:          JC = 1
175:       ELSE
176:          MI = M
177:          JA = N - L + 1
178:          IC = 1
179:       END IF
180: *
181:       DO 10 I = I1, I2, I3
182:          IF( LEFT ) THEN
183: *
184: *           H(i) or H(i)' is applied to C(i:m,1:n)
185: *
186:             MI = M - I + 1
187:             IC = I
188:          ELSE
189: *
190: *           H(i) or H(i)' is applied to C(1:m,i:n)
191: *
192:             NI = N - I + 1
193:             JC = I
194:          END IF
195: *
196: *        Apply H(i) or H(i)'
197: *
198:          IF( NOTRAN ) THEN
199:             TAUI = TAU( I )
200:          ELSE
201:             TAUI = CONJG( TAU( I ) )
202:          END IF
203:          CALL CLARZ( SIDE, MI, NI, L, A( I, JA ), LDA, TAUI,
204:      $               C( IC, JC ), LDC, WORK )
205: *
206:    10 CONTINUE
207: *
208:       RETURN
209: *
210: *     End of CUNMR3
211: *
212:       END
213: