001:       SUBROUTINE CGEEV( JOBVL, JOBVR, N, A, LDA, W, VL, LDVL, VR, LDVR,
002:      $                  WORK, LWORK, RWORK, INFO )
003: *
004: *  -- LAPACK driver routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          JOBVL, JOBVR
010:       INTEGER            INFO, LDA, LDVL, LDVR, LWORK, N
011: *     ..
012: *     .. Array Arguments ..
013:       REAL               RWORK( * )
014:       COMPLEX            A( LDA, * ), VL( LDVL, * ), VR( LDVR, * ),
015:      $                   W( * ), WORK( * )
016: *     ..
017: *
018: *  Purpose
019: *  =======
020: *
021: *  CGEEV computes for an N-by-N complex nonsymmetric matrix A, the
022: *  eigenvalues and, optionally, the left and/or right eigenvectors.
023: *
024: *  The right eigenvector v(j) of A satisfies
025: *                   A * v(j) = lambda(j) * v(j)
026: *  where lambda(j) is its eigenvalue.
027: *  The left eigenvector u(j) of A satisfies
028: *                u(j)**H * A = lambda(j) * u(j)**H
029: *  where u(j)**H denotes the conjugate transpose of u(j).
030: *
031: *  The computed eigenvectors are normalized to have Euclidean norm
032: *  equal to 1 and largest component real.
033: *
034: *  Arguments
035: *  =========
036: *
037: *  JOBVL   (input) CHARACTER*1
038: *          = 'N': left eigenvectors of A are not computed;
039: *          = 'V': left eigenvectors of are computed.
040: *
041: *  JOBVR   (input) CHARACTER*1
042: *          = 'N': right eigenvectors of A are not computed;
043: *          = 'V': right eigenvectors of A are computed.
044: *
045: *  N       (input) INTEGER
046: *          The order of the matrix A. N >= 0.
047: *
048: *  A       (input/output) COMPLEX array, dimension (LDA,N)
049: *          On entry, the N-by-N matrix A.
050: *          On exit, A has been overwritten.
051: *
052: *  LDA     (input) INTEGER
053: *          The leading dimension of the array A.  LDA >= max(1,N).
054: *
055: *  W       (output) COMPLEX array, dimension (N)
056: *          W contains the computed eigenvalues.
057: *
058: *  VL      (output) COMPLEX array, dimension (LDVL,N)
059: *          If JOBVL = 'V', the left eigenvectors u(j) are stored one
060: *          after another in the columns of VL, in the same order
061: *          as their eigenvalues.
062: *          If JOBVL = 'N', VL is not referenced.
063: *          u(j) = VL(:,j), the j-th column of VL.
064: *
065: *  LDVL    (input) INTEGER
066: *          The leading dimension of the array VL.  LDVL >= 1; if
067: *          JOBVL = 'V', LDVL >= N.
068: *
069: *  VR      (output) COMPLEX array, dimension (LDVR,N)
070: *          If JOBVR = 'V', the right eigenvectors v(j) are stored one
071: *          after another in the columns of VR, in the same order
072: *          as their eigenvalues.
073: *          If JOBVR = 'N', VR is not referenced.
074: *          v(j) = VR(:,j), the j-th column of VR.
075: *
076: *  LDVR    (input) INTEGER
077: *          The leading dimension of the array VR.  LDVR >= 1; if
078: *          JOBVR = 'V', LDVR >= N.
079: *
080: *  WORK    (workspace/output) COMPLEX array, dimension (MAX(1,LWORK))
081: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
082: *
083: *  LWORK   (input) INTEGER
084: *          The dimension of the array WORK.  LWORK >= max(1,2*N).
085: *          For good performance, LWORK must generally be larger.
086: *
087: *          If LWORK = -1, then a workspace query is assumed; the routine
088: *          only calculates the optimal size of the WORK array, returns
089: *          this value as the first entry of the WORK array, and no error
090: *          message related to LWORK is issued by XERBLA.
091: *
092: *  RWORK   (workspace) REAL array, dimension (2*N)
093: *
094: *  INFO    (output) INTEGER
095: *          = 0:  successful exit
096: *          < 0:  if INFO = -i, the i-th argument had an illegal value.
097: *          > 0:  if INFO = i, the QR algorithm failed to compute all the
098: *                eigenvalues, and no eigenvectors have been computed;
099: *                elements and i+1:N of W contain eigenvalues which have
100: *                converged.
101: *
102: *  =====================================================================
103: *
104: *     .. Parameters ..
105:       REAL               ZERO, ONE
106:       PARAMETER          ( ZERO = 0.0E0, ONE = 1.0E0 )
107: *     ..
108: *     .. Local Scalars ..
109:       LOGICAL            LQUERY, SCALEA, WANTVL, WANTVR
110:       CHARACTER          SIDE
111:       INTEGER            HSWORK, I, IBAL, IERR, IHI, ILO, IRWORK, ITAU,
112:      $                   IWRK, K, MAXWRK, MINWRK, NOUT
113:       REAL               ANRM, BIGNUM, CSCALE, EPS, SCL, SMLNUM
114:       COMPLEX            TMP
115: *     ..
116: *     .. Local Arrays ..
117:       LOGICAL            SELECT( 1 )
118:       REAL               DUM( 1 )
119: *     ..
120: *     .. External Subroutines ..
121:       EXTERNAL           CGEBAK, CGEBAL, CGEHRD, CHSEQR, CLACPY, CLASCL,
122:      $                   CSCAL, CSSCAL, CTREVC, CUNGHR, SLABAD, XERBLA
123: *     ..
124: *     .. External Functions ..
125:       LOGICAL            LSAME
126:       INTEGER            ILAENV, ISAMAX
127:       REAL               CLANGE, SCNRM2, SLAMCH
128:       EXTERNAL           LSAME, ILAENV, ISAMAX, CLANGE, SCNRM2, SLAMCH
129: *     ..
130: *     .. Intrinsic Functions ..
131:       INTRINSIC          AIMAG, CMPLX, CONJG, MAX, REAL, SQRT
132: *     ..
133: *     .. Executable Statements ..
134: *
135: *     Test the input arguments
136: *
137:       INFO = 0
138:       LQUERY = ( LWORK.EQ.-1 )
139:       WANTVL = LSAME( JOBVL, 'V' )
140:       WANTVR = LSAME( JOBVR, 'V' )
141:       IF( ( .NOT.WANTVL ) .AND. ( .NOT.LSAME( JOBVL, 'N' ) ) ) THEN
142:          INFO = -1
143:       ELSE IF( ( .NOT.WANTVR ) .AND. ( .NOT.LSAME( JOBVR, 'N' ) ) ) THEN
144:          INFO = -2
145:       ELSE IF( N.LT.0 ) THEN
146:          INFO = -3
147:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
148:          INFO = -5
149:       ELSE IF( LDVL.LT.1 .OR. ( WANTVL .AND. LDVL.LT.N ) ) THEN
150:          INFO = -8
151:       ELSE IF( LDVR.LT.1 .OR. ( WANTVR .AND. LDVR.LT.N ) ) THEN
152:          INFO = -10
153:       END IF
154: 
155: *
156: *     Compute workspace
157: *      (Note: Comments in the code beginning "Workspace:" describe the
158: *       minimal amount of workspace needed at that point in the code,
159: *       as well as the preferred amount for good performance.
160: *       CWorkspace refers to complex workspace, and RWorkspace to real
161: *       workspace. NB refers to the optimal block size for the
162: *       immediately following subroutine, as returned by ILAENV.
163: *       HSWORK refers to the workspace preferred by CHSEQR, as
164: *       calculated below. HSWORK is computed assuming ILO=1 and IHI=N,
165: *       the worst case.)
166: *
167:       IF( INFO.EQ.0 ) THEN
168:          IF( N.EQ.0 ) THEN
169:             MINWRK = 1
170:             MAXWRK = 1
171:          ELSE
172:             MAXWRK = N + N*ILAENV( 1, 'CGEHRD', ' ', N, 1, N, 0 )
173:             MINWRK = 2*N
174:             IF( WANTVL ) THEN
175:                MAXWRK = MAX( MAXWRK, N + ( N - 1 )*ILAENV( 1, 'CUNGHR',
176:      $                       ' ', N, 1, N, -1 ) )
177:                CALL CHSEQR( 'S', 'V', N, 1, N, A, LDA, W, VL, LDVL,
178:      $                WORK, -1, INFO )
179:             ELSE IF( WANTVR ) THEN
180:                MAXWRK = MAX( MAXWRK, N + ( N - 1 )*ILAENV( 1, 'CUNGHR',
181:      $                       ' ', N, 1, N, -1 ) )
182:                CALL CHSEQR( 'S', 'V', N, 1, N, A, LDA, W, VR, LDVR,
183:      $                WORK, -1, INFO )
184:             ELSE
185:                CALL CHSEQR( 'E', 'N', N, 1, N, A, LDA, W, VR, LDVR,
186:      $                WORK, -1, INFO )
187:             END IF
188:             HSWORK = WORK( 1 )
189:             MAXWRK = MAX( MAXWRK, HSWORK, MINWRK )
190:          END IF
191:          WORK( 1 ) = MAXWRK
192: *
193:          IF( LWORK.LT.MINWRK .AND. .NOT.LQUERY ) THEN
194:             INFO = -12
195:          END IF
196:       END IF
197: *
198:       IF( INFO.NE.0 ) THEN
199:          CALL XERBLA( 'CGEEV ', -INFO )
200:          RETURN
201:       ELSE IF( LQUERY ) THEN
202:          RETURN
203:       END IF
204: *
205: *     Quick return if possible
206: *
207:       IF( N.EQ.0 )
208:      $   RETURN
209: *
210: *     Get machine constants
211: *
212:       EPS = SLAMCH( 'P' )
213:       SMLNUM = SLAMCH( 'S' )
214:       BIGNUM = ONE / SMLNUM
215:       CALL SLABAD( SMLNUM, BIGNUM )
216:       SMLNUM = SQRT( SMLNUM ) / EPS
217:       BIGNUM = ONE / SMLNUM
218: *
219: *     Scale A if max element outside range [SMLNUM,BIGNUM]
220: *
221:       ANRM = CLANGE( 'M', N, N, A, LDA, DUM )
222:       SCALEA = .FALSE.
223:       IF( ANRM.GT.ZERO .AND. ANRM.LT.SMLNUM ) THEN
224:          SCALEA = .TRUE.
225:          CSCALE = SMLNUM
226:       ELSE IF( ANRM.GT.BIGNUM ) THEN
227:          SCALEA = .TRUE.
228:          CSCALE = BIGNUM
229:       END IF
230:       IF( SCALEA )
231:      $   CALL CLASCL( 'G', 0, 0, ANRM, CSCALE, N, N, A, LDA, IERR )
232: *
233: *     Balance the matrix
234: *     (CWorkspace: none)
235: *     (RWorkspace: need N)
236: *
237:       IBAL = 1
238:       CALL CGEBAL( 'B', N, A, LDA, ILO, IHI, RWORK( IBAL ), IERR )
239: *
240: *     Reduce to upper Hessenberg form
241: *     (CWorkspace: need 2*N, prefer N+N*NB)
242: *     (RWorkspace: none)
243: *
244:       ITAU = 1
245:       IWRK = ITAU + N
246:       CALL CGEHRD( N, ILO, IHI, A, LDA, WORK( ITAU ), WORK( IWRK ),
247:      $             LWORK-IWRK+1, IERR )
248: *
249:       IF( WANTVL ) THEN
250: *
251: *        Want left eigenvectors
252: *        Copy Householder vectors to VL
253: *
254:          SIDE = 'L'
255:          CALL CLACPY( 'L', N, N, A, LDA, VL, LDVL )
256: *
257: *        Generate unitary matrix in VL
258: *        (CWorkspace: need 2*N-1, prefer N+(N-1)*NB)
259: *        (RWorkspace: none)
260: *
261:          CALL CUNGHR( N, ILO, IHI, VL, LDVL, WORK( ITAU ), WORK( IWRK ),
262:      $                LWORK-IWRK+1, IERR )
263: *
264: *        Perform QR iteration, accumulating Schur vectors in VL
265: *        (CWorkspace: need 1, prefer HSWORK (see comments) )
266: *        (RWorkspace: none)
267: *
268:          IWRK = ITAU
269:          CALL CHSEQR( 'S', 'V', N, ILO, IHI, A, LDA, W, VL, LDVL,
270:      $                WORK( IWRK ), LWORK-IWRK+1, INFO )
271: *
272:          IF( WANTVR ) THEN
273: *
274: *           Want left and right eigenvectors
275: *           Copy Schur vectors to VR
276: *
277:             SIDE = 'B'
278:             CALL CLACPY( 'F', N, N, VL, LDVL, VR, LDVR )
279:          END IF
280: *
281:       ELSE IF( WANTVR ) THEN
282: *
283: *        Want right eigenvectors
284: *        Copy Householder vectors to VR
285: *
286:          SIDE = 'R'
287:          CALL CLACPY( 'L', N, N, A, LDA, VR, LDVR )
288: *
289: *        Generate unitary matrix in VR
290: *        (CWorkspace: need 2*N-1, prefer N+(N-1)*NB)
291: *        (RWorkspace: none)
292: *
293:          CALL CUNGHR( N, ILO, IHI, VR, LDVR, WORK( ITAU ), WORK( IWRK ),
294:      $                LWORK-IWRK+1, IERR )
295: *
296: *        Perform QR iteration, accumulating Schur vectors in VR
297: *        (CWorkspace: need 1, prefer HSWORK (see comments) )
298: *        (RWorkspace: none)
299: *
300:          IWRK = ITAU
301:          CALL CHSEQR( 'S', 'V', N, ILO, IHI, A, LDA, W, VR, LDVR,
302:      $                WORK( IWRK ), LWORK-IWRK+1, INFO )
303: *
304:       ELSE
305: *
306: *        Compute eigenvalues only
307: *        (CWorkspace: need 1, prefer HSWORK (see comments) )
308: *        (RWorkspace: none)
309: *
310:          IWRK = ITAU
311:          CALL CHSEQR( 'E', 'N', N, ILO, IHI, A, LDA, W, VR, LDVR,
312:      $                WORK( IWRK ), LWORK-IWRK+1, INFO )
313:       END IF
314: *
315: *     If INFO > 0 from CHSEQR, then quit
316: *
317:       IF( INFO.GT.0 )
318:      $   GO TO 50
319: *
320:       IF( WANTVL .OR. WANTVR ) THEN
321: *
322: *        Compute left and/or right eigenvectors
323: *        (CWorkspace: need 2*N)
324: *        (RWorkspace: need 2*N)
325: *
326:          IRWORK = IBAL + N
327:          CALL CTREVC( SIDE, 'B', SELECT, N, A, LDA, VL, LDVL, VR, LDVR,
328:      $                N, NOUT, WORK( IWRK ), RWORK( IRWORK ), IERR )
329:       END IF
330: *
331:       IF( WANTVL ) THEN
332: *
333: *        Undo balancing of left eigenvectors
334: *        (CWorkspace: none)
335: *        (RWorkspace: need N)
336: *
337:          CALL CGEBAK( 'B', 'L', N, ILO, IHI, RWORK( IBAL ), N, VL, LDVL,
338:      $                IERR )
339: *
340: *        Normalize left eigenvectors and make largest component real
341: *
342:          DO 20 I = 1, N
343:             SCL = ONE / SCNRM2( N, VL( 1, I ), 1 )
344:             CALL CSSCAL( N, SCL, VL( 1, I ), 1 )
345:             DO 10 K = 1, N
346:                RWORK( IRWORK+K-1 ) = REAL( VL( K, I ) )**2 +
347:      $                               AIMAG( VL( K, I ) )**2
348:    10       CONTINUE
349:             K = ISAMAX( N, RWORK( IRWORK ), 1 )
350:             TMP = CONJG( VL( K, I ) ) / SQRT( RWORK( IRWORK+K-1 ) )
351:             CALL CSCAL( N, TMP, VL( 1, I ), 1 )
352:             VL( K, I ) = CMPLX( REAL( VL( K, I ) ), ZERO )
353:    20    CONTINUE
354:       END IF
355: *
356:       IF( WANTVR ) THEN
357: *
358: *        Undo balancing of right eigenvectors
359: *        (CWorkspace: none)
360: *        (RWorkspace: need N)
361: *
362:          CALL CGEBAK( 'B', 'R', N, ILO, IHI, RWORK( IBAL ), N, VR, LDVR,
363:      $                IERR )
364: *
365: *        Normalize right eigenvectors and make largest component real
366: *
367:          DO 40 I = 1, N
368:             SCL = ONE / SCNRM2( N, VR( 1, I ), 1 )
369:             CALL CSSCAL( N, SCL, VR( 1, I ), 1 )
370:             DO 30 K = 1, N
371:                RWORK( IRWORK+K-1 ) = REAL( VR( K, I ) )**2 +
372:      $                               AIMAG( VR( K, I ) )**2
373:    30       CONTINUE
374:             K = ISAMAX( N, RWORK( IRWORK ), 1 )
375:             TMP = CONJG( VR( K, I ) ) / SQRT( RWORK( IRWORK+K-1 ) )
376:             CALL CSCAL( N, TMP, VR( 1, I ), 1 )
377:             VR( K, I ) = CMPLX( REAL( VR( K, I ) ), ZERO )
378:    40    CONTINUE
379:       END IF
380: *
381: *     Undo scaling if necessary
382: *
383:    50 CONTINUE
384:       IF( SCALEA ) THEN
385:          CALL CLASCL( 'G', 0, 0, CSCALE, ANRM, N-INFO, 1, W( INFO+1 ),
386:      $                MAX( N-INFO, 1 ), IERR )
387:          IF( INFO.GT.0 ) THEN
388:             CALL CLASCL( 'G', 0, 0, CSCALE, ANRM, ILO-1, 1, W, N, IERR )
389:          END IF
390:       END IF
391: *
392:       WORK( 1 ) = MAXWRK
393:       RETURN
394: *
395: *     End of CGEEV
396: *
397:       END
398: