001:       SUBROUTINE CLARFT( DIRECT, STOREV, N, K, V, LDV, TAU, T, LDT )
002: *
003: *  -- LAPACK auxiliary routine (version 3.2) --
004: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
005: *     November 2006
006: *
007: *     .. Scalar Arguments ..
008:       CHARACTER          DIRECT, STOREV
009:       INTEGER            K, LDT, LDV, N
010: *     ..
011: *     .. Array Arguments ..
012:       COMPLEX            T( LDT, * ), TAU( * ), V( LDV, * )
013: *     ..
014: *
015: *  Purpose
016: *  =======
017: *
018: *  CLARFT forms the triangular factor T of a complex block reflector H
019: *  of order n, which is defined as a product of k elementary reflectors.
020: *
021: *  If DIRECT = 'F', H = H(1) H(2) . . . H(k) and T is upper triangular;
022: *
023: *  If DIRECT = 'B', H = H(k) . . . H(2) H(1) and T is lower triangular.
024: *
025: *  If STOREV = 'C', the vector which defines the elementary reflector
026: *  H(i) is stored in the i-th column of the array V, and
027: *
028: *     H  =  I - V * T * V'
029: *
030: *  If STOREV = 'R', the vector which defines the elementary reflector
031: *  H(i) is stored in the i-th row of the array V, and
032: *
033: *     H  =  I - V' * T * V
034: *
035: *  Arguments
036: *  =========
037: *
038: *  DIRECT  (input) CHARACTER*1
039: *          Specifies the order in which the elementary reflectors are
040: *          multiplied to form the block reflector:
041: *          = 'F': H = H(1) H(2) . . . H(k) (Forward)
042: *          = 'B': H = H(k) . . . H(2) H(1) (Backward)
043: *
044: *  STOREV  (input) CHARACTER*1
045: *          Specifies how the vectors which define the elementary
046: *          reflectors are stored (see also Further Details):
047: *          = 'C': columnwise
048: *          = 'R': rowwise
049: *
050: *  N       (input) INTEGER
051: *          The order of the block reflector H. N >= 0.
052: *
053: *  K       (input) INTEGER
054: *          The order of the triangular factor T (= the number of
055: *          elementary reflectors). K >= 1.
056: *
057: *  V       (input/output) COMPLEX array, dimension
058: *                               (LDV,K) if STOREV = 'C'
059: *                               (LDV,N) if STOREV = 'R'
060: *          The matrix V. See further details.
061: *
062: *  LDV     (input) INTEGER
063: *          The leading dimension of the array V.
064: *          If STOREV = 'C', LDV >= max(1,N); if STOREV = 'R', LDV >= K.
065: *
066: *  TAU     (input) COMPLEX array, dimension (K)
067: *          TAU(i) must contain the scalar factor of the elementary
068: *          reflector H(i).
069: *
070: *  T       (output) COMPLEX array, dimension (LDT,K)
071: *          The k by k triangular factor T of the block reflector.
072: *          If DIRECT = 'F', T is upper triangular; if DIRECT = 'B', T is
073: *          lower triangular. The rest of the array is not used.
074: *
075: *  LDT     (input) INTEGER
076: *          The leading dimension of the array T. LDT >= K.
077: *
078: *  Further Details
079: *  ===============
080: *
081: *  The shape of the matrix V and the storage of the vectors which define
082: *  the H(i) is best illustrated by the following example with n = 5 and
083: *  k = 3. The elements equal to 1 are not stored; the corresponding
084: *  array elements are modified but restored on exit. The rest of the
085: *  array is not used.
086: *
087: *  DIRECT = 'F' and STOREV = 'C':         DIRECT = 'F' and STOREV = 'R':
088: *
089: *               V = (  1       )                 V = (  1 v1 v1 v1 v1 )
090: *                   ( v1  1    )                     (     1 v2 v2 v2 )
091: *                   ( v1 v2  1 )                     (        1 v3 v3 )
092: *                   ( v1 v2 v3 )
093: *                   ( v1 v2 v3 )
094: *
095: *  DIRECT = 'B' and STOREV = 'C':         DIRECT = 'B' and STOREV = 'R':
096: *
097: *               V = ( v1 v2 v3 )                 V = ( v1 v1  1       )
098: *                   ( v1 v2 v3 )                     ( v2 v2 v2  1    )
099: *                   (  1 v2 v3 )                     ( v3 v3 v3 v3  1 )
100: *                   (     1 v3 )
101: *                   (        1 )
102: *
103: *  =====================================================================
104: *
105: *     .. Parameters ..
106:       COMPLEX            ONE, ZERO
107:       PARAMETER          ( ONE = ( 1.0E+0, 0.0E+0 ),
108:      $                   ZERO = ( 0.0E+0, 0.0E+0 ) )
109: *     ..
110: *     .. Local Scalars ..
111:       INTEGER            I, J, PREVLASTV, LASTV
112:       COMPLEX            VII
113: *     ..
114: *     .. External Subroutines ..
115:       EXTERNAL           CGEMV, CLACGV, CTRMV
116: *     ..
117: *     .. External Functions ..
118:       LOGICAL            LSAME
119:       EXTERNAL           LSAME
120: *     ..
121: *     .. Executable Statements ..
122: *
123: *     Quick return if possible
124: *
125:       IF( N.EQ.0 )
126:      $   RETURN
127: *
128:       IF( LSAME( DIRECT, 'F' ) ) THEN
129:          PREVLASTV = N
130:          DO 20 I = 1, K
131:             PREVLASTV = MAX( PREVLASTV, I )
132:             IF( TAU( I ).EQ.ZERO ) THEN
133: *
134: *              H(i)  =  I
135: *
136:                DO 10 J = 1, I
137:                   T( J, I ) = ZERO
138:    10          CONTINUE
139:             ELSE
140: *
141: *              general case
142: *
143:                VII = V( I, I )
144:                V( I, I ) = ONE
145:                IF( LSAME( STOREV, 'C' ) ) THEN
146: !                 Skip any trailing zeros.
147:                   DO LASTV = N, I+1, -1
148:                      IF( V( LASTV, I ).NE.ZERO ) EXIT
149:                   END DO
150:                   J = MIN( LASTV, PREVLASTV )
151: *
152: *                 T(1:i-1,i) := - tau(i) * V(i:j,1:i-1)' * V(i:j,i)
153: *
154:                   CALL CGEMV( 'Conjugate transpose', J-I+1, I-1,
155:      $                        -TAU( I ), V( I, 1 ), LDV, V( I, I ), 1,
156:      $                        ZERO, T( 1, I ), 1 )
157:                ELSE
158: !                 Skip any trailing zeros.
159:                   DO LASTV = N, I+1, -1
160:                      IF( V( I, LASTV ).NE.ZERO ) EXIT
161:                   END DO
162:                   J = MIN( LASTV, PREVLASTV )
163: *
164: *                 T(1:i-1,i) := - tau(i) * V(1:i-1,i:j) * V(i,i:j)'
165: *
166:                   IF( I.LT.J )
167:      $               CALL CLACGV( J-I, V( I, I+1 ), LDV )
168:                   CALL CGEMV( 'No transpose', I-1, J-I+1, -TAU( I ),
169:      $                        V( 1, I ), LDV, V( I, I ), LDV, ZERO,
170:      $                        T( 1, I ), 1 )
171:                   IF( I.LT.J )
172:      $               CALL CLACGV( J-I, V( I, I+1 ), LDV )
173:                END IF
174:                V( I, I ) = VII
175: *
176: *              T(1:i-1,i) := T(1:i-1,1:i-1) * T(1:i-1,i)
177: *
178:                CALL CTRMV( 'Upper', 'No transpose', 'Non-unit', I-1, T,
179:      $                     LDT, T( 1, I ), 1 )
180:                T( I, I ) = TAU( I )
181:                IF( I.GT.1 ) THEN
182:                   PREVLASTV = MAX( PREVLASTV, LASTV )
183:                ELSE
184:                   PREVLASTV = LASTV
185:                END IF
186:             END IF
187:    20    CONTINUE
188:       ELSE
189:          PREVLASTV = 1
190:          DO 40 I = K, 1, -1
191:             IF( TAU( I ).EQ.ZERO ) THEN
192: *
193: *              H(i)  =  I
194: *
195:                DO 30 J = I, K
196:                   T( J, I ) = ZERO
197:    30          CONTINUE
198:             ELSE
199: *
200: *              general case
201: *
202:                IF( I.LT.K ) THEN
203:                   IF( LSAME( STOREV, 'C' ) ) THEN
204:                      VII = V( N-K+I, I )
205:                      V( N-K+I, I ) = ONE
206: !                    Skip any leading zeros.
207:                      DO LASTV = 1, I-1
208:                         IF( V( LASTV, I ).NE.ZERO ) EXIT
209:                      END DO
210:                      J = MAX( LASTV, PREVLASTV )
211: *
212: *                    T(i+1:k,i) :=
213: *                            - tau(i) * V(j:n-k+i,i+1:k)' * V(j:n-k+i,i)
214: *
215:                      CALL CGEMV( 'Conjugate transpose', N-K+I-J+1, K-I,
216:      $                           -TAU( I ), V( J, I+1 ), LDV, V( J, I ),
217:      $                           1, ZERO, T( I+1, I ), 1 )
218:                      V( N-K+I, I ) = VII
219:                   ELSE
220:                      VII = V( I, N-K+I )
221:                      V( I, N-K+I ) = ONE
222: !                    Skip any leading zeros.
223:                      DO LASTV = 1, I-1
224:                         IF( V( I, LASTV ).NE.ZERO ) EXIT
225:                      END DO
226:                      J = MAX( LASTV, PREVLASTV )
227: *
228: *                    T(i+1:k,i) :=
229: *                            - tau(i) * V(i+1:k,j:n-k+i) * V(i,j:n-k+i)'
230: *
231:                      CALL CLACGV( N-K+I-1-J+1, V( I, J ), LDV )
232:                      CALL CGEMV( 'No transpose', K-I, N-K+I-J+1,
233:      $                    -TAU( I ), V( I+1, J ), LDV, V( I, J ), LDV,
234:      $                    ZERO, T( I+1, I ), 1 )
235:                      CALL CLACGV( N-K+I-1-J+1, V( I, J ), LDV )
236:                      V( I, N-K+I ) = VII
237:                   END IF
238: *
239: *                 T(i+1:k,i) := T(i+1:k,i+1:k) * T(i+1:k,i)
240: *
241:                   CALL CTRMV( 'Lower', 'No transpose', 'Non-unit', K-I,
242:      $                        T( I+1, I+1 ), LDT, T( I+1, I ), 1 )
243:                   IF( I.GT.1 ) THEN
244:                      PREVLASTV = MIN( PREVLASTV, LASTV )
245:                   ELSE
246:                      PREVLASTV = LASTV
247:                   END IF
248:                END IF
249:                T( I, I ) = TAU( I )
250:             END IF
251:    40    CONTINUE
252:       END IF
253:       RETURN
254: *
255: *     End of CLARFT
256: *
257:       END
258: