001:       SUBROUTINE CLATZM( SIDE, M, N, V, INCV, TAU, C1, C2, LDC, WORK )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
005: *     November 2006
006: *
007: *     .. Scalar Arguments ..
008:       CHARACTER          SIDE
009:       INTEGER            INCV, LDC, M, N
010:       COMPLEX            TAU
011: *     ..
012: *     .. Array Arguments ..
013:       COMPLEX            C1( LDC, * ), C2( LDC, * ), V( * ), WORK( * )
014: *     ..
015: *
016: *  Purpose
017: *  =======
018: *
019: *  This routine is deprecated and has been replaced by routine CUNMRZ.
020: *
021: *  CLATZM applies a Householder matrix generated by CTZRQF to a matrix.
022: *
023: *  Let P = I - tau*u*u',   u = ( 1 ),
024: *                              ( v )
025: *  where v is an (m-1) vector if SIDE = 'L', or a (n-1) vector if
026: *  SIDE = 'R'.
027: *
028: *  If SIDE equals 'L', let
029: *         C = [ C1 ] 1
030: *             [ C2 ] m-1
031: *               n
032: *  Then C is overwritten by P*C.
033: *
034: *  If SIDE equals 'R', let
035: *         C = [ C1, C2 ] m
036: *                1  n-1
037: *  Then C is overwritten by C*P.
038: *
039: *  Arguments
040: *  =========
041: *
042: *  SIDE    (input) CHARACTER*1
043: *          = 'L': form P * C
044: *          = 'R': form C * P
045: *
046: *  M       (input) INTEGER
047: *          The number of rows of the matrix C.
048: *
049: *  N       (input) INTEGER
050: *          The number of columns of the matrix C.
051: *
052: *  V       (input) COMPLEX array, dimension
053: *                  (1 + (M-1)*abs(INCV)) if SIDE = 'L'
054: *                  (1 + (N-1)*abs(INCV)) if SIDE = 'R'
055: *          The vector v in the representation of P. V is not used
056: *          if TAU = 0.
057: *
058: *  INCV    (input) INTEGER
059: *          The increment between elements of v. INCV <> 0
060: *
061: *  TAU     (input) COMPLEX
062: *          The value tau in the representation of P.
063: *
064: *  C1      (input/output) COMPLEX array, dimension
065: *                         (LDC,N) if SIDE = 'L'
066: *                         (M,1)   if SIDE = 'R'
067: *          On entry, the n-vector C1 if SIDE = 'L', or the m-vector C1
068: *          if SIDE = 'R'.
069: *
070: *          On exit, the first row of P*C if SIDE = 'L', or the first
071: *          column of C*P if SIDE = 'R'.
072: *
073: *  C2      (input/output) COMPLEX array, dimension
074: *                         (LDC, N)   if SIDE = 'L'
075: *                         (LDC, N-1) if SIDE = 'R'
076: *          On entry, the (m - 1) x n matrix C2 if SIDE = 'L', or the
077: *          m x (n - 1) matrix C2 if SIDE = 'R'.
078: *
079: *          On exit, rows 2:m of P*C if SIDE = 'L', or columns 2:m of C*P
080: *          if SIDE = 'R'.
081: *
082: *  LDC     (input) INTEGER
083: *          The leading dimension of the arrays C1 and C2.
084: *          LDC >= max(1,M).
085: *
086: *  WORK    (workspace) COMPLEX array, dimension
087: *                      (N) if SIDE = 'L'
088: *                      (M) if SIDE = 'R'
089: *
090: *  =====================================================================
091: *
092: *     .. Parameters ..
093:       COMPLEX            ONE, ZERO
094:       PARAMETER          ( ONE = ( 1.0E+0, 0.0E+0 ),
095:      $                   ZERO = ( 0.0E+0, 0.0E+0 ) )
096: *     ..
097: *     .. External Subroutines ..
098:       EXTERNAL           CAXPY, CCOPY, CGEMV, CGERC, CGERU, CLACGV
099: *     ..
100: *     .. External Functions ..
101:       LOGICAL            LSAME
102:       EXTERNAL           LSAME
103: *     ..
104: *     .. Intrinsic Functions ..
105:       INTRINSIC          MIN
106: *     ..
107: *     .. Executable Statements ..
108: *
109:       IF( ( MIN( M, N ).EQ.0 ) .OR. ( TAU.EQ.ZERO ) )
110:      $   RETURN
111: *
112:       IF( LSAME( SIDE, 'L' ) ) THEN
113: *
114: *        w :=  conjg( C1 + v' * C2 )
115: *
116:          CALL CCOPY( N, C1, LDC, WORK, 1 )
117:          CALL CLACGV( N, WORK, 1 )
118:          CALL CGEMV( 'Conjugate transpose', M-1, N, ONE, C2, LDC, V,
119:      $               INCV, ONE, WORK, 1 )
120: *
121: *        [ C1 ] := [ C1 ] - tau* [ 1 ] * w'
122: *        [ C2 ]    [ C2 ]        [ v ]
123: *
124:          CALL CLACGV( N, WORK, 1 )
125:          CALL CAXPY( N, -TAU, WORK, 1, C1, LDC )
126:          CALL CGERU( M-1, N, -TAU, V, INCV, WORK, 1, C2, LDC )
127: *
128:       ELSE IF( LSAME( SIDE, 'R' ) ) THEN
129: *
130: *        w := C1 + C2 * v
131: *
132:          CALL CCOPY( M, C1, 1, WORK, 1 )
133:          CALL CGEMV( 'No transpose', M, N-1, ONE, C2, LDC, V, INCV, ONE,
134:      $               WORK, 1 )
135: *
136: *        [ C1, C2 ] := [ C1, C2 ] - tau* w * [ 1 , v']
137: *
138:          CALL CAXPY( M, -TAU, WORK, 1, C1, 1 )
139:          CALL CGERC( M, N-1, -TAU, WORK, 1, V, INCV, C2, LDC )
140:       END IF
141: *
142:       RETURN
143: *
144: *     End of CLATZM
145: *
146:       END
147: