001:       SUBROUTINE CLAUU2( UPLO, N, A, LDA, INFO )
002: *
003: *  -- LAPACK auxiliary routine (version 3.2) --
004: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
005: *     November 2006
006: *
007: *     .. Scalar Arguments ..
008:       CHARACTER          UPLO
009:       INTEGER            INFO, LDA, N
010: *     ..
011: *     .. Array Arguments ..
012:       COMPLEX            A( LDA, * )
013: *     ..
014: *
015: *  Purpose
016: *  =======
017: *
018: *  CLAUU2 computes the product U * U' or L' * L, where the triangular
019: *  factor U or L is stored in the upper or lower triangular part of
020: *  the array A.
021: *
022: *  If UPLO = 'U' or 'u' then the upper triangle of the result is stored,
023: *  overwriting the factor U in A.
024: *  If UPLO = 'L' or 'l' then the lower triangle of the result is stored,
025: *  overwriting the factor L in A.
026: *
027: *  This is the unblocked form of the algorithm, calling Level 2 BLAS.
028: *
029: *  Arguments
030: *  =========
031: *
032: *  UPLO    (input) CHARACTER*1
033: *          Specifies whether the triangular factor stored in the array A
034: *          is upper or lower triangular:
035: *          = 'U':  Upper triangular
036: *          = 'L':  Lower triangular
037: *
038: *  N       (input) INTEGER
039: *          The order of the triangular factor U or L.  N >= 0.
040: *
041: *  A       (input/output) COMPLEX array, dimension (LDA,N)
042: *          On entry, the triangular factor U or L.
043: *          On exit, if UPLO = 'U', the upper triangle of A is
044: *          overwritten with the upper triangle of the product U * U';
045: *          if UPLO = 'L', the lower triangle of A is overwritten with
046: *          the lower triangle of the product L' * L.
047: *
048: *  LDA     (input) INTEGER
049: *          The leading dimension of the array A.  LDA >= max(1,N).
050: *
051: *  INFO    (output) INTEGER
052: *          = 0: successful exit
053: *          < 0: if INFO = -k, the k-th argument had an illegal value
054: *
055: *  =====================================================================
056: *
057: *     .. Parameters ..
058:       COMPLEX            ONE
059:       PARAMETER          ( ONE = ( 1.0E+0, 0.0E+0 ) )
060: *     ..
061: *     .. Local Scalars ..
062:       LOGICAL            UPPER
063:       INTEGER            I
064:       REAL               AII
065: *     ..
066: *     .. External Functions ..
067:       LOGICAL            LSAME
068:       COMPLEX            CDOTC
069:       EXTERNAL           LSAME, CDOTC
070: *     ..
071: *     .. External Subroutines ..
072:       EXTERNAL           CGEMV, CLACGV, CSSCAL, XERBLA
073: *     ..
074: *     .. Intrinsic Functions ..
075:       INTRINSIC          CMPLX, MAX, REAL
076: *     ..
077: *     .. Executable Statements ..
078: *
079: *     Test the input parameters.
080: *
081:       INFO = 0
082:       UPPER = LSAME( UPLO, 'U' )
083:       IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
084:          INFO = -1
085:       ELSE IF( N.LT.0 ) THEN
086:          INFO = -2
087:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
088:          INFO = -4
089:       END IF
090:       IF( INFO.NE.0 ) THEN
091:          CALL XERBLA( 'CLAUU2', -INFO )
092:          RETURN
093:       END IF
094: *
095: *     Quick return if possible
096: *
097:       IF( N.EQ.0 )
098:      $   RETURN
099: *
100:       IF( UPPER ) THEN
101: *
102: *        Compute the product U * U'.
103: *
104:          DO 10 I = 1, N
105:             AII = A( I, I )
106:             IF( I.LT.N ) THEN
107:                A( I, I ) = AII*AII + REAL( CDOTC( N-I, A( I, I+1 ), LDA,
108:      $                     A( I, I+1 ), LDA ) )
109:                CALL CLACGV( N-I, A( I, I+1 ), LDA )
110:                CALL CGEMV( 'No transpose', I-1, N-I, ONE, A( 1, I+1 ),
111:      $                     LDA, A( I, I+1 ), LDA, CMPLX( AII ),
112:      $                     A( 1, I ), 1 )
113:                CALL CLACGV( N-I, A( I, I+1 ), LDA )
114:             ELSE
115:                CALL CSSCAL( I, AII, A( 1, I ), 1 )
116:             END IF
117:    10    CONTINUE
118: *
119:       ELSE
120: *
121: *        Compute the product L' * L.
122: *
123:          DO 20 I = 1, N
124:             AII = A( I, I )
125:             IF( I.LT.N ) THEN
126:                A( I, I ) = AII*AII + REAL( CDOTC( N-I, A( I+1, I ), 1,
127:      $                     A( I+1, I ), 1 ) )
128:                CALL CLACGV( I-1, A( I, 1 ), LDA )
129:                CALL CGEMV( 'Conjugate transpose', N-I, I-1, ONE,
130:      $                     A( I+1, 1 ), LDA, A( I+1, I ), 1,
131:      $                     CMPLX( AII ), A( I, 1 ), LDA )
132:                CALL CLACGV( I-1, A( I, 1 ), LDA )
133:             ELSE
134:                CALL CSSCAL( I, AII, A( I, 1 ), LDA )
135:             END IF
136:    20    CONTINUE
137:       END IF
138: *
139:       RETURN
140: *
141: *     End of CLAUU2
142: *
143:       END
144: