001:       SUBROUTINE CUNMQL( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
002:      $                   WORK, LWORK, INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          SIDE, TRANS
010:       INTEGER            INFO, K, LDA, LDC, LWORK, M, N
011: *     ..
012: *     .. Array Arguments ..
013:       COMPLEX            A( LDA, * ), C( LDC, * ), TAU( * ),
014:      $                   WORK( * )
015: *     ..
016: *
017: *  Purpose
018: *  =======
019: *
020: *  CUNMQL overwrites the general complex M-by-N matrix C with
021: *
022: *                  SIDE = 'L'     SIDE = 'R'
023: *  TRANS = 'N':      Q * C          C * Q
024: *  TRANS = 'C':      Q**H * C       C * Q**H
025: *
026: *  where Q is a complex unitary matrix defined as the product of k
027: *  elementary reflectors
028: *
029: *        Q = H(k) . . . H(2) H(1)
030: *
031: *  as returned by CGEQLF. Q is of order M if SIDE = 'L' and of order N
032: *  if SIDE = 'R'.
033: *
034: *  Arguments
035: *  =========
036: *
037: *  SIDE    (input) CHARACTER*1
038: *          = 'L': apply Q or Q**H from the Left;
039: *          = 'R': apply Q or Q**H from the Right.
040: *
041: *  TRANS   (input) CHARACTER*1
042: *          = 'N':  No transpose, apply Q;
043: *          = 'C':  Transpose, apply Q**H.
044: *
045: *  M       (input) INTEGER
046: *          The number of rows of the matrix C. M >= 0.
047: *
048: *  N       (input) INTEGER
049: *          The number of columns of the matrix C. N >= 0.
050: *
051: *  K       (input) INTEGER
052: *          The number of elementary reflectors whose product defines
053: *          the matrix Q.
054: *          If SIDE = 'L', M >= K >= 0;
055: *          if SIDE = 'R', N >= K >= 0.
056: *
057: *  A       (input) COMPLEX array, dimension (LDA,K)
058: *          The i-th column must contain the vector which defines the
059: *          elementary reflector H(i), for i = 1,2,...,k, as returned by
060: *          CGEQLF in the last k columns of its array argument A.
061: *          A is modified by the routine but restored on exit.
062: *
063: *  LDA     (input) INTEGER
064: *          The leading dimension of the array A.
065: *          If SIDE = 'L', LDA >= max(1,M);
066: *          if SIDE = 'R', LDA >= max(1,N).
067: *
068: *  TAU     (input) COMPLEX array, dimension (K)
069: *          TAU(i) must contain the scalar factor of the elementary
070: *          reflector H(i), as returned by CGEQLF.
071: *
072: *  C       (input/output) COMPLEX array, dimension (LDC,N)
073: *          On entry, the M-by-N matrix C.
074: *          On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
075: *
076: *  LDC     (input) INTEGER
077: *          The leading dimension of the array C. LDC >= max(1,M).
078: *
079: *  WORK    (workspace/output) COMPLEX array, dimension (MAX(1,LWORK))
080: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
081: *
082: *  LWORK   (input) INTEGER
083: *          The dimension of the array WORK.
084: *          If SIDE = 'L', LWORK >= max(1,N);
085: *          if SIDE = 'R', LWORK >= max(1,M).
086: *          For optimum performance LWORK >= N*NB if SIDE = 'L', and
087: *          LWORK >= M*NB if SIDE = 'R', where NB is the optimal
088: *          blocksize.
089: *
090: *          If LWORK = -1, then a workspace query is assumed; the routine
091: *          only calculates the optimal size of the WORK array, returns
092: *          this value as the first entry of the WORK array, and no error
093: *          message related to LWORK is issued by XERBLA.
094: *
095: *  INFO    (output) INTEGER
096: *          = 0:  successful exit
097: *          < 0:  if INFO = -i, the i-th argument had an illegal value
098: *
099: *  =====================================================================
100: *
101: *     .. Parameters ..
102:       INTEGER            NBMAX, LDT
103:       PARAMETER          ( NBMAX = 64, LDT = NBMAX+1 )
104: *     ..
105: *     .. Local Scalars ..
106:       LOGICAL            LEFT, LQUERY, NOTRAN
107:       INTEGER            I, I1, I2, I3, IB, IINFO, IWS, LDWORK, LWKOPT,
108:      $                   MI, NB, NBMIN, NI, NQ, NW
109: *     ..
110: *     .. Local Arrays ..
111:       COMPLEX            T( LDT, NBMAX )
112: *     ..
113: *     .. External Functions ..
114:       LOGICAL            LSAME
115:       INTEGER            ILAENV
116:       EXTERNAL           LSAME, ILAENV
117: *     ..
118: *     .. External Subroutines ..
119:       EXTERNAL           CLARFB, CLARFT, CUNM2L, XERBLA
120: *     ..
121: *     .. Intrinsic Functions ..
122:       INTRINSIC          MAX, MIN
123: *     ..
124: *     .. Executable Statements ..
125: *
126: *     Test the input arguments
127: *
128:       INFO = 0
129:       LEFT = LSAME( SIDE, 'L' )
130:       NOTRAN = LSAME( TRANS, 'N' )
131:       LQUERY = ( LWORK.EQ.-1 )
132: *
133: *     NQ is the order of Q and NW is the minimum dimension of WORK
134: *
135:       IF( LEFT ) THEN
136:          NQ = M
137:          NW = MAX( 1, N )
138:       ELSE
139:          NQ = N
140:          NW = MAX( 1, M )
141:       END IF
142:       IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
143:          INFO = -1
144:       ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'C' ) ) THEN
145:          INFO = -2
146:       ELSE IF( M.LT.0 ) THEN
147:          INFO = -3
148:       ELSE IF( N.LT.0 ) THEN
149:          INFO = -4
150:       ELSE IF( K.LT.0 .OR. K.GT.NQ ) THEN
151:          INFO = -5
152:       ELSE IF( LDA.LT.MAX( 1, NQ ) ) THEN
153:          INFO = -7
154:       ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
155:          INFO = -10
156:       END IF
157: *
158:       IF( INFO.EQ.0 ) THEN
159:          IF( M.EQ.0 .OR. N.EQ.0 ) THEN
160:             LWKOPT = 1
161:          ELSE
162: *
163: *           Determine the block size.  NB may be at most NBMAX, where
164: *           NBMAX is used to define the local array T.
165: *
166:             NB = MIN( NBMAX, ILAENV( 1, 'CUNMQL', SIDE // TRANS, M, N,
167:      $                               K, -1 ) )
168:             LWKOPT = NW*NB
169:          END IF
170:          WORK( 1 ) = LWKOPT
171: *
172:          IF( LWORK.LT.NW .AND. .NOT.LQUERY ) THEN
173:             INFO = -12
174:          END IF
175:       END IF
176: *
177:       IF( INFO.NE.0 ) THEN
178:          CALL XERBLA( 'CUNMQL', -INFO )
179:          RETURN
180:       ELSE IF( LQUERY ) THEN
181:          RETURN
182:       END IF
183: *
184: *     Quick return if possible
185: *
186:       IF( M.EQ.0 .OR. N.EQ.0 ) THEN
187:          RETURN
188:       END IF
189: *
190:       NBMIN = 2
191:       LDWORK = NW
192:       IF( NB.GT.1 .AND. NB.LT.K ) THEN
193:          IWS = NW*NB
194:          IF( LWORK.LT.IWS ) THEN
195:             NB = LWORK / LDWORK
196:             NBMIN = MAX( 2, ILAENV( 2, 'CUNMQL', SIDE // TRANS, M, N, K,
197:      $              -1 ) )
198:          END IF
199:       ELSE
200:          IWS = NW
201:       END IF
202: *
203:       IF( NB.LT.NBMIN .OR. NB.GE.K ) THEN
204: *
205: *        Use unblocked code
206: *
207:          CALL CUNM2L( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK,
208:      $                IINFO )
209:       ELSE
210: *
211: *        Use blocked code
212: *
213:          IF( ( LEFT .AND. NOTRAN ) .OR.
214:      $       ( .NOT.LEFT .AND. .NOT.NOTRAN ) ) THEN
215:             I1 = 1
216:             I2 = K
217:             I3 = NB
218:          ELSE
219:             I1 = ( ( K-1 ) / NB )*NB + 1
220:             I2 = 1
221:             I3 = -NB
222:          END IF
223: *
224:          IF( LEFT ) THEN
225:             NI = N
226:          ELSE
227:             MI = M
228:          END IF
229: *
230:          DO 10 I = I1, I2, I3
231:             IB = MIN( NB, K-I+1 )
232: *
233: *           Form the triangular factor of the block reflector
234: *           H = H(i+ib-1) . . . H(i+1) H(i)
235: *
236:             CALL CLARFT( 'Backward', 'Columnwise', NQ-K+I+IB-1, IB,
237:      $                   A( 1, I ), LDA, TAU( I ), T, LDT )
238:             IF( LEFT ) THEN
239: *
240: *              H or H' is applied to C(1:m-k+i+ib-1,1:n)
241: *
242:                MI = M - K + I + IB - 1
243:             ELSE
244: *
245: *              H or H' is applied to C(1:m,1:n-k+i+ib-1)
246: *
247:                NI = N - K + I + IB - 1
248:             END IF
249: *
250: *           Apply H or H'
251: *
252:             CALL CLARFB( SIDE, TRANS, 'Backward', 'Columnwise', MI, NI,
253:      $                   IB, A( 1, I ), LDA, T, LDT, C, LDC, WORK,
254:      $                   LDWORK )
255:    10    CONTINUE
256:       END IF
257:       WORK( 1 ) = LWKOPT
258:       RETURN
259: *
260: *     End of CUNMQL
261: *
262:       END
263: