001:       SUBROUTINE CLAGS2( UPPER, A1, A2, A3, B1, B2, B3, CSU, SNU, CSV,
002:      $                   SNV, CSQ, SNQ )
003: *
004: *  -- LAPACK auxiliary routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       LOGICAL            UPPER
010:       REAL               A1, A3, B1, B3, CSQ, CSU, CSV
011:       COMPLEX            A2, B2, SNQ, SNU, SNV
012: *     ..
013: *
014: *  Purpose
015: *  =======
016: *
017: *  CLAGS2 computes 2-by-2 unitary matrices U, V and Q, such
018: *  that if ( UPPER ) then
019: *
020: *            U'*A*Q = U'*( A1 A2 )*Q = ( x  0  )
021: *                        ( 0  A3 )     ( x  x  )
022: *  and
023: *            V'*B*Q = V'*( B1 B2 )*Q = ( x  0  )
024: *                        ( 0  B3 )     ( x  x  )
025: *
026: *  or if ( .NOT.UPPER ) then
027: *
028: *            U'*A*Q = U'*( A1 0  )*Q = ( x  x  )
029: *                        ( A2 A3 )     ( 0  x  )
030: *  and
031: *            V'*B*Q = V'*( B1 0  )*Q = ( x  x  )
032: *                        ( B2 B3 )     ( 0  x  )
033: *  where
034: *
035: *    U = (     CSU      SNU ), V = (     CSV     SNV ),
036: *        ( -CONJG(SNU)  CSU )      ( -CONJG(SNV) CSV )
037: *
038: *    Q = (     CSQ      SNQ )
039: *        ( -CONJG(SNQ)  CSQ )
040: *
041: *  Z' denotes the conjugate transpose of Z.
042: *
043: *  The rows of the transformed A and B are parallel. Moreover, if the
044: *  input 2-by-2 matrix A is not zero, then the transformed (1,1) entry
045: *  of A is not zero. If the input matrices A and B are both not zero,
046: *  then the transformed (2,2) element of B is not zero, except when the
047: *  first rows of input A and B are parallel and the second rows are
048: *  zero.
049: *
050: *  Arguments
051: *  =========
052: *
053: *  UPPER   (input) LOGICAL
054: *          = .TRUE.: the input matrices A and B are upper triangular.
055: *          = .FALSE.: the input matrices A and B are lower triangular.
056: *
057: *  A1      (input) REAL
058: *  A2      (input) COMPLEX
059: *  A3      (input) REAL
060: *          On entry, A1, A2 and A3 are elements of the input 2-by-2
061: *          upper (lower) triangular matrix A.
062: *
063: *  B1      (input) REAL
064: *  B2      (input) COMPLEX
065: *  B3      (input) REAL
066: *          On entry, B1, B2 and B3 are elements of the input 2-by-2
067: *          upper (lower) triangular matrix B.
068: *
069: *  CSU     (output) REAL
070: *  SNU     (output) COMPLEX
071: *          The desired unitary matrix U.
072: *
073: *  CSV     (output) REAL
074: *  SNV     (output) COMPLEX
075: *          The desired unitary matrix V.
076: *
077: *  CSQ     (output) REAL
078: *  SNQ     (output) COMPLEX
079: *          The desired unitary matrix Q.
080: *
081: *  =====================================================================
082: *
083: *     .. Parameters ..
084:       REAL               ZERO, ONE
085:       PARAMETER          ( ZERO = 0.0E+0, ONE = 1.0E+0 )
086: *     ..
087: *     .. Local Scalars ..
088:       REAL               A, AUA11, AUA12, AUA21, AUA22, AVB11, AVB12,
089:      $                   AVB21, AVB22, CSL, CSR, D, FB, FC, S1, S2, SNL,
090:      $                   SNR, UA11R, UA22R, VB11R, VB22R
091:       COMPLEX            B, C, D1, R, T, UA11, UA12, UA21, UA22, VB11,
092:      $                   VB12, VB21, VB22
093: *     ..
094: *     .. External Subroutines ..
095:       EXTERNAL           CLARTG, SLASV2
096: *     ..
097: *     .. Intrinsic Functions ..
098:       INTRINSIC          ABS, AIMAG, CMPLX, CONJG, REAL
099: *     ..
100: *     .. Statement Functions ..
101:       REAL               ABS1
102: *     ..
103: *     .. Statement Function definitions ..
104:       ABS1( T ) = ABS( REAL( T ) ) + ABS( AIMAG( T ) )
105: *     ..
106: *     .. Executable Statements ..
107: *
108:       IF( UPPER ) THEN
109: *
110: *        Input matrices A and B are upper triangular matrices
111: *
112: *        Form matrix C = A*adj(B) = ( a b )
113: *                                   ( 0 d )
114: *
115:          A = A1*B3
116:          D = A3*B1
117:          B = A2*B1 - A1*B2
118:          FB = ABS( B )
119: *
120: *        Transform complex 2-by-2 matrix C to real matrix by unitary
121: *        diagonal matrix diag(1,D1).
122: *
123:          D1 = ONE
124:          IF( FB.NE.ZERO )
125:      $      D1 = B / FB
126: *
127: *        The SVD of real 2 by 2 triangular C
128: *
129: *         ( CSL -SNL )*( A B )*(  CSR  SNR ) = ( R 0 )
130: *         ( SNL  CSL ) ( 0 D ) ( -SNR  CSR )   ( 0 T )
131: *
132:          CALL SLASV2( A, FB, D, S1, S2, SNR, CSR, SNL, CSL )
133: *
134:          IF( ABS( CSL ).GE.ABS( SNL ) .OR. ABS( CSR ).GE.ABS( SNR ) )
135:      $        THEN
136: *
137: *           Compute the (1,1) and (1,2) elements of U'*A and V'*B,
138: *           and (1,2) element of |U|'*|A| and |V|'*|B|.
139: *
140:             UA11R = CSL*A1
141:             UA12 = CSL*A2 + D1*SNL*A3
142: *
143:             VB11R = CSR*B1
144:             VB12 = CSR*B2 + D1*SNR*B3
145: *
146:             AUA12 = ABS( CSL )*ABS1( A2 ) + ABS( SNL )*ABS( A3 )
147:             AVB12 = ABS( CSR )*ABS1( B2 ) + ABS( SNR )*ABS( B3 )
148: *
149: *           zero (1,2) elements of U'*A and V'*B
150: *
151:             IF( ( ABS( UA11R )+ABS1( UA12 ) ).EQ.ZERO ) THEN
152:                CALL CLARTG( -CMPLX( VB11R ), CONJG( VB12 ), CSQ, SNQ,
153:      $                      R )
154:             ELSE IF( ( ABS( VB11R )+ABS1( VB12 ) ).EQ.ZERO ) THEN
155:                CALL CLARTG( -CMPLX( UA11R ), CONJG( UA12 ), CSQ, SNQ,
156:      $                      R )
157:             ELSE IF( AUA12 / ( ABS( UA11R )+ABS1( UA12 ) ).LE.AVB12 /
158:      $               ( ABS( VB11R )+ABS1( VB12 ) ) ) THEN
159:                CALL CLARTG( -CMPLX( UA11R ), CONJG( UA12 ), CSQ, SNQ,
160:      $                      R )
161:             ELSE
162:                CALL CLARTG( -CMPLX( VB11R ), CONJG( VB12 ), CSQ, SNQ,
163:      $                      R )
164:             END IF
165: *
166:             CSU = CSL
167:             SNU = -D1*SNL
168:             CSV = CSR
169:             SNV = -D1*SNR
170: *
171:          ELSE
172: *
173: *           Compute the (2,1) and (2,2) elements of U'*A and V'*B,
174: *           and (2,2) element of |U|'*|A| and |V|'*|B|.
175: *
176:             UA21 = -CONJG( D1 )*SNL*A1
177:             UA22 = -CONJG( D1 )*SNL*A2 + CSL*A3
178: *
179:             VB21 = -CONJG( D1 )*SNR*B1
180:             VB22 = -CONJG( D1 )*SNR*B2 + CSR*B3
181: *
182:             AUA22 = ABS( SNL )*ABS1( A2 ) + ABS( CSL )*ABS( A3 )
183:             AVB22 = ABS( SNR )*ABS1( B2 ) + ABS( CSR )*ABS( B3 )
184: *
185: *           zero (2,2) elements of U'*A and V'*B, and then swap.
186: *
187:             IF( ( ABS1( UA21 )+ABS1( UA22 ) ).EQ.ZERO ) THEN
188:                CALL CLARTG( -CONJG( VB21 ), CONJG( VB22 ), CSQ, SNQ, R )
189:             ELSE IF( ( ABS1( VB21 )+ABS( VB22 ) ).EQ.ZERO ) THEN
190:                CALL CLARTG( -CONJG( UA21 ), CONJG( UA22 ), CSQ, SNQ, R )
191:             ELSE IF( AUA22 / ( ABS1( UA21 )+ABS1( UA22 ) ).LE.AVB22 /
192:      $               ( ABS1( VB21 )+ABS1( VB22 ) ) ) THEN
193:                CALL CLARTG( -CONJG( UA21 ), CONJG( UA22 ), CSQ, SNQ, R )
194:             ELSE
195:                CALL CLARTG( -CONJG( VB21 ), CONJG( VB22 ), CSQ, SNQ, R )
196:             END IF
197: *
198:             CSU = SNL
199:             SNU = D1*CSL
200:             CSV = SNR
201:             SNV = D1*CSR
202: *
203:          END IF
204: *
205:       ELSE
206: *
207: *        Input matrices A and B are lower triangular matrices
208: *
209: *        Form matrix C = A*adj(B) = ( a 0 )
210: *                                   ( c d )
211: *
212:          A = A1*B3
213:          D = A3*B1
214:          C = A2*B3 - A3*B2
215:          FC = ABS( C )
216: *
217: *        Transform complex 2-by-2 matrix C to real matrix by unitary
218: *        diagonal matrix diag(d1,1).
219: *
220:          D1 = ONE
221:          IF( FC.NE.ZERO )
222:      $      D1 = C / FC
223: *
224: *        The SVD of real 2 by 2 triangular C
225: *
226: *         ( CSL -SNL )*( A 0 )*(  CSR  SNR ) = ( R 0 )
227: *         ( SNL  CSL ) ( C D ) ( -SNR  CSR )   ( 0 T )
228: *
229:          CALL SLASV2( A, FC, D, S1, S2, SNR, CSR, SNL, CSL )
230: *
231:          IF( ABS( CSR ).GE.ABS( SNR ) .OR. ABS( CSL ).GE.ABS( SNL ) )
232:      $        THEN
233: *
234: *           Compute the (2,1) and (2,2) elements of U'*A and V'*B,
235: *           and (2,1) element of |U|'*|A| and |V|'*|B|.
236: *
237:             UA21 = -D1*SNR*A1 + CSR*A2
238:             UA22R = CSR*A3
239: *
240:             VB21 = -D1*SNL*B1 + CSL*B2
241:             VB22R = CSL*B3
242: *
243:             AUA21 = ABS( SNR )*ABS( A1 ) + ABS( CSR )*ABS1( A2 )
244:             AVB21 = ABS( SNL )*ABS( B1 ) + ABS( CSL )*ABS1( B2 )
245: *
246: *           zero (2,1) elements of U'*A and V'*B.
247: *
248:             IF( ( ABS1( UA21 )+ABS( UA22R ) ).EQ.ZERO ) THEN
249:                CALL CLARTG( CMPLX( VB22R ), VB21, CSQ, SNQ, R )
250:             ELSE IF( ( ABS1( VB21 )+ABS( VB22R ) ).EQ.ZERO ) THEN
251:                CALL CLARTG( CMPLX( UA22R ), UA21, CSQ, SNQ, R )
252:             ELSE IF( AUA21 / ( ABS1( UA21 )+ABS( UA22R ) ).LE.AVB21 /
253:      $               ( ABS1( VB21 )+ABS( VB22R ) ) ) THEN
254:                CALL CLARTG( CMPLX( UA22R ), UA21, CSQ, SNQ, R )
255:             ELSE
256:                CALL CLARTG( CMPLX( VB22R ), VB21, CSQ, SNQ, R )
257:             END IF
258: *
259:             CSU = CSR
260:             SNU = -CONJG( D1 )*SNR
261:             CSV = CSL
262:             SNV = -CONJG( D1 )*SNL
263: *
264:          ELSE
265: *
266: *           Compute the (1,1) and (1,2) elements of U'*A and V'*B,
267: *           and (1,1) element of |U|'*|A| and |V|'*|B|.
268: *
269:             UA11 = CSR*A1 + CONJG( D1 )*SNR*A2
270:             UA12 = CONJG( D1 )*SNR*A3
271: *
272:             VB11 = CSL*B1 + CONJG( D1 )*SNL*B2
273:             VB12 = CONJG( D1 )*SNL*B3
274: *
275:             AUA11 = ABS( CSR )*ABS( A1 ) + ABS( SNR )*ABS1( A2 )
276:             AVB11 = ABS( CSL )*ABS( B1 ) + ABS( SNL )*ABS1( B2 )
277: *
278: *           zero (1,1) elements of U'*A and V'*B, and then swap.
279: *
280:             IF( ( ABS1( UA11 )+ABS1( UA12 ) ).EQ.ZERO ) THEN
281:                CALL CLARTG( VB12, VB11, CSQ, SNQ, R )
282:             ELSE IF( ( ABS1( VB11 )+ABS1( VB12 ) ).EQ.ZERO ) THEN
283:                CALL CLARTG( UA12, UA11, CSQ, SNQ, R )
284:             ELSE IF( AUA11 / ( ABS1( UA11 )+ABS1( UA12 ) ).LE.AVB11 /
285:      $               ( ABS1( VB11 )+ABS1( VB12 ) ) ) THEN
286:                CALL CLARTG( UA12, UA11, CSQ, SNQ, R )
287:             ELSE
288:                CALL CLARTG( VB12, VB11, CSQ, SNQ, R )
289:             END IF
290: *
291:             CSU = SNR
292:             SNU = CONJG( D1 )*CSR
293:             CSV = SNL
294:             SNV = CONJG( D1 )*CSL
295: *
296:          END IF
297: *
298:       END IF
299: *
300:       RETURN
301: *
302: *     End of CLAGS2
303: *
304:       END
305: