001:       SUBROUTINE CLA_HERFSX_EXTENDED( PREC_TYPE, UPLO, N, NRHS, A, LDA,
002:      $                                AF, LDAF, IPIV, COLEQU, C, B, LDB,
003:      $                                Y, LDY, BERR_OUT, N_NORMS, ERRS_N,
004:      $                                ERRS_C, RES, AYB, DY, Y_TAIL,
005:      $                                RCOND, ITHRESH, RTHRESH, DZ_UB,
006:      $                                IGNORE_CWISE, INFO )
007: *
008: *     -- LAPACK routine (version 3.2)                                 --
009: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
010: *     -- Jason Riedy of Univ. of California Berkeley.                 --
011: *     -- November 2008                                                --
012: *
013: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
014: *     -- Univ. of California Berkeley and NAG Ltd.                    --
015: *
016:       IMPLICIT NONE
017: *     ..
018: *     .. Scalar Arguments ..
019:       INTEGER            INFO, LDA, LDAF, LDB, LDY, N, NRHS, PREC_TYPE,
020:      $                   N_NORMS, ITHRESH
021:       CHARACTER          UPLO
022:       LOGICAL            COLEQU, IGNORE_CWISE
023:       REAL               RTHRESH, DZ_UB
024: *     ..
025: *     .. Array Arguments ..
026:       INTEGER            IPIV( * )
027:       COMPLEX            A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
028:      $                   Y( LDY, * ), RES( * ), DY( * ), Y_TAIL( * )
029:       REAL               C( * ), AYB( * ), RCOND, BERR_OUT( * ),
030:      $                   ERRS_N( NRHS, * ), ERRS_C( NRHS, * )
031: *     ..
032: *     .. Local Scalars ..
033:       INTEGER            UPLO2, CNT, I, J, X_STATE, Z_STATE,
034:      $                   Y_PREC_STATE
035:       REAL               YK, DYK, YMIN, NORMY, NORMX, NORMDX, DXRAT,
036:      $                   DZRAT, PREVNORMDX, PREV_DZ_Z, DXRATMAX,
037:      $                   DZRATMAX, DX_X, DZ_Z, FINAL_DX_X, FINAL_DZ_Z,
038:      $                   EPS, HUGEVAL, INCR_THRESH
039:       LOGICAL            INCR_PREC
040:       COMPLEX            ZDUM
041: *     ..
042: *     .. Parameters ..
043:       INTEGER            UNSTABLE_STATE, WORKING_STATE, CONV_STATE,
044:      $                   NOPROG_STATE, BASE_RESIDUAL, EXTRA_RESIDUAL,
045:      $                   EXTRA_Y
046:       PARAMETER          ( UNSTABLE_STATE = 0, WORKING_STATE = 1,
047:      $                   CONV_STATE = 2, NOPROG_STATE = 3 )
048:       PARAMETER          ( BASE_RESIDUAL = 0, EXTRA_RESIDUAL = 1,
049:      $                   EXTRA_Y = 2 )
050:       INTEGER            FINAL_NRM_ERR_I, FINAL_CMP_ERR_I, BERR_I
051:       INTEGER            RCOND_I, NRM_RCOND_I, NRM_ERR_I, CMP_RCOND_I
052:       INTEGER            CMP_ERR_I, PIV_GROWTH_I
053:       PARAMETER          ( FINAL_NRM_ERR_I = 1, FINAL_CMP_ERR_I = 2,
054:      $                   BERR_I = 3 )
055:       PARAMETER          ( RCOND_I = 4, NRM_RCOND_I = 5, NRM_ERR_I = 6 )
056:       PARAMETER          ( CMP_RCOND_I = 7, CMP_ERR_I = 8,
057:      $                   PIV_GROWTH_I = 9 )
058:       INTEGER            LA_LINRX_ITREF_I, LA_LINRX_ITHRESH_I,
059:      $                   LA_LINRX_CWISE_I
060:       PARAMETER          ( LA_LINRX_ITREF_I = 1,
061:      $                   LA_LINRX_ITHRESH_I = 2 )
062:       PARAMETER          ( LA_LINRX_CWISE_I = 3 )
063:       INTEGER            LA_LINRX_TRUST_I, LA_LINRX_ERR_I,
064:      $                   LA_LINRX_RCOND_I
065:       PARAMETER          ( LA_LINRX_TRUST_I = 1, LA_LINRX_ERR_I = 2 )
066:       PARAMETER          ( LA_LINRX_RCOND_I = 3 )
067:       INTEGER            LA_LINRX_MAX_N_ERRS
068:       PARAMETER          ( LA_LINRX_MAX_N_ERRS = 3 )      
069: *     ..
070: *     .. External Functions ..
071:       LOGICAL            LSAME
072:       EXTERNAL           ILAUPLO
073:       INTEGER            ILAUPLO
074: *     ..
075: *     .. External Subroutines ..
076:       EXTERNAL           CAXPY, CCOPY, CHETRS, CHEMV, BLAS_CHEMV_X,
077:      $                   BLAS_CHEMV2_X, CLA_HEAMV, CLA_WWADDW,
078:      $                   CLA_LIN_BERR
079:       REAL               SLAMCH
080: *     ..
081: *     .. Intrinsic Functions ..
082:       INTRINSIC          ABS, REAL, AIMAG, MAX, MIN
083: *     ..
084: *     .. Statement Functions ..
085:       REAL               CABS1
086: *     ..
087: *     .. Statement Function Definitions ..
088:       CABS1( ZDUM ) = ABS( REAL( ZDUM ) ) + ABS( AIMAG( ZDUM ) )
089: *     ..
090: *     .. Executable Statements ..
091: *
092:       IF (INFO.NE.0) RETURN
093:       EPS = SLAMCH( 'Epsilon' )
094:       HUGEVAL = SLAMCH( 'Overflow' )
095: *     Force HUGEVAL to Inf
096:       HUGEVAL = HUGEVAL * HUGEVAL
097: *     Using HUGEVAL may lead to spurious underflows.
098:       INCR_THRESH = REAL( N ) * EPS
099: 
100:       IF ( LSAME ( UPLO, 'L' ) ) THEN
101:          UPLO2 = ILAUPLO( 'L' )
102:       ELSE
103:          UPLO2 = ILAUPLO( 'U' )
104:       ENDIF
105: 
106:       DO J = 1, NRHS
107:          Y_PREC_STATE = EXTRA_RESIDUAL
108:          IF ( Y_PREC_STATE .EQ. EXTRA_Y ) THEN
109:             DO I = 1, N
110:                Y_TAIL( I ) = 0.0
111:             END DO
112:          END IF
113: 
114:          DXRAT = 0.0
115:          DXRATMAX = 0.0
116:          DZRAT = 0.0
117:          DZRATMAX = 0.0
118:          FINAL_DX_X = HUGEVAL
119:          FINAL_DZ_Z = HUGEVAL
120:          PREVNORMDX = HUGEVAL
121:          PREV_DZ_Z = HUGEVAL
122:          DZ_Z = HUGEVAL
123:          DX_X = HUGEVAL
124: 
125:          X_STATE = WORKING_STATE
126:          Z_STATE = UNSTABLE_STATE
127:          INCR_PREC = .FALSE.
128: 
129:          DO CNT = 1, ITHRESH
130: *
131: *         Compute residual RES = B_s - op(A_s) * Y,
132: *             op(A) = A, A**T, or A**H depending on TRANS (and type).
133: *
134:             CALL CCOPY( N, B( 1, J ), 1, RES, 1 )
135:             IF ( Y_PREC_STATE .EQ. BASE_RESIDUAL ) THEN
136:                CALL CHEMV( UPLO, N, CMPLX(-1.0), A, LDA, Y( 1, J ), 1,
137:      $              CMPLX(1.0), RES, 1 )
138:             ELSE IF ( Y_PREC_STATE .EQ. EXTRA_RESIDUAL ) THEN
139:                CALL BLAS_CHEMV_X( UPLO2, N, CMPLX(-1.0), A, LDA,
140:      $              Y( 1, J ), 1, CMPLX(1.0), RES, 1, PREC_TYPE)
141:             ELSE
142:                CALL BLAS_CHEMV2_X(UPLO2, N, CMPLX(-1.0), A, LDA,
143:      $              Y(1, J), Y_TAIL, 1, CMPLX(1.0), RES, 1, PREC_TYPE)
144:             END IF
145: 
146: !         XXX: RES is no longer needed.
147:             CALL CCOPY( N, RES, 1, DY, 1 )
148:             CALL CHETRS( UPLO, N, NRHS, AF, LDAF, IPIV, DY, N, INFO )
149: *
150: *         Calculate relative changes DX_X, DZ_Z and ratios DXRAT, DZRAT.
151: *
152:             NORMX = 0.0
153:             NORMY = 0.0
154:             NORMDX = 0.0
155:             DZ_Z = 0.0
156:             YMIN = HUGEVAL
157: 
158:             DO I = 1, N
159:                YK = CABS1( Y( I, J ) )
160:                DYK = CABS1( DY( I ) )
161: 
162:                IF (YK .NE. 0.0) THEN
163:                   DZ_Z = MAX( DZ_Z, DYK / YK )
164:                ELSE IF ( DYK .NE. 0.0 ) THEN
165:                   DZ_Z = HUGEVAL
166:                END IF
167: 
168:                YMIN = MIN( YMIN, YK )
169: 
170:                NORMY = MAX( NORMY, YK )
171: 
172:                IF ( COLEQU ) THEN
173:                   NORMX = MAX( NORMX, YK * C( I ) )
174:                   NORMDX = MAX( NORMDX, DYK * C( I ) )
175:                ELSE
176:                   NORMX = NORMY
177:                   NORMDX = MAX( NORMDX, DYK )
178:                END IF
179:             END DO
180: 
181:             IF ( NORMX .NE. 0.0 ) THEN
182:                DX_X = NORMDX / NORMX
183:             ELSE IF ( NORMDX .EQ. 0.0 ) THEN
184:                DX_X = 0.0
185:             ELSE
186:                DX_X = HUGEVAL
187:             END IF
188: 
189:             DXRAT = NORMDX / PREVNORMDX
190:             DZRAT = DZ_Z / PREV_DZ_Z
191: *
192: *         Check termination criteria.
193: *
194:             IF ( YMIN*RCOND .LT. INCR_THRESH*NORMY
195:      $           .AND. Y_PREC_STATE .LT. EXTRA_Y )
196:      $           INCR_PREC = .TRUE.
197: 
198:             IF ( X_STATE .EQ. NOPROG_STATE .AND. DXRAT .LE. RTHRESH )
199:      $           X_STATE = WORKING_STATE
200:             IF ( X_STATE .EQ. WORKING_STATE ) THEN
201:                IF ( DX_X .LE. EPS ) THEN
202:                   X_STATE = CONV_STATE
203:                ELSE IF ( DXRAT .GT. RTHRESH ) THEN
204:                   IF ( Y_PREC_STATE .NE. EXTRA_Y ) THEN
205:                      INCR_PREC = .TRUE.
206:                   ELSE
207:                      X_STATE = NOPROG_STATE
208:                   END IF
209:                ELSE
210:                   IF (DXRAT .GT. DXRATMAX) DXRATMAX = DXRAT
211:                END IF
212:                IF ( X_STATE .GT. WORKING_STATE ) FINAL_DX_X = DX_X
213:             END IF
214: 
215:             IF ( Z_STATE .EQ. UNSTABLE_STATE .AND. DZ_Z .LE. DZ_UB )
216:      $           Z_STATE = WORKING_STATE
217:             IF ( Z_STATE .EQ. NOPROG_STATE .AND. DZRAT .LE. RTHRESH )
218:      $           Z_STATE = WORKING_STATE
219:             IF ( Z_STATE .EQ. WORKING_STATE ) THEN
220:                IF ( DZ_Z .LE. EPS ) THEN
221:                   Z_STATE = CONV_STATE
222:                ELSE IF ( DZ_Z .GT. DZ_UB ) THEN
223:                   Z_STATE = UNSTABLE_STATE
224:                   DZRATMAX = 0.0
225:                   FINAL_DZ_Z = HUGEVAL
226:                ELSE IF ( DZRAT .GT. RTHRESH ) THEN
227:                   IF ( Y_PREC_STATE .NE. EXTRA_Y ) THEN
228:                      INCR_PREC = .TRUE.
229:                   ELSE
230:                      Z_STATE = NOPROG_STATE
231:                   END IF
232:                ELSE
233:                   IF ( DZRAT .GT. DZRATMAX ) DZRATMAX = DZRAT
234:                END IF
235:                IF ( Z_STATE .GT. WORKING_STATE ) FINAL_DZ_Z = DZ_Z
236:             END IF
237: 
238:             IF ( X_STATE.NE.WORKING_STATE.AND.
239:      $           ( IGNORE_CWISE.OR.Z_STATE.NE.WORKING_STATE ) )
240:      $           GOTO 666
241: 
242:             IF ( INCR_PREC ) THEN
243:                INCR_PREC = .FALSE.
244:                Y_PREC_STATE = Y_PREC_STATE + 1
245:                DO I = 1, N
246:                   Y_TAIL( I ) = 0.0
247:                END DO
248:             END IF
249: 
250:             PREVNORMDX = NORMDX
251:             PREV_DZ_Z = DZ_Z
252: *
253: *           Update soluton.
254: *
255:             IF ( Y_PREC_STATE .LT. EXTRA_Y ) THEN
256:                CALL CAXPY( N, CMPLX(1.0), DY, 1, Y(1,J), 1 )
257:             ELSE
258:                CALL CLA_WWADDW( N, Y(1,J), Y_TAIL, DY )
259:             END IF
260: 
261:          END DO
262: *        Target of "IF (Z_STOP .AND. X_STOP)".  Sun's f77 won't EXIT.
263:  666     CONTINUE
264: *
265: *     Set final_* when cnt hits ithresh.
266: *
267:          IF ( X_STATE .EQ. WORKING_STATE ) FINAL_DX_X = DX_X
268:          IF ( Z_STATE .EQ. WORKING_STATE ) FINAL_DZ_Z = DZ_Z
269: *
270: *     Compute error bounds.
271: *
272:          IF ( N_NORMS .GE. 1 ) THEN
273:             ERRS_N( J, LA_LINRX_ERR_I ) = FINAL_DX_X / (1 - DXRATMAX)
274:          END IF
275:          IF (N_NORMS .GE. 2) THEN
276:             ERRS_C( J, LA_LINRX_ERR_I ) = FINAL_DZ_Z / (1 - DZRATMAX)
277:          END IF
278: *
279: *     Compute componentwise relative backward error from formula
280: *         max(i) ( abs(R(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
281: *     where abs(Z) is the componentwise absolute value of the matrix
282: *     or vector Z.
283: *
284: *         Compute residual RES = B_s - op(A_s) * Y,
285: *             op(A) = A, A**T, or A**H depending on TRANS (and type).
286: *
287:          CALL CCOPY( N, B( 1, J ), 1, RES, 1 )
288:          CALL CHEMV( UPLO, N, CMPLX(-1.0), A, LDA, Y(1,J), 1,
289:      $        CMPLX(1.0), RES, 1 )
290: 
291:          DO I = 1, N
292:             AYB( I ) = CABS1( B( I, J ) )
293:          END DO
294: *
295: *     Compute abs(op(A_s))*abs(Y) + abs(B_s).
296: *
297:          CALL CLA_HEAMV( UPLO2, N, 1.0,
298:      $        A, LDA, Y(1, J), 1, 1.0, AYB, 1 )
299: 
300:          CALL CLA_LIN_BERR( N, N, 1, RES, AYB, BERR_OUT( J ) )
301: *
302: *     End of loop for each RHS.
303: *
304:       END DO
305: *
306:       RETURN
307:       END
308: