001:       REAL FUNCTION CLA_SYRCOND_C( UPLO, N, A, LDA, AF, LDAF, IPIV, C,
002:      $                             CAPPLY, INFO, WORK, RWORK )
003: *
004: *     -- LAPACK routine (version 3.2)                                 --
005: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
006: *     -- Jason Riedy of Univ. of California Berkeley.                 --
007: *     -- November 2008                                                --
008: *
009: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
010: *     -- Univ. of California Berkeley and NAG Ltd.                    --
011: *
012:       IMPLICIT NONE
013: *     ..
014: *     .. Scalar Arguments ..
015:       CHARACTER          UPLO
016:       LOGICAL            CAPPLY
017:       INTEGER            N, LDA, LDAF, INFO
018: *     ..
019: *     .. Array Arguments ..
020:       INTEGER            IPIV( * )
021:       COMPLEX            A( LDA, * ), AF( LDAF, * ), WORK( * )
022:       REAL               C( * ), RWORK( * )
023: *
024: *     CLA_SYRCOND_C Computes the infinity norm condition number of
025: *     op(A) * inv(diag(C)) where C is a REAL vector.
026: *     WORK is a COMPLEX workspace of size 2*N, and
027: *     RWORK is a REAL workspace of size 3*N.
028: *     ..
029: *     .. Local Scalars ..
030:       INTEGER            KASE
031:       REAL               AINVNM, ANORM, TMP
032:       INTEGER            I, J
033:       LOGICAL            UP
034:       COMPLEX            ZDUM
035: *     ..
036: *     .. Local Arrays ..
037:       INTEGER            ISAVE( 3 )
038: *     ..
039: *     .. External Functions ..
040:       LOGICAL            LSAME
041:       EXTERNAL           LSAME
042: *     ..
043: *     .. External Subroutines ..
044:       EXTERNAL           CLACN2, CSYTRS, XERBLA
045: *     ..
046: *     .. Intrinsic Functions ..
047:       INTRINSIC          ABS, MAX
048: *     ..
049: *     .. Statement Functions ..
050:       REAL CABS1
051: *     ..
052: *     .. Statement Function Definitions ..
053:       CABS1( ZDUM ) = ABS( REAL( ZDUM ) ) + ABS( AIMAG( ZDUM ) )
054: *     ..
055: *     .. Executable Statements ..
056: *
057:       CLA_SYRCOND_C = 0.0E+0
058: *
059:       INFO = 0
060:       IF( N.LT.0 ) THEN
061:          INFO = -2
062:       END IF
063:       IF( INFO.NE.0 ) THEN
064:          CALL XERBLA( 'CLA_SYRCOND_C', -INFO )
065:          RETURN
066:       END IF
067:       UP = .FALSE.
068:       IF ( LSAME( UPLO, 'U' ) ) UP = .TRUE.
069: *
070: *     Compute norm of op(A)*op2(C).
071: *
072:       ANORM = 0.0E+0
073:       IF ( UP ) THEN
074:          DO I = 1, N
075:             TMP = 0.0E+0
076:             IF ( CAPPLY ) THEN
077:                DO J = 1, N
078:                   IF (I.GT.J) THEN
079:                      TMP = TMP + CABS1( A( J, I ) ) / C( J )
080:                   ELSE
081:                      TMP = TMP + CABS1( A( I, J ) ) / C( J )
082:                   END IF
083:                END DO
084:             ELSE
085:                DO J = 1, N
086:                   IF ( I.GT.J ) THEN
087:                      TMP = TMP + CABS1( A( J, I ) )
088:                   ELSE
089:                      TMP = TMP + CABS1( A( I, J ) )
090:                   END IF
091:                END DO
092:             END IF
093:             RWORK( 2*N+I ) = TMP
094:             ANORM = MAX( ANORM, TMP )
095:          END DO
096:       ELSE
097:          DO I = 1, N
098:             TMP = 0.0E+0
099:             IF ( CAPPLY ) THEN
100:                DO J = 1, N
101:                   IF ( I.LT.J ) THEN
102:                      TMP = TMP + CABS1( A( J, I ) ) / C( J )
103:                   ELSE
104:                      TMP = TMP + CABS1( A( I, J ) ) / C( J )
105:                   END IF
106:                END DO
107:             ELSE
108:                DO J = 1, N
109:                   IF ( I.LT.J ) THEN
110:                      TMP = TMP + CABS1( A( J, I ) )
111:                   ELSE
112:                      TMP = TMP + CABS1( A( I, J ) )
113:                   END IF
114:                END DO
115:             END IF
116:             RWORK( 2*N+I ) = TMP
117:             ANORM = MAX( ANORM, TMP )
118:          END DO
119:       END IF
120: *
121: *     Quick return if possible.
122: *
123:       IF( N.EQ.0 ) THEN
124:          CLA_SYRCOND_C = 1.0E+0
125:          RETURN
126:       ELSE IF( ANORM .EQ. 0.0E+0 ) THEN
127:          RETURN
128:       END IF
129: *
130: *     Estimate the norm of inv(op(A)).
131: *
132:       AINVNM = 0.0E+0
133: *
134:       KASE = 0
135:    10 CONTINUE
136:       CALL CLACN2( N, WORK( N+1 ), WORK, AINVNM, KASE, ISAVE )
137:       IF( KASE.NE.0 ) THEN
138:          IF( KASE.EQ.2 ) THEN
139: *
140: *           Multiply by R.
141: *
142:             DO I = 1, N
143:                WORK( I ) = WORK( I ) * RWORK( 2*N+I )
144:             END DO
145: *
146:             IF ( UP ) THEN
147:                CALL CSYTRS( 'U', N, 1, AF, LDAF, IPIV,
148:      $            WORK, N, INFO )
149:             ELSE
150:                CALL CSYTRS( 'L', N, 1, AF, LDAF, IPIV,
151:      $            WORK, N, INFO )
152:             ENDIF
153: *
154: *           Multiply by inv(C).
155: *
156:             IF ( CAPPLY ) THEN
157:                DO I = 1, N
158:                   WORK( I ) = WORK( I ) * C( I )
159:                END DO
160:             END IF
161:          ELSE
162: *
163: *           Multiply by inv(C').
164: *
165:             IF ( CAPPLY ) THEN
166:                DO I = 1, N
167:                   WORK( I ) = WORK( I ) * C( I )
168:                END DO
169:             END IF
170: *
171:             IF ( UP ) THEN
172:                CALL CSYTRS( 'U', N, 1, AF, LDAF, IPIV,
173:      $            WORK, N, INFO )
174:             ELSE
175:                CALL CSYTRS( 'L', N, 1, AF, LDAF, IPIV,
176:      $            WORK, N, INFO )
177:             END IF
178: *
179: *           Multiply by R.
180: *
181:             DO I = 1, N
182:                WORK( I ) = WORK( I ) * RWORK( 2*N+I )
183:             END DO
184:          END IF
185:          GO TO 10
186:       END IF
187: *
188: *     Compute the estimate of the reciprocal condition number.
189: *
190:       IF( AINVNM .NE. 0.0E+0 )
191:      $   CLA_SYRCOND_C = 1.0E+0 / AINVNM
192: *
193:       RETURN
194: *
195:       END
196: