001:       SUBROUTINE CGETF2( M, N, A, LDA, IPIV, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
005: *     November 2006
006: *
007: *     .. Scalar Arguments ..
008:       INTEGER            INFO, LDA, M, N
009: *     ..
010: *     .. Array Arguments ..
011:       INTEGER            IPIV( * )
012:       COMPLEX            A( LDA, * )
013: *     ..
014: *
015: *  Purpose
016: *  =======
017: *
018: *  CGETF2 computes an LU factorization of a general m-by-n matrix A
019: *  using partial pivoting with row interchanges.
020: *
021: *  The factorization has the form
022: *     A = P * L * U
023: *  where P is a permutation matrix, L is lower triangular with unit
024: *  diagonal elements (lower trapezoidal if m > n), and U is upper
025: *  triangular (upper trapezoidal if m < n).
026: *
027: *  This is the right-looking Level 2 BLAS version of the algorithm.
028: *
029: *  Arguments
030: *  =========
031: *
032: *  M       (input) INTEGER
033: *          The number of rows of the matrix A.  M >= 0.
034: *
035: *  N       (input) INTEGER
036: *          The number of columns of the matrix A.  N >= 0.
037: *
038: *  A       (input/output) COMPLEX array, dimension (LDA,N)
039: *          On entry, the m by n matrix to be factored.
040: *          On exit, the factors L and U from the factorization
041: *          A = P*L*U; the unit diagonal elements of L are not stored.
042: *
043: *  LDA     (input) INTEGER
044: *          The leading dimension of the array A.  LDA >= max(1,M).
045: *
046: *  IPIV    (output) INTEGER array, dimension (min(M,N))
047: *          The pivot indices; for 1 <= i <= min(M,N), row i of the
048: *          matrix was interchanged with row IPIV(i).
049: *
050: *  INFO    (output) INTEGER
051: *          = 0: successful exit
052: *          < 0: if INFO = -k, the k-th argument had an illegal value
053: *          > 0: if INFO = k, U(k,k) is exactly zero. The factorization
054: *               has been completed, but the factor U is exactly
055: *               singular, and division by zero will occur if it is used
056: *               to solve a system of equations.
057: *
058: *  =====================================================================
059: *
060: *     .. Parameters ..
061:       COMPLEX            ONE, ZERO
062:       PARAMETER          ( ONE = ( 1.0E+0, 0.0E+0 ),
063:      $                   ZERO = ( 0.0E+0, 0.0E+0 ) )
064: *     ..
065: *     .. Local Scalars ..
066:       REAL               SFMIN
067:       INTEGER            I, J, JP
068: *     ..
069: *     .. External Functions ..
070:       REAL               SLAMCH
071:       INTEGER            ICAMAX
072:       EXTERNAL           SLAMCH, ICAMAX
073: *     ..
074: *     .. External Subroutines ..
075:       EXTERNAL           CGERU, CSCAL, CSWAP, XERBLA
076: *     ..
077: *     .. Intrinsic Functions ..
078:       INTRINSIC          MAX, MIN
079: *     ..
080: *     .. Executable Statements ..
081: *
082: *     Test the input parameters.
083: *
084:       INFO = 0
085:       IF( M.LT.0 ) THEN
086:          INFO = -1
087:       ELSE IF( N.LT.0 ) THEN
088:          INFO = -2
089:       ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
090:          INFO = -4
091:       END IF
092:       IF( INFO.NE.0 ) THEN
093:          CALL XERBLA( 'CGETF2', -INFO )
094:          RETURN
095:       END IF
096: *
097: *     Quick return if possible
098: *
099:       IF( M.EQ.0 .OR. N.EQ.0 )
100:      $   RETURN
101: *
102: *     Compute machine safe minimum
103: *
104:       SFMIN = SLAMCH('S') 
105: *
106:       DO 10 J = 1, MIN( M, N )
107: *
108: *        Find pivot and test for singularity.
109: *
110:          JP = J - 1 + ICAMAX( M-J+1, A( J, J ), 1 )
111:          IPIV( J ) = JP
112:          IF( A( JP, J ).NE.ZERO ) THEN
113: *
114: *           Apply the interchange to columns 1:N.
115: *
116:             IF( JP.NE.J )
117:      $         CALL CSWAP( N, A( J, 1 ), LDA, A( JP, 1 ), LDA )
118: *
119: *           Compute elements J+1:M of J-th column.
120: *
121:             IF( J.LT.M ) THEN
122:                IF( ABS(A( J, J )) .GE. SFMIN ) THEN
123:                   CALL CSCAL( M-J, ONE / A( J, J ), A( J+1, J ), 1 )
124:                ELSE
125:                   DO 20 I = 1, M-J
126:                      A( J+I, J ) = A( J+I, J ) / A( J, J )
127:    20             CONTINUE
128:                END IF
129:             END IF
130: *
131:          ELSE IF( INFO.EQ.0 ) THEN
132: *
133:             INFO = J
134:          END IF
135: *
136:          IF( J.LT.MIN( M, N ) ) THEN
137: *
138: *           Update trailing submatrix.
139: *
140:             CALL CGERU( M-J, N-J, -ONE, A( J+1, J ), 1, A( J, J+1 ),
141:      $                  LDA, A( J+1, J+1 ), LDA )
142:          END IF
143:    10 CONTINUE
144:       RETURN
145: *
146: *     End of CGETF2
147: *
148:       END
149: