001:       SUBROUTINE CLA_GEAMV ( TRANS, M, N, ALPHA, A, LDA, X, INCX, BETA,
002:      $                       Y, INCY )
003: *
004: *     -- LAPACK routine (version 3.2)                                 --
005: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
006: *     -- Jason Riedy of Univ. of California Berkeley.                 --
007: *     -- November 2008                                                --
008: *
009: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
010: *     -- Univ. of California Berkeley and NAG Ltd.                    --
011: *
012:       IMPLICIT NONE
013: *     ..
014: *     .. Scalar Arguments ..
015:       REAL               ALPHA, BETA
016:       INTEGER            INCX, INCY, LDA, M, N
017:       INTEGER            TRANS
018: *     ..
019: *     .. Array Arguments ..
020:       COMPLEX            A( LDA, * ), X( * )
021:       REAL               Y( * )
022: *     ..
023: *
024: *  Purpose
025: *  =======
026: *
027: *  CLA_GEAMV  performs one of the matrix-vector operations
028: *
029: *          y := alpha*abs(A)*abs(x) + beta*abs(y),
030: *     or   y := alpha*abs(A)'*abs(x) + beta*abs(y),
031: *
032: *  where alpha and beta are scalars, x and y are vectors and A is an
033: *  m by n matrix.
034: *
035: *  This function is primarily used in calculating error bounds.
036: *  To protect against underflow during evaluation, components in
037: *  the resulting vector are perturbed away from zero by (N+1)
038: *  times the underflow threshold.  To prevent unnecessarily large
039: *  errors for block-structure embedded in general matrices,
040: *  "symbolically" zero components are not perturbed.  A zero
041: *  entry is considered "symbolic" if all multiplications involved
042: *  in computing that entry have at least one zero multiplicand.
043: *
044: *  Parameters
045: *  ==========
046: *
047: *  TRANS  - INTEGER
048: *           On entry, TRANS specifies the operation to be performed as
049: *           follows:
050: *
051: *             BLAS_NO_TRANS      y := alpha*abs(A)*abs(x) + beta*abs(y)
052: *             BLAS_TRANS         y := alpha*abs(A')*abs(x) + beta*abs(y)
053: *             BLAS_CONJ_TRANS    y := alpha*abs(A')*abs(x) + beta*abs(y)
054: *
055: *           Unchanged on exit.
056: *
057: *  M      - INTEGER
058: *           On entry, M specifies the number of rows of the matrix A.
059: *           M must be at least zero.
060: *           Unchanged on exit.
061: *
062: *  N      - INTEGER
063: *           On entry, N specifies the number of columns of the matrix A.
064: *           N must be at least zero.
065: *           Unchanged on exit.
066: *
067: *  ALPHA  - REAL
068: *           On entry, ALPHA specifies the scalar alpha.
069: *           Unchanged on exit.
070: *
071: *  A      - COMPLEX          array of DIMENSION ( LDA, n )
072: *           Before entry, the leading m by n part of the array A must
073: *           contain the matrix of coefficients.
074: *           Unchanged on exit.
075: *
076: *  LDA    - INTEGER
077: *           On entry, LDA specifies the first dimension of A as declared
078: *           in the calling (sub) program. LDA must be at least
079: *           max( 1, m ).
080: *           Unchanged on exit.
081: *
082: *  X      - COMPLEX          array of DIMENSION at least
083: *           ( 1 + ( n - 1 )*abs( INCX ) ) when TRANS = 'N' or 'n'
084: *           and at least
085: *           ( 1 + ( m - 1 )*abs( INCX ) ) otherwise.
086: *           Before entry, the incremented array X must contain the
087: *           vector x.
088: *           Unchanged on exit.
089: *
090: *  INCX   - INTEGER
091: *           On entry, INCX specifies the increment for the elements of
092: *           X. INCX must not be zero.
093: *           Unchanged on exit.
094: *
095: *  BETA   - REAL
096: *           On entry, BETA specifies the scalar beta. When BETA is
097: *           supplied as zero then Y need not be set on input.
098: *           Unchanged on exit.
099: *
100: *  Y      - REAL             array of DIMENSION at least
101: *           ( 1 + ( m - 1 )*abs( INCY ) ) when TRANS = 'N' or 'n'
102: *           and at least
103: *           ( 1 + ( n - 1 )*abs( INCY ) ) otherwise.
104: *           Before entry with BETA non-zero, the incremented array Y
105: *           must contain the vector y. On exit, Y is overwritten by the
106: *           updated vector y.
107: *
108: *  INCY   - INTEGER
109: *           On entry, INCY specifies the increment for the elements of
110: *           Y. INCY must not be zero.
111: *           Unchanged on exit.
112: *
113: *
114: *  Level 2 Blas routine.
115: *
116: *     ..
117: *     .. Parameters ..
118:       COMPLEX            ONE, ZERO
119:       PARAMETER          ( ONE = 1.0E+0, ZERO = 0.0E+0 )
120: *     ..
121: *     .. Local Scalars ..
122:       LOGICAL            SYMB_ZERO
123:       REAL               TEMP, SAFE1
124:       INTEGER            I, INFO, IY, J, JX, KX, KY, LENX, LENY
125:       COMPLEX            CDUM
126: *     ..
127: *     .. External Subroutines ..
128:       EXTERNAL           XERBLA, SLAMCH
129:       REAL               SLAMCH
130: *     ..
131: *     .. External Functions ..
132:       EXTERNAL           ILATRANS
133:       INTEGER            ILATRANS
134: *     ..
135: *     .. Intrinsic Functions ..
136:       INTRINSIC          MAX, ABS, REAL, AIMAG, SIGN
137: *     ..
138: *     .. Statement Functions ..
139:       REAL               CABS1
140: *     ..
141: *     .. Statement Function Definitions ..
142:       CABS1( CDUM ) = ABS( REAL( CDUM ) ) + ABS( AIMAG( CDUM ) )
143: *     ..
144: *     .. Executable Statements ..
145: *
146: *     Test the input parameters.
147: *
148:       INFO = 0
149:       IF     ( .NOT.( ( TRANS.EQ.ILATRANS( 'N' ) )
150:      $           .OR. ( TRANS.EQ.ILATRANS( 'T' ) )
151:      $           .OR. ( TRANS.EQ.ILATRANS( 'C' ) ) ) ) THEN
152:          INFO = 1
153:       ELSE IF( M.LT.0 )THEN
154:          INFO = 2
155:       ELSE IF( N.LT.0 )THEN
156:          INFO = 3
157:       ELSE IF( LDA.LT.MAX( 1, M ) )THEN
158:          INFO = 6
159:       ELSE IF( INCX.EQ.0 )THEN
160:          INFO = 8
161:       ELSE IF( INCY.EQ.0 )THEN
162:          INFO = 11
163:       END IF
164:       IF( INFO.NE.0 )THEN
165:          CALL XERBLA( 'CLA_GEAMV ', INFO )
166:          RETURN
167:       END IF
168: *
169: *     Quick return if possible.
170: *
171:       IF( ( M.EQ.0 ).OR.( N.EQ.0 ).OR.
172:      $    ( ( ALPHA.EQ.ZERO ).AND.( BETA.EQ.ONE ) ) )
173:      $   RETURN
174: *
175: *     Set  LENX  and  LENY, the lengths of the vectors x and y, and set
176: *     up the start points in  X  and  Y.
177: *
178:       IF( TRANS.EQ.ILATRANS( 'N' ) )THEN
179:          LENX = N
180:          LENY = M
181:       ELSE
182:          LENX = M
183:          LENY = N
184:       END IF
185:       IF( INCX.GT.0 )THEN
186:          KX = 1
187:       ELSE
188:          KX = 1 - ( LENX - 1 )*INCX
189:       END IF
190:       IF( INCY.GT.0 )THEN
191:          KY = 1
192:       ELSE
193:          KY = 1 - ( LENY - 1 )*INCY
194:       END IF
195: *
196: *     Set SAFE1 essentially to be the underflow threshold times the
197: *     number of additions in each row.
198: *
199:       SAFE1 = SLAMCH( 'Safe minimum' )
200:       SAFE1 = (N+1)*SAFE1
201: *
202: *     Form  y := alpha*abs(A)*abs(x) + beta*abs(y).
203: *
204: *     The O(M*N) SYMB_ZERO tests could be replaced by O(N) queries to
205: *     the inexact flag.  Still doesn't help change the iteration order
206: *     to per-column.
207: *
208:       IY = KY
209:       IF ( INCX.EQ.1 ) THEN
210:          DO I = 1, LENY
211:             IF ( BETA .EQ. 0.0 ) THEN
212:                SYMB_ZERO = .TRUE.
213:                Y( IY ) = 0.0
214:             ELSE IF ( Y( IY ) .EQ. 0.0 ) THEN
215:                SYMB_ZERO = .TRUE.
216:             ELSE
217:                SYMB_ZERO = .FALSE.
218:                Y( IY ) = BETA * ABS( Y( IY ) )
219:             END IF
220:             IF ( ALPHA .NE. 0.0 ) THEN
221:                DO J = 1, LENX
222:                   IF( TRANS.EQ.ILATRANS( 'N' ) )THEN
223:                      TEMP = CABS1( A( I, J ) )
224:                   ELSE
225:                      TEMP = CABS1( A( J, I ) )
226:                   END IF
227: 
228:                   SYMB_ZERO = SYMB_ZERO .AND.
229:      $                 ( X( J ) .EQ. ZERO .OR. TEMP .EQ. ZERO )
230: 
231:                   Y( IY ) = Y( IY ) + ALPHA*CABS1( X( J ) )*TEMP
232:                END DO
233:             END IF
234: 
235:             IF ( .NOT.SYMB_ZERO ) Y( IY ) =
236:      $           Y( IY ) + SIGN( SAFE1, Y( IY ) )
237: 
238:             IY = IY + INCY
239:          END DO
240:       ELSE
241:          DO I = 1, LENY
242:             IF ( BETA .EQ. 0.0 ) THEN
243:                SYMB_ZERO = .TRUE.
244:                Y( IY ) = 0.0
245:             ELSE IF ( Y( IY ) .EQ. 0.0 ) THEN
246:                SYMB_ZERO = .TRUE.
247:             ELSE
248:                SYMB_ZERO = .FALSE.
249:                Y( IY ) = BETA * ABS( Y( IY ) )
250:             END IF
251:             IF ( ALPHA .NE. 0.0 ) THEN
252:                JX = KX
253:                DO J = 1, LENX
254: 
255:                   IF( TRANS.EQ.ILATRANS( 'N' ) )THEN
256:                      TEMP = CABS1( A( I, J ) )
257:                   ELSE
258:                      TEMP = CABS1( A( J, I ) )
259:                   END IF
260: 
261:                   SYMB_ZERO = SYMB_ZERO .AND.
262:      $                 ( X( JX ) .EQ. ZERO .OR. TEMP .EQ. ZERO )
263: 
264:                   Y( IY ) = Y( IY ) + ALPHA*CABS1( X( JX ) )*TEMP
265:                   JX = JX + INCX
266:                END DO
267:             END IF
268: 
269:             IF ( .NOT.SYMB_ZERO ) Y( IY ) =
270:      $           Y( IY ) + SIGN( SAFE1, Y( IY ) )
271: 
272:             IY = IY + INCY
273:          END DO
274:       END IF
275: *
276:       RETURN
277: *
278: *     End of CLA_GEAMV
279: *
280:       END
281: